Excel Primer for Finance Students

John Byrd, November 2015.

This primer assumes you can enter data and copy functions and equations between
cells in Excel. If you aren’t familiar with these basic skills read the note:

ExcelBasics.pdf

There is a set of practice problems with solutions at the end of each section.

Here is the URL for a very good website about Excel basics including the material
covered in this primer.

http://www.tvmcalcs.com/calculators/Excel_tvm_functions/Excel_tvm_functions_p
age1

Excel for finance

There are five Excel functions that we will use this semester in BUSN 6640. If you
have used a financial calculator you will see the similarity of the Excel functions. If
you are new to both Excel and financial calculators read through the next section
carefully.

The Five Basic Finance Functions In Excel

Much of the material in a basic finance course is based on the concept that money
has a time value. The Excel functions that we review below are all associated with
the time value of money. These functions are all based on five inputs.

First there is an interest rate or a growth rate, which in Excel is referred to by the
name Rate.

Next there are different types of cash flows. The amount today is called the present
value and will be abbreviated PV. The terminal cash flow or ending amount is called
the future value, and is abbreviated FV. The third type of cash flow are intermediate
payments. When these are equally spaced in the same amount we have only to enter
a single number, which we will call PMT. If the payments are different amounts
and/or irregularly spaced in time things become a bit more complicated. We will do
an example of this type of problem after we introduce the functions.

The final input is the number of payment periods. If the payments are made
annually this will be the number of years. If we are looking at a home mortgage with
monthly payments it will be the number of months. In Excel the number of payment
periods is abbreviated NPER.
The five functions introduced in this note solve for each of these five inputs; that is,
there’s a function that solves for Rate, there’s a function that solves for PV, there’s a
function that solves for NPER, etc.

The functions (and all Excel functions) are written in a specific way. They all start
with an “=” equal sign (that is what designates a formula or function in Excel). A
function begins with an equal sign and the function’s name, then in parentheses are
a list of inputs. The inputs have to be entered in a specific order, separated by
commas. Because the inputs are separated by commas that means when you enter
numbers they cannot have commas separating thousands, e.g., you cannot enter
10,000, it has to be 10000. Excel can use other cells as inputs. So you can refer to a
cell that has a number in it as an input into your function. I’ll show you some
examples of this as we proceed.

The PV Function
To solve for present value or today’s price we use the PV function. The format of the
PV function is:

PV(RATE,NPER,PMT,FV,TYPE)

1) Finding the present value of a single future amount.

In this case we have no payments just one cash flow sometime in the future.
Suppose the interest rate is 10% per year and that the single future cash flow occurs
five years from now. If the single cash flow is for $1000 then we would enter the
inputs into the PV function as follows:

= PV(RATE,NPER,PMT,FV,TYPE)

=PV(10%,5,0,1000,0)

Pasting this function into a spreadsheet, the result (620.92) would be displayed.
This is a negative number, which leads us to one of the more confusing aspects of
using Excel.

The signs of inputs and outputs

For Excel to compute its financial functions there have to be cash flows going in and
out. That is, there has to be a sign change somewhere in the function or in the result.
In the example we just did we might say this: we deposit $620.92 today (that is an
outlay that we make, so the money is going away from us and we sign it negative).
The bank or financial institution promises to pay us, in exactly 5 years, $1000. The
$1000 is money that flows to us, so we will sign it positive.

As you enter the inputs into the Excel functions you’ll have to think about whether
the cash flows are flowing to you (which we think of as signed positive) or our
outlays that you are making (which we think of as signed negative).
 In the PV formula there was one input that we haven’t talked about yet, TYPE. This
designates whether payments occur at the beginning of a period or the end of a
period. In our class the rule of thumb will almost always be payments occurred at
the end of periods. The exception will be for leases. Here’s the logic behind this
distinction. If something is earning interest it takes some time for that interest to
build up, so some interest is built up by the end of the period and that’s when we
recognize it. For a lease, we’re buying a service so we pay in advance for the use of
the asset or building. So lease payments are made at the beginning of periods to pay
for the associated service. If the TYPE input is zero or omitted that tells Excel that
payments occur at the end of a period. If the TYPE input is one that means that the
payments occur at the beginning of the period.

