ABAP 7.

40 Quick Reference
72304922,983

Contents
1. Inline Declarations
2. Table Expressions
3. Conversion Operator CONV
4. Value Operator VALUE
5. FOR operator
6. Reduction operator REDUCE
7. Conditional operators COND and SWITCH
8. CORRESPONDING operator
9. Strings
10. Loop at Group By
11. Classes/Methods
12. Meshes
13. Filter
14. Document Purpose

1. Inline Declarations
Before 7.40 With 7.40
Data
DATA text TYPE string. DATA(text) = 'ABC'.
text = 'ABC'.

Loop at
into DATA wa like LINE OF itab. LOOP AT itab INTO DATA(wa).
work LOOP AT itab INTO wa. ...
... ENDLOOP.
area
ENDLOOP.

Call
method DATA a1 TYPE ... oref->meth(
DATA a2 TYPE ... IMPORTING p1 = DATA(a1)
IMPORTING p2 = DATA(a2) ).
oref->meth(
IMPORTING p1 = a1
IMPORTING p2 = a2 ).

Loop at
assignin FIELD-SYMBOLS: <line> type … LOOP AT itab
g ASSIGNING FIELD-SYMBOL(<line>).
LOOP AT itab ASSIGNING ...

1
 <line>. ENDLOOP.
...
ENDLOOP.

Read
assignin FIELD-SYMBOLS: <line> type … READ TABLE itab
g ASSIGNING FIELD-SYMBOL(<line>).
READ TABLE itab
ASSIGNING <line>.

Select
into tabl DATA itab TYPE TABLE OF SELECT * FROM dbtab
e dbtab. INTO TABLE @DATA(itab)
WHERE fld1 = @lv_fld1.
SELECT * FROM dbtab
INTO TABLE itab
WHERE fld1 = lv_fld1.

Select
single SELECT SINGLE f1 f2 SELECT SINGLE f1 AS my_f1,
into FROM dbtab f2 AS abc
INTO (lv_f1, lv_f2) FROM dbtab
WHERE ... INTO DATA(ls_struct)
WHERE ...
WRITE: / lv_f1, lv_f2.
WRITE: / ls_struct-my_f1,
ls_struct-abc.

2. Table Expressions
If a table line is not found, the exception CX_SY_ITAB_LINE_NOT_FOUND is raised. No sy-
subrc.

Before 7.40 With 7.40

Read Table
index READ TABLE itab INDEX wa = itab[ idx ].
idx
INTO wa.

Read Table
using key READ TABLE itab INDEX wa = itab[ KEY key INDEX idx ].
idx
USING KEY key
INTO wa.

2
 Read Table
with key READ TABLE itab wa = itab[ col1 = … col2 = … ].
WITH KEY col1 = …
col2 = …
INTO wa.

Read Table
with key READ TABLE itab wa = itab[ KEY key col1 = …
components WITH TABLE KEY key col2 = … ].
COMPONENTS col1 = …
col2 = …
INTO wa.

Does record
exist? READ TABLE itab ... IF line_exists( itab[ ... ] ).
TRANSPORTING NO ...
FIELDS. ENDIF.

IF sy-subrc = 0.
...
ENDIF.

Get table
index DATA idx type sy- DATA(idx) =
tabix. line_index( itab[ ... ] ).

READ TABLE ...

TRANSPORTING NO
FIELDS.
idx = sy-tabix.

NB: There will be a short dump if you use an inline expression that references a non-existent record.

SAP says you should therefore assign a field symbol and check sy-subrc.

ASSIGN lt_tab[ 1 ] to FIELD-SYMBOL(<ls_tab>).

IF sy-subrc = 0.
...
ENDIF.

NB: Use itab [ table_line = … ] for untyped tables.

3. Conversion Operator CONV

I. Definition

3
CONV dtype|#( … )

dtype = Type you want to convert to (explicit)

# = compiler must use the context to decide the type to convert to

(implicit)

II. Example
Method cl_abap_codepage=>convert_to expects a string

Before 7.40

DATA text TYPE c LENGTH 255.

DATA helper TYPE string.
DATA xstr TYPE xstring.

helper = text.

xstr = cl_abap_codepage=>convert_to( source = helper ).

