Windows에서 Rscript.exe 찾기

Windows 컴퓨터에서 Rscript를 실행하고 싶습니다. 이를 위해서는 Rscript가 %PATH%에 없기 때문에 정확한 위치를 찾아야 합니다. stackoverflow를 검색하다가 이 방법을 찾았습니다.

where /r "c:\Program Files" Rscript.exe

세 줄을 생성합니다.

c:\Program Files\R\R-3.6.2\bin\Rscript.exe
c:\Program Files\R\R-3.6.2\bin\i386\Rscript.exe
c:\Program Files\R\R-3.6.2\bin\x64\Rscript.exe

이제 진행 방법을 모르겠습니다. Windows cmd의 (로컬) 환경 변수에 세 줄 중 하나를 어떻게 할당할 수 있습니까? 이상적으로는 첫 번째 또는 세 번째 줄, 즉 x64 rscript.exe입니다.

SO에서 찾은 또 다른 접근 방식은 다음과 같습니다.

set "src=c:\Program Files"
set "search=Rscript.exe"

for /r "%src%" %%F in (*%search%*) do (
  set "full=%%~fF"
  set "name=%%~nxF"
  echo %full%
)

하지만 %full%에는 아무 것도 할당되지 않습니다.

두 대 이상의 컴퓨터에서 배치 파일을 실행하고 싶기 때문에 이러한 컴퓨터에서 추가 구성(PATH 또는 R_HOME 설정 또는 Rscript를 .R 파일에 할당 또는...)을 수행하는 것을 피하고 싶습니다.

내가 제공하는 첫 번째 조언은 파일과 파일 연결에서 해당 위치가 레지스트리에 추가되었는지 확인하는 것 .RData입니다. 발견되면 본질적으로 다음으로 바꿀 수 RGui.exe있습니다 RScript.exe.

@Echo Off
SetLocal EnableExtensions
Set "Key=HKCU\Software\Classes\RWorkspace\Shell\Open\Command"
Set "RDir="
For /F "EOL=H Tokens=2*" %%G In ('%__AppDir__%reg.exe Query "%Key%" /VE 2^>NUL'
) Do Set "RDir=%~dpH"
If Not Defined RDir For /F "EOL=H Tokens=2*" %%G In (
    '%__AppDir__%reg.exe Query "HKLM%Key:~4%" /VE 2^>NUL') Do Set "RDir=%~dpH"
If Defined RDir Where /Q "%RDir%.":"RScript.exe" && (
    Set "RDir=%RDir%RScript.exe") || Set "RDir="
If Defined RDir Echo Your default RScript.exe absolute path is %RDir% & Pause

다른 대안은 설치 위치에 대한 레지스트리 제거 정보를 확인하고 발견된 경우 \bin하위 디렉토리와 해당 아키텍처 하위를 추가하는 것입니다.

@Echo Off
SetLocal EnableExtensions
Set "Key=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
Set "Sub=R for Windows"
Set "Val=InstallLocation"
Set "Reg=%__AppDir__%reg.exe"
Set "Find=%__AppDir__%find.exe"
Set "RDir="
For /F "EOL=H Tokens=2*" %%G In (
    '"%Reg% Query "%Key%" /S /F "%Sub%" /K /V "%Val%" 2>NUL|%Find% "\""'
) Do Set "RDir=%%H"
If Not Defined RDir If Defined PROCESSOR_ARCHITEW6432 (
    For /F "EOL=H Tokens=2*" %%G In (
        '"%Reg% Query "%Key%" /S /F "%Sub%" /K /V "%Val%" /Reg:32 2>NUL|%Find% "\""'
    ) Do Set "RDir=%%H")
If Not Defined RDir GoTo :EOF
If "%PROCESSOR_ARCHITECTURE:~-2%" == "86" (
    If Not Defined PROCESSOR_ARCHITEW6432 (Set "RDir=%RDir%\bin\i386"
) Else Set "RDir=%RDir%\bin\x64") Else Set "RDir=%RDir%\bin\x64"
Where /Q "%RDir%":"RScript.exe" && (Set "RDir=%RDir%\RScript.exe") || Set "RDir="
If Defined RDir Echo Your default RScript.exe absolute path is %RDir% & Pause