Finding present values without the Excel functions

The formula for the present value of a single amount is:

PV = FV/(1+Rate)NPER

Using our previous example, the formula would be:

PV = 1000/(1.10)5

To enter this in an Excel spreadsheet you must designate the exponent with a “^”.
So the formula you would actually enter would be:

=1000/(1.10)^5

Display: 620.9213

2) Finding the present value of a series of payments.

Sometimes when we are shopping for a large asset–a car or a house–we figure out
what sort of payment we can make, and how many payments we are willing to make,
and that determines the price range of the cars or the houses that we look at. So the
payments determine the price that we can pay for something; in Excel terms the
payments determined the PV. Most loans have monthly payments, which we will
deal with later on in this primer, but for the sake of simplification we will use annual
payments in this example.

You are thinking about buying a lot to build a vacation home on. You think that you
can afford to make annual loan payments of $6000 per year for 15 years. What
price range of lots should you be looking at? We want to find the present value of a
series of $6000 annual payments for 15 years. Suppose the developer is offering
financing for 6% per year. Then we would compute the present value as:

= PV(RATE,NPER,PMT,FV,TYPE)

=PV(6%,15,-6000,0,0)

=$58,273.49
This result says we can look at lots in the $55,000-$60,000 price range. Notice a
couple things about how the formula was constructed. The payment was entered as
a negative number because it’s going to be an outlay that we make. FV is zero. We
want no final balance on our loan. We want to pay it off completely. Type is zero
because we assume that the payment will be at the end of the period.

Notice that the 15 payments of $6,000 total $90,000. The difference between the PV
and the total amount paid is the interest paid on the loan. The total interest is
$31,726.51!

When payments are not the same over time: Two solutions

The PV function allows just one payment input, so payments have to be the same
over the life of the asset being valued. Excel addresses this issue with its NPV
function. This misnamed function (you’ll learn why in the BUSN 6640 class) allows
a set of payments to be valued. The form of the NPV function is:

=NPV(RATE, VALUE1, VALUE2, VALUE3, . . . )

There can be up to 254 values in the function (in my version of Excel). You can
enter them in the function as numbers or select a set of cells that contain the
appropriate values. Here is an example.

The NPV function uses a RATE of 8% and refers to the values in cells B2 through B6.
The ability to refer to cells as inputs in functions is really helpful. Notice that the
first value is discounted one year, the second value two years, etc. This means that
the NPV function assumes that cash flows begin one year from today. We will do
things a bit differently, assuming the first cash flow occurs today (in the present) so
the NPV function will discount one period too many relative to how we will set up
our analyses. I’ll warn you about this in the class.
The second method for finding the present value of a series of unequal cash flows is
to do it manually using the PV=FV/(1+Rate)NPER formula. The first image shows the
formulas in column C. In cell C2 the formula is =B2/(1.08)^A2. B2 refers to the
$500 value in cell B2. The “^A2” refers to the value in cell A2, which is 1 year, and
raises the 1.08 term to that power. It is the NPER part of the PV function. As you go
down column C you can see that the value and exponent changes, so the formula
refers to the appropriate value and exponent. You do not have to type in all these
formulas. If you type in the first one you can copy it to the other cells and the
spreadsheet automatically changes the references for you.

Here is the view showing the results. The =SUM(C2:C6) function adds up the
individual present values. You can see that the answer is the same as the result
from the NPV function shown in cell B8.

3) Finding the price of a corporate bond.

Here is an example that lets us apply the PV function/ Corporate bonds are
structured in the following way. They make periodic interest payments based on a
$1000 face value, and at maturity they return the $1000. The structure is a series of
payments plus a lump sum payment. Assumed that a corporate bond has a 5%
coupon rate (this is the interest rate per year that the bond pays) so pays $50
interest per year (5% of $1000). Suppose further that the bond matures in 20 years.
If we buy the bond we will get 20 $50 payments plus a single $1000 payment in 20
years. Notice that the 5% coupon rate determines the payment, but it is not
necessarily the number that goes into the PV function as the RATE input. Here’s
what we know so far:

= PV(RATE,NPER,PMT,FV,TYPE)

=PV(RATE,20,-50,1000,0)