With 7.40

DATA text TYPE c LENGTH 255.

DATA(xstr) = cl_abap_codepage=>convert_to( source = CONV string( text ) ).

OR

DATA(xstr) = cl_abap_codepage=>convert_to( source = CONV #( text ) ).

4. Value Operator VALUE

I. Definition
Variables: VALUE dtype|#( )

Structures: VALUE dtype|#( comp1 = a1 comp2 = a2 … )

Tables: VALUE dtype|#( ( … ) ( … ) … ) …

II. Example for structures

4
TYPES: BEGIN OF ty_columns1, “Simple structure
cols1 TYPE i,
cols2 TYPE i,
END OF ty_columns1.

TYPES: BEGIN OF ty_columnns2, “Nested structure

coln1 TYPE i,
coln2 TYPE ty_columns1,
END OF ty_columns2.

DATA: struc_simple TYPE ty_columns1,

struc_nest TYPE ty_columns2.

struct_nest = VALUE t_struct(coln1 = 1

coln2-cols1 = 1
coln2-cols2 = 2 ).

OR

struct_nest = VALUE t_struct(coln1 = 1

coln2 = VALUE #( cols1 = 1
cols2 = 2 ) ).

III. Examples for internal tables

Elementary line type:

TYPES t_itab TYPE TABLE OF i WITH EMPTY KEY.

DATA itab TYPE t_itab.

itab = VALUE #( ( ) ( 1 ) ( 2 ) ).

Structured line type (RANGES table):

DATA itab TYPE RANGE OF i.

itab = VALUE #( sign = 'I' option = 'BT' ( low = 1 high = 10 )

( low = 21 high = 30 )
( low = 41 high = 50 )
option = 'GE' ( low = 61 ) ).

5
5. FOR operator
I. Definition
FOR wa|<fs> IN itab [INDEX INTO idx] [cond]

II. Explanation
This effectively causes a loop at itab. For each loop the row read is assigned to a work area (wa) or field-
symbol(<fs>).

This wa or <fs> is local to the expression i.e. if declared in a subrourine the variable wa or <fs> is a local
variable of

that subroutine. Index like SY-TABIX in loop.

Given:

TYPES: BEGIN OF ty_ship,

tknum TYPE tknum, "Shipment Number
name TYPE ernam, "Name of Person who Created the Object
city TYPE ort01, "Starting city
route TYPE route, "Shipment route
END OF ty_ship.
TYPES: ty_ships TYPE SORTED TABLE OF ty_ship WITH UNIQUE KEY tknum.
TYPES: ty_citys TYPE STANDARD TABLE OF ort01 WITH EMPTY KEY.

GT_SHIPS type ty_ships. -> has been populated as follows:

Row TKNUM[C(10)] Name[C(12)] City[C(25)] Route[C(6)]

1 001 John Melbourn R0001
e
2 002 Gavin Sydney R0003
3 003 Lucy Adelaide R0001
4 004 Elaine Perth R0003

III. Example 1
Populate internal table GT_CITYS with the cities from GT_SHIPS.

Before 7.40

DATA: gt_citys TYPE ty_citys,

6
 Before 7.40

gs_ship TYPE ty_ship,

gs_city TYPE ort01.

LOOP AT gt_ships INTO gs_ship.

gs_city = gs_ship-city.
APPEND gs_city TO gt_citys.
ENDLOOP.

With 7.40

DATA(gt_citys) = VALUE ty_citys( FOR ls_ship IN gt_ships ( ls_ship-city ) ).

IV. Example 2
Populate internal table GT_CITYS with the cities from GT_SHIPS where the route
is R0001.

Before 7.40

DATA: gt_citys TYPE ty_citys,

gs_ship TYPE ty_ship,
gs_city TYPE ort01.

LOOP AT gt_ships INTO gs_ship WHERE route = 'R0001'.

gs_city = gs_ship-city.
APPEND gs_city TO gt_citys.
ENDLOOP.

With 7.40

DATA(gt_citys) = VALUE ty_citys( FOR ls_ship IN gt_ships

WHERE ( route = 'R0001' ) ( ls_ship-city ) ).