설치 시 에서 설치 옵션 Save version number in registry이 선택 되었는지 (또는 나중에 또는 를 사용하여 ) 확인한 다음 반환된 홈 디렉토리 경로를 사용하여 하위 디렉토리를 추가 하는지 확인하는 것도 좋습니다 .Select Additional TasksRSetReg.exeRSetReg.exe /Personal

@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
Set "Reg=%__AppDir__%reg.exe"
Set "Find=%__AppDir__%find.exe"
Set "Key=HKCU\Software\R-core\R"
Set "Val=InstallPath"
Set "RDir="
For /F "EOL=H Tokens=2*" %%G In (
    '"%Reg% Query "%Key%" /S /F "%Val%" /V 2>NUL|%Find% "\""') Do Set "RDir=%%~H"
If Not Defined RDir For /F "EOL=H Tokens=2*" %%G In (
    '"%Reg% Query "HKLM%Key:~4%" /S /F "%Val%" /V 2>NUL|%Find% "\""'
) Do Set "RDir=%%~H"
If Not Defined RDir GoTo :EOF
If "%PROCESSOR_ARCHITECTURE:~-2%" == "86" (
    If Not Defined PROCESSOR_ARCHITEW6432 (Set "RDir=%RDir%\bin\i386"
) Else Set "RDir=%RDir%\bin\x64") Else Set "RDir=%RDir%\bin\x64"
Where /Q "%RDir%":"RScript.exe" && (Set "RDir=%RDir%\RScript.exe") || Set "RDir="
If Defined RDir Echo Your default RScript.exe absolute path is %RDir% & Pause

이러한 방법 중 하나가 위치를 제공하지 못하는 경우에만 시스템 드라이브 또는 실행 파일에 대해 사용 가능한 다른 볼륨을 검색하는 것이 좋습니다.

for /F 루프를 사용하여 명령 출력을 변수로 캡처할 수 있습니다. if conditions 또는 출력을 find 또는 findstr로 파이프하면 해당 출력을 추가로 필터링할 수 있습니다.

출력의 첫 번째 줄만 캡처하는 간단한 경우에는 다음으로 충분합니다.

@echo off
Setlocal ENABLEdelayedexpansion
For /F "Delims=" %%0 In ('where /r "c:\Program Files" Rscript.exe') do If "!scriptpath!" == "" Set "scriptpath=%%~0"

참고로 제가 생각해낸 해결책은 다음과 같습니다.

@echo off

set "rscript=I:\path\to\myscript.R"

for /r "c:\Program Files" %%F in (*Rscript.exe*) do (
  "%%~fF" "%rscript%" %*
  goto :eof
)

echo No Rscript.exe found. Maybe you need to install R.
pause

편집: @Compo의 제안을 사용하여 배치 파일을 다음과 같이 수정했습니다.

@Echo Off
SetLocal EnableExtensions

set "rscript=I:\path\to\myscript.R"

For /F "EOL=H Tokens=3*" %%G In (
    '"reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall /S /F "R for Windows" /K /V "InstallLocation" 2> NUL | find "InstallLocation""'
) Do Set "rexe=%%G %%Hbin\x64\Rscript.exe"

if not defined rexe goto nope

"%rexe%" "%rscript%" %*
goto :eof

:nope
echo No Rscript.exe found. Maybe you need to install R.
pause

여기에 내가 그 과정에서 배운 몇 가지 메모가 있습니다.

• .RData내 PC의 RStudio와 연결되어 있으므로 여기를 보는 것은 좋지 않습니다.
• SetLocal EnableExtension내 PC에는 필요하지 않지만 다른 PC에는 있을 수 있으므로 라인을 유지했습니다.
• 는 세 번째 토큰으로 Tokens=3*정의 %G하고 암시적 %H으로 세 번째 토큰 이후의 모든 토큰으로 정의합니다. 미친 구문.
• 2> NUL"오류 메시지 무시"를 의미합니다.
• 이중 따옴표 "'reg ...'"가 정말 필요한데 왜 그런지 궁금합니다.

이것은 지금 나를 위해 작동합니다. 배치 파일이 실행될 PC가 x64 아키텍처이고 Program Files. 나중에 rscript에 옵션을 추가해야 할 수도 있습니다. 또한 R이 2개 이상 설치되어 있을 경우를 대비하여 최신 R 버전을 사용할 수 있도록 알아내야 할 것입니다.