How much are we willing to pay today for these promised payments? It depends on
what rate of return we require. The number that we use as the input for RATE will
determine our rate of return. The higher the rate of return we want to earn, the less
we will pay today. There is an inverse relationship between the price we pay and
the rate of return we earn. Let’s do some numerical examples and you will see how
this works. If we want to earn 8% we would compute:

=PV(8%,20,50,1000,0) = ($705.04)

If we could buy this bond for $705.04, and hold it for 20 years, we would earn an 8%
return. Notice that the price is signed negative because it is the amount that we
have to pay in order to purchase the future cash inflows. Consider these different
inputs for the RATE number.

RATE (input) PV( Price today)

8.00% ($705.46)
7.00% ($788.12)
6.00% ($885.30)
5.00% ($1,000.00)
4.00% ($1,135.90)
3.00% ($1,297.55)

Note: Corporate bonds typically pay interest semi-annually. We will show that
adjustment later in the primer.
PV Function Self-test

1) At retirement you would like to have enough saved, so you can withdraw (e.g.,
make yourself a payment) of $70,000 per year for 20 years. If the balance in the
savings account earns 4% per year and withdrawals are made at the end of the year,
how much will you need in your savings account? Assume that the account will
have a zero balance when the last $70,000 withdrawal is made, i.e., no inheritance
for the kids.

2) In (1) above we assumed that you accumulated your retirement target, then let it
grow for one year before you started making withdrawals; the first withdrawal was
at the end of the first year. Instead, suppose that the minute you accumulate your
target amount you retire and make your first withdrawal; that is, the payments are
made at the beginning of the period instead of the end of the period. How does this
change the amount you need to have in your savings account? Hint: This requires
TYPE to be set to 1.

3) A corporate bond has a 7% coupon rate. A $1,000 face value and will mature in
exactly 12 years. If its next interest payment is due in one-year, what will the bond
sell for today, if bonds of similar risk are yielding 4.5% per year?

PV Self-test Solutions

1) You want to find the PV of 20 $70,000 payments with a rate of 4% and FV will be
zero. The PV function using these inputs will be:

=PV(4%,20,70000,0,) = ($951,322.84)

Accumulating $951,322.84 will allow you to have $70,000 per year to live on for 20
years. Notice that 20 x $70,000 is $1,400,000. The interest earned on the
$951,322.84, and the decreasing balance over time will make up the other $450,000
you need for retirement.

2) You want to find the PV of 20 $70,000 payments with a rate of 4%, with payments
at the beginning of the period (TYPE=1) and FV will be zero. The PV function using
these inputs will be:

=PV(4%,20,70000,0,1) = ($989,375.76)

The target amount increases because you no longer have the first year of interest on
the $951,322.84 that allowed your account to grow. In fact, if you compute the
interest on the $951,322.84 at 4% ($38,052.92) it just equals the difference between
$989,375.76 and $951,322.84.
3) The 7% coupon rate means the bond pays $70 per year of interest. The RATE
input in the PV function will be the current market yield on similar bonds, 4.5%. FV
is the $1,000 face value and NPER is 12 years. Putting all of these inputs into the PV
function, we have:

=PV(4.5%,12,70,1000,) = ($1,227.96)

We would pay a premium over the $1,000 face value because the interest paid by
this bond is so much higher than the 4.5% that bonds of similar risk are paying.

The FV Function
1) Finding the future value of a single deposit (Exponential growth).

Suppose that a 4-year CD (certificate of deposit) pays an interest rate is 6% per year.
If we deposit $10,000 in the CD today, how much will it be worth when the CD
matures? To answer questions about future values or growth we use the FV
function in Excel. The ordering of inputs is very similar to that of the PV function.

= FV(RATE,NPER,PMT,PV,TYPE)

Given the CD example the inputs for the FV function would be:

=FV(6%,4,0,10000,0)

Entering the function into a spreadsheet the result is: ($12,624.77)

Note: We entered 6% as the rate. This means we were assuming that the CD
computed and compounded interest on an annual basis. In fact, most CD’s calculate
and compound interest much more often than this – monthly or quarterly – which
accelerates growth. We deal with compounding periods different than annual
compounding below.

The FV result is a negative number because we entered the $10,000 as positive. If