Note: ls_ship does not appear to have been declared but it is declared implicitly.

V. FOR with THEN and UNTIL|WHILE

FOR i = … [THEN expr] UNTIL|WHILE log_exp

Populate an internal table as follows:

7
TYPES:
BEGIN OF ty_line,
col1 TYPE i,
col2 TYPE i,
col3 TYPE i,
END OF ty_line,
ty_tab TYPE STANDARD TABLE OF ty_line WITH EMPTY KEY.

Before 7.40

DATA: gt_itab TYPE ty_tab,

j TYPE i.
FIELD-SYMBOLS <ls_tab> TYPE ty_line.j= 1.

DO.
j = j + 10.
IF j > 40. EXIT. ENDIF.
APPEND INITIAL LINE TO gt_itab ASSIGNING <ls_tab>.
<ls_tab>-col1 = j.
<ls_tab>-col2 = j + 1.
<ls_tab>-col3 = j + 2.
ENDDO.

With 7.40

DATA(gt_itab) = VALUE ty_tab( FOR j = 11 THEN j + 10 UNTIL j > 40

( col1 = j col2 = j + 1 col3 = j + 2 ) ).

6. Reduction operator REDUCE

I. Definition
… REDUCE type(
INIT result = start_value
…
FOR for_exp1
FOR for_exp2
…
NEXT …
result = iterated_value
…)

II. Note

8
 While VALUE and NEW expressions can include FOR expressions, REDUCE must include at least one
FOR expression. You can use all kinds of FOR expressions in REDUCE:
 with IN for iterating internal tables
 with UNTIL or WHILE for conditional iterations

III. Example 1
Count lines of table that meet a condition (field F1 contains “XYZ”).

Before 7.40

DATA: lv_lines TYPE i.

LOOP AT gt_itab INTO ls_itab where F1 = ‘XYZ’.

lv_lines = lv_lines + 1.
ENDLOOP.

With 7.40

DATA(lv_lines) = REDUCE i( INIT x = 0 FOR wa IN gt_itab

WHERE( F1 = ‘XYZ’ ) NEXT x = x + 1 ).

IV. Example 2
Sum the values 1 to 10 stored in the column of a table defined as follows

DATA gt_itab TYPE STANDARD TABLE OF i WITH EMPTY KEY.

gt_itab = VALUE #( FOR j = 1 WHILE j <= 10 ( j ) ).

Before 7.40

DATA: lv_line TYPE i,

lv_sum TYPE i.

LOOP AT gt_itab INTO lv_line.

lv_sum = lv_sum + lv_line.
ENDLOOP.

With 7.40

DATA(lv_sum) = REDUCE i( INIT x = 0 FOR wa IN itab NEXT x = x + wa ).

V. Example 3
Using a class reference – works because “write” method returns reference to instance object

9
 With 7.40

TYPES outref TYPE REF TO if_demo_output.

DATA(output) = REDUCE outref( INIT out = cl_demo_output=>new( )

text = `Count up:`
FOR n = 1 UNTIL n > 11
NEXT out = out->write( text )
text = |{ n }| ).
output->display( ).

7. Conditional operators COND and SWITCH

I. Definition
… COND dtype|#( WHEN log_exp1 THEN result1
[ WHEN log_exp2 THEN result2 ]
…
[ ELSE resultn ] ) …
… SWITCH dtype|#( operand
WHEN const1 THEN result1
[ WHEN const2 THEN result2 ]
…
[ ELSE resultn ] ) …

II. Example for COND

DATA(time) =
COND string(
WHEN sy-timlo < '120000' THEN
|{ sy-timlo TIME = ISO } AM|
WHEN sy-timlo > '120000' THEN
|{ CONV t( sy-timlo - 12 * 3600 )
TIME = ISO } PM|
WHEN sy-timlo = '120000' THEN
|High Noon|
ELSE
THROW cx_cant_be( ) ).

III. Example for SWITCH

DATA(text) =
NEW class( )->meth(

10
 SWITCH #( sy-langu
WHEN 'D' THEN `DE`
WHEN 'E' THEN `EN`
ELSE THROW cx_langu_not_supported( ) ) ).

