Ballerlikemahler

Babel user information

en-N	This user has a native understanding of English.

ru-1	Этот участник владеет русским языком на начальном уровне.

I used to work at the Northeastern University Libraries (Q73495377), so many edits I made to Boston-related items from 2020 to 2022 were in my professional capacity; everything else is just for fun!

Fun/useful queries

Massachusetts music venues

Make a map of Massachusetts music venues!

#title: Music venues in Massachusetts
#defaultView:Map{"markercluster":"true"}

SELECT ?music_venue ?music_venueLabel ?coords
(group_concat(distinct ?locationLabel; separator="; ") as ?locations) 
WHERE {
   hint:Query hint:optimizer "None".
    ?music_venue wdt:P131+ wd:Q771;
                 wdt:P131 ?location.
    # Things that have instance of (some subclass of) music venue or 
    # has use (some subclass of) music venue
    {?music_venue wdt:P31/wdt:P279* wd:Q8719053.}
    UNION
    {?music_venue wdt:P366/wdt:P279* wd:Q8719053.}
    OPTIONAL{?music_venue wdt:P625 ?coords}
    SERVICE wikibase:label { 
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". 
        ?location rdfs:label ?locationLabel.
        ?music_venue rdfs:label ?music_venueLabel.}
} group by ?music_venue ?music_venueLabel ?coords

Music venues in Massachusetts

Bloomsbury Group

Make a graph of the messy relationships within the Bloomsbury Group!

#title: Bloomsbury Messiness
#defaultView:Graph
select distinct ?person ?personLabel 
?image
?linkTo
?linkToLabel
?edgeLabel
where {
  ?person wdt:P31 wd:Q5;
          (wdt:P135|wdt:P463) wd:Q603529. 
  optional{?person wdt:P18 ?image.}
  optional{?person ?directClaimP ?linkTo.
          ?linkTo (wdt:P135|wdt:P463) wd:Q603529;
                  wdt:P31 wd:Q5.
          ?p wikibase:directClaim ?directClaimP.
          ?p rdfs:label ?edgeLabel.
          filter(lang(?edgeLabel)="en")}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".}
 }

Bloomsbury Messiness

Fictional futures

Make a table of works that depict the world 50+ years in the future from their publication date

select ?work ?workLabel 
(min(year(?pubDate)) as ?earliestPublicationYear) 
(max(year(?settingYear)) as ?latestSettingYear) 
where {
  ?work wdt:P2408 ?period;
        wdt:P577 ?pubDate.
  ?period wdt:P31 wd:Q3186692;
          wdt:P585 ?settingYear. 
  filter(year(?settingYear) - year(?pubDate) >= 50)
  
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} 
group by ?work ?workLabel

Try it!

SPB musical ensembles with no Discogs

Musical ensembles from Saint Petersburg w/o Discogs artist ID statements (useful template for a lot of work)

SELECT DISTINCT ?item ?itemLabel WHERE {
  ?item wdt:P31/wdt:P279* wd:Q2088357;
        wdt:P740 wd:Q656.
  
    FILTER NOT EXISTS{?item wdt:P1953 ?discogsID}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ru". }
}

Try it!

Use of floruit statements by item type

Summary of use of floruit statements by items' instance of values (again, useful template for a lot of work)

SELECT ?itemType ?itemTypeLabel (COUNT(?item) AS ?items) WHERE {
  ?item wdt:P31 ?itemType;
        wdt:P1317 ?floruit.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
} GROUP BY ?itemType ?itemTypeLabel
ORDER BY DESC(?items)

Try it!