we follow my cash out as negative, cash in as positive rule, then we should have
signed the $10,000 as negative (we deposited it, so it left us), which would make the
result positive.

=FV(6%,4,0,-10000,0) = $12,624.77

The TYPE input item indicates whether payments occur at the beginning of a period
or the end of a period. Since the CD requires time for interest to build up, it is paid at
the end of the period. We designate this with either a “0” entry or omitting the input
item.

Time Starting amount Ending Amount

Year 1 10,000.00 10,600.00
Year 2 10,600.00 11,236.00
 Year 3 11,236.00 11,910.16
Year 4 11,910.16 12,624.77

Finding future values without the Excel functions

The formula for the future value of a single amount is:

FV = PV x (1+Rate)NPER

Using our previous example, the formula would be:

FV = 10,000x(1.06)4

To enter this in an Excel spreadsheet you must designate the exponent with a “^”
and the multiplication sign as “*” an astrerisk. So the formula you would actually
enter would be:

=10000*(1.06)^4

Display: 12624.7696

Because the number of compounding periods (years in this example) is in the form
of an exponent this approach is often called “exponential growth.” In exponential
growth the rate of growth is the same across all periods, and interest (or growth) is
compounded. Compounding means that interest earned in earlier periods is added
to the original principal (or the PV) to determine the base upon which interest is
earned. You can see this in the table above. The first year the interest earned in
$600 = 6% of $10,000. In Year 2 the interest earned is $636 = $11,236 – $10,600.
The $636 can be decomposed into $600 on the original $10,000 and $36 on the
$600 on interest earned the first period.

There are other ways to compute interest and growth. “Simple interest” means that
the dollar amount of interest is the same for all periods. At 6% simple interest the
$10,000 would grow by $600 each year, to total $12,400 at the end of 4 years.
Mathematically, the formula would be:
10,000 + 4 x (0.06 x 10,000)

The annual interest of $600 is multiplied by the number of periods and added to the
original deposit, rather than the number of periods being an exponent.

2) Finding the future value of a series of payments.

My wife and I are beginning to talk more seriously about retirement, which is a
perfect application for the FV function. Suppose you can contribute $20,000 a year
to your retirement account every year. This includes both your contribution and
your employer’s match. How much will you have in your retirement account after
20 years if the account earns 4% per year?
 = FV(RATE,NPER,PMT,PV,TYPE)

=FV(4%,20,-20000,0,0)

=$595,561.57

This result assumes that we make annual contributions at the end of each year. If
the contributions were made at the beginning of the period, this would increase the
FV because there would be one additional compounding period. We can find the FV
with payments at the beginning of the period by entering the TYPE input as 1
instead of zero.

= FV(RATE,NPER,PMT,PV,TYPE)

=FV(4%,20,-20000,0,1)

=$619,384.03

Of course, for most of us the contributions are made monthly. We will consider this
later in this primer.

FV Function Self-test

1) You save $20,000 per year for 20 years. If the balance in the savings account
earns 4% per year and deposits are made at the end of the year, how much will you
have in your savings account after the 20 th year? Assume that you have $35,000 in
the account when you begin this savings program.

2) The current growth rate of the world’s population is 1.2% per year. As of
January 3, 2013, the population was estimated to be 7,057,400,401
(http://www.census.gov/main/www/popclock.html). What will the population be
in 40 years (in 2043)?

3) A zero-coupon bond grows at 6% per year. It has a price of $1,000 today and will
mature in exactly 12 years. It makes no interest payments, but the annual growth in
added to the $1000. What will this zero-coupon bond be worth when it matures?
FV Self-test Solutions

1) You want to find the FV of 20 $20,000 payments with a rate of 4% and PV is

$35,000. The FV function using these inputs will be:

=FV(4%,20,-20000,-35000,0) = $672,250.88

Notice that both the $20,000 annual contributions and the $35,000 initial balance
are signed negative because you deposited them into the account (money going
away from you).

2) You want to find the FV of 7.057 billion growing at 1.2% per year for 40 years.
The FV function using these inputs will be:
 =FV(1.2%,40, 0,-7057400401,0) = 11,372,743,860 = 11.3 billion

Today’s population is signed negative to get a positive result, but we know that both
of these numbers are positive so could have made the translation of the negative
result.