8. Corresponding Operator
I. Definition
… CORRESPONDING type( [BASE ( base )] struct|itab [mapping|except] )

II. Example Code

With 7.40

TYPES: BEGIN OF line1, col1 TYPE i, col2 TYPE i, END OF line1.

TYPES: BEGIN OF line2, col1 TYPE i, col2 TYPE i, col3 TYPE i, END OF line2.

DATA(ls_line1) = VALUE line1( col1 = 1 col2 = 2 ).

WRITE: / 'ls_line1 =' ,15 ls_line1-col1, ls_line1-col2.
DATA(ls_line2) = VALUE line2( col1 = 4 col2 = 5 col3 = 6 ).
WRITE: / 'ls_line2 =' ,15 ls_line2-col1, ls_line2-col2, ls_line2-col3.
SKIP 2.

ls_line2 = CORRESPONDING #( ls_line1 ).

WRITE: / 'ls_line2 = CORRESPONDING #( ls_line1 )'
,70 'Result is ls_line2 = '
,ls_line2-col1, ls_line2-col2, ls_line2-col3.
SKIP.

ls_line2 = VALUE line2( col1 = 4 col2 = 5 col3 = 6 ). "Restore ls_line2

ls_line2 = CORRESPONDING #( BASE ( ls_line2 ) ls_line1 ).
WRITE: / 'ls_line2 = CORRESPONDING #( BASE ( ls_line2 ) ls_line1 )'
, 70 'Result is ls_line2 = ', ls_line2-col1
, ls_line2-col2, ls_line2-col3.
SKIP.

ls_line2 = VALUE line2( col1 = 4 col2 = 5 col3 = 6 ). "Restore ls_line2

DATA(ls_line3) = CORRESPONDING line2( BASE ( ls_line2 ) ls_line1 ).
WRITE: / 'DATA(ls_line3) = CORRESPONDING line2( BASE ( ls_line2 ) ls_line1 )'
, 70 'Result is ls_line3 = ' , ls_line3-col1
, ls_line3-col2, ls_line3-col3.

III. Output

11
IV. Explanation
Given structures ls_line1 & ls_line2 defined and populated as above.

Before 7.40 With 7.40

1
CLEAR ls_line2. ls_line2 = CORRESPONDING #( ls_line1 ).
MOVE-CORRESPONDING
ls_line1
TO
ls_line2.

2
MOVE-CORRESPONDING ls_line2 = CORRESPONDING #
ls_line1 ( BASE ( ls_line2 ) ls_line1 ).
TO
ls_line2.

3
DATA: ls_line3 like DATA(ls_line3) = CORRESPONDING line2
ls_line2. ( BASE ( ls_line2 ) ls_line1 ).

ls_line3 = ls_line2.
MOVE-CORRESPONDING
ls_line1
TO
ls_line2.

1. The contents of ls_line1 are moved to ls_line2 where there is a matching column name. Where there
is no

match the column of ls_line2 is initialised.

2. This uses the existing contents of ls_line2 as a base and overwrites the matching columns from ls_line1.

This is exactly like MOVE-CORRESPONDING.

3. This creates a third and new structure (ls_line3) which is based on ls_line2 but overwritten by matching

columns of ls_line1.

V. Additions MAPPING and EXCEPT

12
MAPPING allows you to map fields with non-identically named components to qualify for the data transfer.

… MAPPING t1 = s1 t2 = s2

EXCEPT allows you to list fields that must be excluded from the data transfer

… EXCEPT {t1 t2 …}

9. Strings
I. String Templates
A string template is enclosed by two characters “|” and creates a character string.
Literal text consists of all characters that are not in braces {}. The braces can contain:
 data objects,
 calculation expressions,
 constructor expressions,
 table expressions,
 predefined functions, or
 functional methods and method chainings
Before 7.40

DATA itab TYPE TABLE OF scarr.

SELECT * FROM scarr INTO TABLE itab.

DATA wa LIKE LINE OF itab.

READ TABLE itab WITH KEY carrid = 'LH' INTO wa.

DATA output TYPE string.

CONCATENATE 'Carrier:' wa-carrname INTO output SEPARATED BY space.

cl_demo_output=>display( output ).

With 7.40

SELECT * FROM scarr INTO TABLE @DATA(lt_scarr).

cl_demo_output=>display( |Carrier: { lt_scarr[ carrid = 'LH' ]-carrname }| ).

II. Concatenation

Before 7.40

DATA lv_output TYPE string.

13
 Before 7.40

CONCATENATE 'Hello' 'world' INTO lv_output SEPARATED BY space.

With 7.40

DATA(lv_out) = |Hello| & | | & |world|.

III. Width/Alignment/Padding

WRITE / |{ 'Left' WIDTH = 20 ALIGN = LEFT PAD = '0' }|.

WRITE / |{ 'Centre' WIDTH = 20 ALIGN = CENTER PAD = '0' }|.
WRITE / |{ 'Right' WIDTH = 20 ALIGN = RIGHT PAD = '0' }|.

IV. Case

WRITE / |{ 'Text' CASE = (cl_abap_format=>c_raw) }|.

WRITE / |{ 'Text' CASE = (cl_abap_format=>c_upper) }|.
WRITE / |{ 'Text' CASE = (cl_abap_format=>c_lower) }|.

V. ALPHA conversion

DATA(lv_vbeln) = '0000012345'.
WRITE / |{ lv_vbeln ALPHA = OUT }|. “or ALPHA = IN to go in other direction

VI. Date conversion

WRITE / |{ pa_date DATE = ISO }|. “Date Format YYYY-MM-DD

WRITE / |{ pa_date DATE = User }|. “As per user settings
WRITE / |{ pa_date DATE = Environment }|. “As per Environment

10. Loop at Group By

I. Definition

LOOP AT itab result [cond] GROUP BY key ( key1 = dobj1 key2 = dobj2 …
[gs = GROUP SIZE] [gi = GROUP INDEX] )

14
[ASCENDING|DESCENDING [AS TEXT]]
[WITHOUT MEMBERS]
[{INTO group}|{ASSIGNING <group>}]
…
[LOOP AT GROUP group|<group>
…
ENDLOOP.]
…

ENDLOOP.

II. Explanation

The outer loop will do one iteration per key. So if 3 records match the key there will only be one iteration
for these 3 records. The structure “group” (or
“<group>” ) is unusual in that it can be looped over using the “LOOP AT GROUP” statement. This will
loop over the 3 records (members) of the group. The
structure “group” also contains the current key as well as the size of the group and index of the group ( if
GROUP SIZE and GROUP INDEX have been
assigned a field name). This is best understood by an example.

III. Example

With 7.40

TYPES: BEGIN OF ty_employee,

name TYPE char30,
role TYPE char30,
age TYPE i,
END OF ty_employee,

ty_employee_t TYPE STANDARD TABLE OF ty_employee WITH KEY name.

DATA(gt_employee) = VALUE ty_employee_t(

( name = 'John' role = 'ABAP guru' age = 34 )
( name = 'Alice' role = 'FI Consultant' age = 42 )
( name = 'Barry' role = 'ABAP guru' age = 54 )
( name = 'Mary' role = 'FI Consultant' age = 37 )
( name = 'Arthur' role = 'ABAP guru' age = 34 )
( name = 'Mandy' role = 'SD Consultant' age = 64 ) ).

DATA: gv_tot_age TYPE i,

gv_avg_age TYPE decfloat34.

"Loop with grouping on Role

LOOP AT gt_employee INTO DATA(ls_employee)
GROUP BY ( role = ls_employee-role
size = GROUP SIZE
index = GROUP INDEX )

15
 With 7.40

ASCENDING
ASSIGNING FIELD-SYMBOL(<group>).

CLEAR: gv_tot_age.

"Output info at group level

WRITE: / |Group: { <group>-index } Role: { <group>-role WIDTH = 15 }|
& | Number in this role: { <group>-size }|.

"Loop at members of the group

LOOP AT GROUP <group> ASSIGNING FIELD-SYMBOL(<ls_member>).
gv_tot_age = gv_tot_age + <ls_member>-age.
WRITE: /13 <ls_member>-name.
ENDLOOP.

"Average age
gv_avg_age = gv_tot_age / <group>-size.
WRITE: / |Average age: { gv_avg_age }|.