3) The value of the 6% zero-coupon bond in 12 years will be:

=FV(6%,12, 0,-1000,) = $2,012.20

The $1,000 we paid for the bond doubled over the 12 year period. When the
product of the rate times the number of years is about 72, that results in a doubling
of the initial value. This is known as the rule of 72. 6% x 12 years, 8% x 9 Years, 3%
x 24 years, all result in about a doubling of the initial investment.

The PMT Function

The retirement discussion immediately leads us to discussing two other Excel
functions. For retirement you are often trying to accumulate some amount of
savings, so need to figure out either how much to save every period or given some
amount of savings how long until you reach your desired target. We look at the
amount issue first.

Suppose in 25 years you and your partner want $1 million in your retirement
account. IF the average rate of growth (the rate you earn on your invested funds) is
5%, how much must you save every year. To find this annual payment we use the
PMT function in Excel. The PMT function solves for a single payment amount that
will be made every year. It doesn’t allow for increasing the retirement contribution
over time. We will look at that situation at the end of this primer.

The PMT function has the following format:

PMT(RATE,NPER,PV,FV,TYPE)

The ordering and definition of inputs is similar to the other functions we have
introduced. We will apply the function to the retirement problem outlined above. If
we are starting with no savings, PV will be zero, FV is our target amount of $1
million, RATE is 5% and NPER is 25, so the complete function is:

=PMT(5%,25,0,1000000,0)

($20,952.46)

A year-end deposit of about $21,000 per year for 25 years will accumulate to $1
million if the deposits earn 5% per year interest. You can see that the TYPE input is
zero, meaning end-of-period deposits.

Suppose that you have already saved $150,000. This would be your PV amount, so
the PMT function would be changed as follows:
 =PMT(5%,25,-150000,1000000,0)

($10,309.59)

Notice that the PV is signed negative. This is because we are assuming that you
deposit $150,000 today (or have $150,000 in a 401K or something similar) so it is
money that is moving away from you into the bank or investment fund. The annual
contributions are also signed negative because they are moving away from you into
your retirement account. This points out how important it is to think about the
direction funds are flowing. Suppose you had entered the function with the
$150,000 signed positive. Then the result would have been:

=PMT(5%,25,150000,1000000,0) = ($31,595.33)

Hopefully, you would have recognized that this is an incorrect answer. If you start
with some savings the annual payments should be less than the $20,952 annual
deposit needed when we had no starting balance in our account. One thing WE see
in BUSN 6640 is people go through the mechanics but don’t ask if their answer
seems reasonable. You need to do this. Sometimes you make an arithmetic error or
inadvertently copy something incorrectly in a spreadsheet, so you need to be able to
evaluate whether your final answer makes sense.

PMT Function Self-test

1) How much must you save per year for 30 years to accumulate $1 million if your
savings will earn 5% per year?

2) You have $800,000 saved when you retire. How much can you withdraw every
year (at the beginning of the year) if you anticipate a 20-year retirement? Assume
the balance in the savings account will grow at 5%.

3) You are filling out financial aid forms for your college-bound daughter. You have
saved $42,000 for her education. The forms ask how much you can contribute to
expenses. If her college fund earns 4% per year, how much can you contribute from
this fund for 4 years; that is, what PMT can be made each year for 4 years? Assume
that you are completing the forms one-year before the first payment will be made.
This implies that payments are made at the end of the period (the first is made one
year from today).

PMT Self-test Solutions

1) You want to find the PMT with NPER set at 30, FV at $1 million, PV at zero and
RATE at 5%. The result with these inputs will be:

=PMT(5%,30,0,1000000,0) = ($15,051.44)

2) You want to find the PMT that can be made from a PV of $800,000 for 20 years at
5%. TYPE will be 1 since you withdraw your living allowance at the beginning of the
period. We assume FV will be zero since it wasn’t specified otherwise.
 =PMT(5%,20,-800000,0,1) = $61,137.21

3) The amount you can send to the school:

=PMT(4%,4,42000,0,0) = ($11,570.58)

The $42,000 divided by 4 would be $10,500 but the interest earned on the unspent
balance adds a little to this amount.

The NPER Function