SKIP.

ENDLOOP.

IV. Output

Group: 1 Role: ABAP guru Number in this role: 3

John
Barry
Arthur
Average age: 40.66666666666666666666666666666667
Group: 2 Role: FI Consultant Number in this role: 2
Alice
Mary
Average age: 39.5
Group: 3 Role: SD Consultant Number in this role: 1
Mandy
Average age: 64

11. Classes/Methods
I. Referencing fields within returned structures

16
 Before 7.40

DATA: ls_lfa1 TYPE lfa1,

lv_name1 TYPE lfa1-name1.

ls_lfa1= My_Class=>get_lfa1( ).
lv_name1 = ls_lfa1-name1.

With 7.40

DATA(lv_name1) = My_Class=>get_lfa1( )-name1.

II. Methods that return a type BOOLEAN

Before 7.40

IF My_Class=>return_boolean( ) = abap_true.
…
ENDIF.

With 7.40

IF My_Class=>return_boolean( ).
…
ENDIF.

NB: The type “BOOLEAN” is not a true Boolean but a char1 with allowed values X,- and <blank>.
Using type “FLAG” or “WDY_BOOLEAN” works just as well.

III. NEW operator

This operator can be used to instantiate an object.

Before 7.40

DATA: lo_delivs TYPE REF TO zcl_sd_delivs,

lo_deliv TYPE REF TO zcl_sd_deliv.

CREATE OBJECT lo_delivs.

CREATE OBJECT lo_deliv.

17
 Before 7.40

lo_deliv = lo_delivs->get_deliv( lv_vbeln ).

With 7.40

DATA(lo_deliv) = new zcl_sd_delivs( )->get_deliv( lv_vbeln ).

12. Meshes
Allows an association to be set up between related data groups.

I. Problem

Given the following 2 internal tables:

TYPES: BEGIN OF t_manager,

name TYPE char10,
salary TYPE int4,
END OF t_manager,
tt_manager TYPE SORTED TABLE OF t_manager WITH UNIQUE KEY name.

TYPES: BEGIN OF t_developer,

name TYPE char10,
salary TYPE int4,
manager TYPE char10, "Name of manager
END OF t_developer,
tt_developer TYPE SORTED TABLE OF t_developer WITH UNIQUE KEY name.

Populated as follows:

Row Name[C(10)] Salary[I(4)]

1 Jason 3000
2 Thomas 3200
Row Name[C(10) Salary[I(4) Manager[C(10)
] ] ]
1 Bob 2100 Jason
2 David 2000 Thomas
3 Jack 1000 Thomas
4 Jerry 1000 Jason
5 John 2100 Thomas

18
6 Tom 2000 Jason

II. SolutionGet the details of Jerry’s manager and all developers managed by Thomas.

With 7.40

TYPES: BEGIN OF MESH m_team,

managers TYPE tt_manager ASSOCIATION my_employee TO developers
ON manager = name,
developers TYPE tt_developer ASSOCIATION my_manager TO managers
ON name = manager,
END OF MESH m_team.

DATA: ls_team TYPE m_team.

ls_team-managers = lt_manager.
ls_team-developers = lt_developer.

*Get details of Jerry's manager *

"get line of dev table

ASSIGN lt_developer[ name = 'Jerry' ] TO FIELD-SYMBOL(<ls_jerry>).
DATA(ls_jmanager) = ls_team-developers\my_manager[ <ls_jerry> ].

WRITE: / |Jerry's manager: { ls_jmanager-name }|,30

|Salary: { ls_jmanager-salary }|.

"Get Thomas' developers

SKIP.
WRITE: / |Thomas' developers:|.

"line of manager table

ASSIGN lt_manager[ name = 'Thomas' ] TO FIELD-SYMBOL(<ls_thomas>).
LOOP AT ls_team-managers\my_employee[ <ls_thomas> ]
ASSIGNING FIELD-SYMBOL(<ls_emp>).
WRITE: / |Employee name: { <ls_emp>-name }|.
ENDLOOP.

III. Output
Jerry’s manager: Jason Salary: 3000

Thomas’ developers:

Employee name: David

Employee name: Jack

Employee name: John

19
13. Filter
Filter the records in a table based on records in another table.

I. Definition
… FILTER type( itab [EXCEPT] [IN ftab] [USING KEY keyname]
WHERE c1 op f1 [AND c2 op f2 […]] )

II. Problem
Filter an internal table of Flight Schedules (SPFLI) to only those flights based on a filter table that contains the
fields Cityfrom and CityTo.

III. Solution

With 7.40

TYPES: BEGIN OF ty_filter,

cityfrom TYPE spfli-cityfrom,
cityto TYPE spfli-cityto,
f3 TYPE i,
END OF ty_filter,
ty_filter_tab TYPE HASHED TABLE OF ty_filter
WITH UNIQUE KEY cityfrom cityto.
DATA: lt_splfi TYPE STANDARD TABLE OF spfli.

SELECT * FROM spfli APPENDING TABLE lt_splfi.

DATA(lt_filter) = VALUE ty_filter_tab( f3 = 2

( cityfrom = 'NEW YORK' cityto = 'SAN FRANCISCO' )
( cityfrom = 'FRANKFURT' cityto = 'NEW YORK' ) ).

DATA(lt_myrecs) = FILTER #( lt_splfi IN lt_filter

WHERE cityfrom = cityfrom
AND cityto = cityto ).

“Output filtered records

LOOP AT lt_myrecs ASSIGNING FIELD-SYMBOL(<ls_rec>).
WRITE: / <ls_rec>-carrid,8 <ls_rec>-cityfrom,30
<ls_rec>-cityto,45 <ls_rec>-deptime.
ENDLOOP.

Note: using the keyword “EXCEPT” (see definition above) would have returned the exact opposite records i.e
all records EXCEPT for those those returned above.

20
14. Document Purpose
So you’re an experienced ABAP programmer wanting to leverage off the fantastic new functionality
available to you in ABAP 7.40!

However, searching for information on this topic leads you to fragmented pages or blogs that refer to only a
couple of the new features available to you.

What you need is a quick reference guide which gives you the essentials you need and shows you how the
code you are familiar with can be improved with ABAP 7.40.

The below document contains exactly this!

It gives examples of “classic” ABAP and its 740 equivalent. It goes into more details on the more difficult
topics normally via examples. This allows the reader to dive in to the level they desire. While this document
does not contain everything pertaining to ABAP 740 it certainly covers the most useful parts in the experience
of the author.

The document has been compiled by drawing on existing material available online as well as trial and error by
the author. In particular the blogs by Horst Keller have been useful and are the best reference I have found
(prior to this document ). He has a landing page of sorts for his various blogs on the topic here:

ABAP Language News for Release 7.40

Credit also goes to Naimesh Patel for his useful explanations and examples on ABAP 7.40. Here is his
example of the “FOR iteration expression” which I leaned on (links to his other 740 articles can be found at the
bottom of the link):

http://zevolving.com/2015/05/abap-740-for-iteration-expression/

I compiled the below document to make the transition to using ABAP 740 easier for myself and my project
team. It has worked well for us and I hope it will do the same for you.
FollowLikeRSS Feed
Alert Moderator
Assigned Tags

 740
 ABAP Development
 SAP NetWeaver
 abap
 document
 overveiw
 reference

View more...

21
Similar Blog Posts
 ABAP News for Release 7.40 - What is ABAP 7.40?
By Horst KellerMay 22, 2013
 ABAP News for Release 7.50 - What is ABAP 7.50?
By Horst KellerOct 20, 2015
 Old and new ABAP syntax - overview sheet
By Thomas KrüglMar 02, 2016
Related Questions
 SE21 - what happend to PACKTYPE ?
By Joachim ReesJan 11, 2017
 ABAP code for multiple releases
By Phil SoadyApr 13, 2016
 SapGui problem
By Morales Lozano Joel AngelJul 23, 2013
72 Comments
You must be Logged on to comment or reply to a post.

Jitendra Soni
October 25, 2015 at 1:42 pm

Hi Jeffrey,

Very informative blog.

Below syntax is not working for me.

"SELECT * FROM dbtab INTO TABLE @DATA(lt_dbtab) WHERE field1 = @lv_field1."

ABAP version:

SAP_BASI 74 000 SAPKB740 000 - SAP Basis Component

S 0 7 07 0
SAP_ABA 74 000 SAPKA740 000 - Cross-Application
0 7 07 0 Component
 Like 0
 Share

Jeffrey Towell

22
Blog Post Author
October 26, 2015 at 8:42 am

Thanks Jitendra.

I am not sure which bits of ABAP 7.40 come in with exactly which version but
here is some working code. If this does not work on your box then its fair to say
you do not have the relevant version yet.

DATA: lv_bukrs type bukrs VALUE '0001'.

SELECT * FROM t001 INTO TABLE @DATA(lt_t001)

WHERE bukrs = @lv_bukrs.

 Like 0
 Share

Christiano José Beltrão Magalhães

October 26, 2015 at 12:20 pm

Hi Jitendra/Jeffrey,

the new open sql syntax was created in ABAP 7.40 SP05 and enhanced in SP08.
More information in ABAP News for 7.40, SP08 - Open SQL.

Jeffrey, great blog... very useful.

BR,

Christiano.
 Like 0
 Share

Paul Bakker

23
October 25, 2015 at 9:52 pm

Thanks for going to so much effort! Very interesting reading.

Unfortunately some of the code (inside the black borders) is truncated on the

right hand side. But I think we can work it out

cheers

Paul
 Like 0
 Share

Jeffrey Towell
Blog Post Author
October 26, 2015 at 12:10 am

Thanks for your comments Paul.

Was also concerned about truncation on the right but found that if you click on
the text and drag to the right that it all becomes visible. Alternatively the scroll
bar at the bottom works but it's a bit inconvenient scrolling down to find it.

Cheers,

Jeff
 Like 0
 Share

Former Member
October 26, 2015 at 5:03 am
Very much useful document Paul!
 Like 0

24
  Share

Manu Kapur
October 26, 2015 at 11:22 am

Brilliant. Thanks for sharing.

 Like 0
 Share

Raphael Pacheco
October 26, 2015 at 11:45 am

Great post Jeffrey !

Just a suggestion ... I believe that would be less harmful to the blocks with commands have

the edges a little thinner.

 Like 0
 Share

Jeffrey Towell
Blog Post Author
October 26, 2015 at 12:05 pm
Good point Raphael! If I can find a relatively easy way to do that I think I will.
 Like 0
 Share

Former Member
October 27, 2015 at 1:18 pm
Brilliant, looking forward for future blogs..
 Like 0
 Share

25
Former Member
October 28, 2015 at 12:20 pm
very helpful, can't wait to use some of the inline expressions
 Like 0
 Share

Guy Lamoureux
October 28, 2015 at 1:34 pm
Very Interesting. But I see that clarity and "ease of reading"continues to be

vastly underestimated and undervalued. ABAP is going to the dark side

 Like 2
 Share

Jeffrey Towell
Blog Post Author
October 29, 2015 at 2:30 am
Guy, I thought the exact same thing at first along with others I have chatted to.
However, after using it a while I realise it becomes more clear as you get more
familiar with the syntax. After years of using the old syntax it has become so
familiar to us that it feels like we have to think too much to understand what is
being coded in the new syntax. Soon it will be second nature to you and hence
easy to read.
 Like 1
 Share

Guy Lamoureux
October 29, 2015 at 11:37 am

Hi Jeffrey,

"after using it a while" the problem is right here. Not everybody is an ABAP
programmer and not everybody programs in ABAP on a regular base. I've seen a
lot of functional analyst who can follow what's going on in an ABAP program.
They do it for many reasons but it's part of their job and the more we change the
language to something more obscure, the less they will be able to do it. They will
need help from ABAP programmers. This will slow down the process.

26
On my part, I've worked as an ABAP programmer for 10 years, followed by 10
years of BW developement. I don't write ABAP code on a regular base. This new
syntax will keep being obscure.
 Like 1
 Share

Christoph Schreiner
October 29, 2015 at 7:59 am

Nice overview, thanks for sharing it with us!

 Like 0
 Share

Former Member
November 8, 2015 at 10:56 am
Great job! Thank you for making our life easy...
 Like 0
 Share

Aslam MD

27