In the discussion about retirement we asked how long it would take to accumulate
some target amount. The Excel NPER function helps us answer that question. The
format of the NPER function is:

NPER(RATE, PMT, PV, FV, TYPE)

We will apply it how answering how many years it will take to accumulate $1
million if we can save $20,000 per year and expect to earn a 4% rate of return.
Before we begin look back at the result the payment required to reach $1 million for
5% and 25 years. That answer was $20,952. With a slightly lower annual
contribution and a lower growth rate, we know that reaching $1 million will take
longer than 25 years. If we get a result less than 25 years we know that we made a
mistake somewhere. Entering the inputs, assuming no initial balance, we have:

NPER(RATE, PMT, PV, FV, TYPE)

=NPER(4%, -20000, 0, 1000000, 0) = 28.01 years

Now suppose we had our $150,000 starting balance. How long to reach $1 million?

=NPER(4%, -20000, -150000, 1000000, 0) = 21.32 years

NPER Function Self-test

1) How long will it take to accumulate $1 million if your save $35,000 per year and
your savings will earn 5% per year? Assume year-end deposits.

2) You have $800,000 saved when you retire. How long will that last if you
withdraw $60,000 per year? Assume the balance in the savings account will grow at
5% and withdrawals occur at the beginning of the period.

3) Your daughter loves animals and goes to veterinary school. She gets her degree
but has accumulated $80,000 of debt doing so. How long will it take her to repay
this loan if she pays $6,000 per year. The loan has an interest rate of 3%. Assume
that annual payments are made at the end of the period (the first is made one year
from today).
NPER Self-test Solutions

1) The NPER function will have the following inputs:

=NPER(5%,-35000,0,1000000,0) = 18.18 years

2) You want to find NPER given a PV of $800,000, PMT of $60,000 and a RATE of
5%. TYPE will be 1 since you withdraw your living allowance at the beginning of the
period. We assume FV will be zero since it wasn’t specified otherwise.

=NPER(5%,60000,-800000,0,1) = 20.65 years

3) Repaying the $80,000 loan will take:

=NPER(3%,-6000,80000,0,0) = 17.28 years

The RATE Function

This is the last finance function we will introduce in this primer. It computes the
rate that equates the PV, FV, NPER and PMT variables. The RATE function has one
input variable that the other functions don’t have GUESS. If you are curious about
why GUESS is only in the RATE function see the box below. You can leave GUESS
blank most of the time and everything will be fine.

GUESS in the RATE function

If you look at any of the mathematical equations for PV, FV etc. you see that the (1 +
RATE) term is raised to some power (NPER is the exponent); that is where the
exponent of exponential growth takes effect. So these expressions are polynomials
in the RATE variable. Recalling your math classes, a polynomial equation can have
as many roots (a root is a value at which the equation equals zero) as the highest
power the variable is raised to. This means that if NPER is large there can be
multiple solutions to the RATE function. Adding a GUESS term locates a
neighborhood in which you think the appropriate root will reside, eliminating
extraneous solutions. Most of the time the multiple answer problem doesn’t arise.
If you have a series of cash flows with sign changes (a mix of inflows and outlays) it
is possible for an equation to have multiple solutions. In this case adding the GUESS
input is probably warranted.

The RATE function has the following format:

RATE(NPER,PMT,PV,FV,TYPE,GUESS)

We will demonstrate the RATE function using the example of a corporate bond. You
can buy a Caterpillar bond that matures in 2031 and has a 7.3% coupon rate for
$1,475.60. The 7.3% coupon rate translates into $73.00 of interest per year. At
maturity the bond will pay its face value of $1,000. If we assume annual interest
payments, as of January 2013, we have 18 payments remaining, so NPER will be 18.
For GUESS we will enter 5%. We chose this number because we know the RATE
solution will be less than 7.3% because the price is higher than $1,000. Entering the
inputs into the RATE function we have:

RATE(NPER,PMT,PV,FV,TYPE,GUESS)

RATE(18,73,-1475.6,1000,0,5%)= 3.649%

The price of $1,475.60 was entered as a negative number because that is what we
pay (it is a cash outlay). The $73.00 is positive because that is money that we collect
or that flows to us, as is the $1,000.

If the price today for this bond was $1,000 (it is selling at par or face value) then the
result would have been:

=RATE(18,73,-1000,1000,0,5%) = 7.30%

When the price is the face value then the rate of return is the coupon rate.

RATE Function Self-test

1) A bond pays annual interest of $55. The bond matures in 9 years at which time it
will repay its $1,000 face value. If the bond’s price today is $1,090 and interest is
paid at the end of the period, what rate of return will you earn if you buy the bond
and hold it to maturity? This is called the “Yield-to-Maturity.”

2) A used car dealer offers this choice: you can pay $10,000 cash today or you can
make two annual payments (the first will be one-year from today and the second
two years from today) of $6,000 each. What is the implied interest rate of the two-
payment option?

3) A supplier offers these terms: 2% 10/30. This translates into a 2% discount if

paid within 10 days, but the full amount must be paid within 30 days. If you
purchase $1,000 of materials you can pay $980 on Day 10 or $1,000 on Day 30.
What is the implied interest rate of this cash discount offer?
RATE Self-test Solutions

1) The RATE function will have the following inputs:

=RATE(9,55,-1090,1000,0,4%) = 4.27%

2) You want to find the RATE that equates a PV of $10,000 to the two $6,000 annual
payments.

=RATE(2,-6000,10000,0,0) = 13.07%

3) This is a tricky one. PV is $980 and FV is $1,000. NPER is 20/365 because we

want an annual rate.
 =RATE(20/365,0,980,-1000,0,20%) = 44.59%

This is the annual compound rate of interest, and assumes that the $20 savings
occur every 20 days all year, and that they are reinvested at the 44.59% rate. It also
uses a slightly higher discount that 2%. It uses 20/980 = 2.0408%. The formula
would be (1.020408)(365/20) – 1 = 44.59%

If you eliminate the reinvestment assumption you would compute the implied
interest rate as 2.0408% x (365/20) = 37.24%. It would be very unusual for a
business to be able to reinvest at 44%, so the method with the 37% result is
probably more realistic.

Other than annual rates and compounding periods

Several places WE have mentioned that our assumption about annual payments or
annual compounding doesn’t apply to actual financial contracts, but is used to
simplify the introduction to the Excel functions. In this section WE show how to
modify the inputs to accommodate monthly or semi-annual payments. Once you see
how it is done you will be able to adjust the inputs for whatever time period you
need.

The process is quite simple. For semi-annual payments you simply count the
number of semi-annual periods (twice the number of years since there are two
semi-annual periods per year) and divide the interest rate by two. For months,
multiply the years by 12 and divide the annual rate by 12.

Monthly example: A car costs $32,000. You will make monthly payments over 5
years at a 6% annual rate. How large will your monthly payments be?

Five years of monthly payments is 60 payments. The monthly rate is 6%/12 = 0.5%.
PV is -$32,000 and FV is zero, since you will pay off the car at the end of the 5 years
period. The TYPE is zero because we make payments at the end of the period so
some interest can build up. So the monthly payment will be:

PMT(RATE,NPER,PV,FV,TYPE)

=PMT(0.5%,60, 32000,0,0)

= ($618.65)

Your monthly payments would be $618.65.

Home mortgage example: We refinanced our house about two years ago with a
10-year mortgage at 4.25%. The amount we refinanced was $120,000. What are
our monthly payments? Notice that WE included a arithmetic operation to compute
the monthly interest cost rather than entering it manually.

PMT(RATE,NPER,PV,FV,TYPE)
 =PMT(4.25%/12,120, 120000,0,0)

= ($1,229.25)

We plan to pay off the mortgage in 5 years. To do, this how much do we need to pay
each month?

PMT(RATE,NPER,PV,FV,TYPE)

=PMT(4.25%/12,60, 120000,0,0)

= ($2,223.55)

Compare the total interest paid with the 10-year and 5-year payoff plans. Total
interest is the difference between the total payments (Payment x months) and the
amount of the original loan ($120,000)

Payment Months Total Paid Interest

($1,229.25) 120 $147,510.05 $27,510.05
($2,223.55) 60 $133,412.80 $13,412.80
Savings $14,097.25

Quarterly retirement Example

You will have $800,000 saved when you retire. How long will that last if you
withdraw $15,000 per quarter ($60,000 per year)? Assume the balance in the
savings account will grow at 5% and withdrawals occur at the beginning of the
period.

We solved this for annual withdrawals and found that NPER was 20.65 years. With
quarterly withdrawals we need to adjust the amount withdrawn from $60,000 to
$15,000 and the periodic interest rate from 5% to 5%/4=1.25% Using these inputs
we find:

=NPER(1.25%,15000,-800000,0,1) = 86.47

Wow! 86 Years! No, these are quarters so we need to divide by 4. The $800,000
will last 21.62 years. The slight postponement of withdrawals, so the remaining
balance earns a little more interest, extends the life of the fund for about a year-and-
a-half.

Other Compounding Periods Self-test

1) You are considering taking out a 30-year mortgage to buy a new home. You will
borrow $270,000 at an annual rate of 4.8%. What will your monthly payments be?

2) A rent-to-own store offers a 42’ flat screen TV for $124.99 per month for 12
months? If the purchaser makes all the rental payments they own the TV. The same
model TV sells for $989.00 at a large appliance retailer. What is the implied interest
rate of the rent-to-own deal? Since these are rental payments they occur at the
beginning of the period.

3) As part of our daughter’s college savings we put $4,000 into a 6-year certificate
of deposit with an annual rate of 4%, but with quarterly compounding. What will
the CD be worth at the end of 6 years?

Other Compounding Periods Self-test Solutions

1) The PMT function will have the following inputs:

=PMT(4.8%/12,360,270000,0,0) = ($1,416.60)

2) You want to find the RATE that equates a PV of $989.00 to the twelve $124.99
monthly rental payments.

=RATE(12,-124.99,989,0,1,10%) = 8.67%

This seems like a reasonable rate until you realize that this is the monthly rate! We
have two ways to annualize a monthly rate. If we want the compound rate we use:

(1 + Monthly Rate)12 – 1

1.086712 – 1 = 171.21%

If we don’t want compounding we would just multiply the monthly rate by 12.

12 x 0.0867 = 104.04%

3) PV is $4,000, the RATE is 4%/4. NPER is 4 times 6 years or 24 quarters and PMT
is zero.

=FV(1%,24,0,-4000,0) = $5,078.94

Increasing payments: An Example of Modeling

In the retirement examples we assumed that the same amount was contributed
every year, but it is much more likely that as salaries increase contributions go up.
We can model such growing contributions using Excel. Suppose a person’s
contributions start at $15,000 a year and increase by 2% per year for 30 years. How
much will the person accumulate after 30 years is invested funds earn 4%?

Here is the spreadsheet solution with the formulas displayed.

In column B we increase the initial $15,000 by 2% per year by multiplying by 1.02.
In cell B3 we multiply B2 by 1.02 or 15000 by 1.02. In cell B4, we multiply the B3 by
1.02 or we multiply 15000 time (1.02)2. In column C we begin with$15,000 (=B2)
then in cell C3 we multiply the $15,000 by 1.04 to reflect the investment income of
4% and we add the value from B3, our second year contribution.

Here is the spreadsheet with values displayed.

Here is the bottom of the data.

By Year 30 the contribution has grown from $15,000 to $26,637.67 and the total
amount contributed, plus investment income of 4%, is $1.074 million. This should
give you some ideas about how versatile Excel can be. You are limited to the
functions. Instead you can model almost any pattern of cash flows.

Spreadsheet Modeling Self-test

A private equity firm is considering investing in a business that will produce annual
cash flows starting at $2.5 million and increasing by 5% per year for 6 years. At the
end of 6 years the firm will sell the company $30 million. If the firm sets its hurdle
rate (the minimum rate of return it must earn on an investment) at 20%, what is the
most it can pay for the company today?

Spreadsheet Modeling Self-test Solutions

Here is my solution.
Here is the solution with the formulas displayed. Column B grows the initial annual
cash flow of $2.5 million by 5% per year. In cell B7 we add the $30 million sales
price to the annual cash flow. In column C we compute the PV of each of the annual
cash flows. Cell C9 sums the PVs to get today’s price. Cell C11 shows that we could
also use the NPV function to find the PV of the cash flows. Notice that it refers to the
cash flows in column B not the already discounted cash flows in column C.

The End