FUNGSI IF EXCEL
Fungsi IF atau Rumus IF adalah salah satu fungsi Excel dalam kategori atau kelompok
logical yang sering digunakan untuk melakukan uji logika tertentu pada rumus
microsoft excel.
Rumus Excel IF akan menghasilkan sebuah nilai tertentu jika kondisi yang kita
tentukan untuk di evaluasi terpenuhi (TRUE) dan akan menghasilkan nilai lainnya
apabila uji logika atau kondisi itu tidak terpenuhi (FALSE).
Dengan kata lain fungsi IF excel ini akan melakukan evaluasi terhadap uji logika
tertentu kemudian menghasilkan nilai TRUE atau FALSE. Nilai TRUE adalah nilai
dimana kondisi tersebut terpenuhi dan nilai FALSE adalah nilai untuk kondisi yang
tidak terpenuhi.
Sebelum menjelaskan cara kerja rumus if kita akan mengingat lagi tentang sintaks
fungsi if :
IF(TesLogika; NilaiJikaBenar; NilaiJikaSalah)
Kemudian kita juga perlu mengingat operator perbandingan yang akan menghasilkan
nilai TRUE(Nilai Benar) atau FALSE(Nilai Salah).
= Artinya "Sama dengan"
> Artinya "Lebih dari"
< Artinya "Kurang dari"
>= Artinya "Lebih dari atau Sama dengan"
<= Artinya "Kurang dari atau Sama dengan"
<> Artinya "Tidak sama dengan"
Cara menggunakan fungsi excel IF atau rumus IF excel pada sebuah rumus atau
formula excel adalah dengan mengikuti kaidah penulisan rumus berikut:
IF(TesLogika; KondisiTerpenuhi; [KondisiTidakTerpenuhi])
Dari sintaksis di atas, dapat kita ketahui bahwa rumus atau fungsi IF pada excel terdiri
dari 3 argumen:
o TesLogika : Argumen ini berisi ekspresi logika yang bisa dievaluasi ke dalam
nilai TRUE atau FALSE. Argumen ini merupakan kriteria acuan untuk
menentukan nilai yang akan dihasilkan oleh rumus excel IF.
o KondisiTerpenuhi : Nilai yang akan dihasilkan jika hasil
evaluasi TesLogika bernilai TRUE. Argumen ini merupakan nilai yang akan
dihasilkan jika kondisi terpenuhi.
o KondisiTidakTerpenuhi : (Opsional) Nilai yang ingin kita hasilkan jika
argumen TesLogika mengevaluasi ke FALSE. Argumen ini merupakan nilai
jika hasil tes logika tidak terpenuhi.
A. FUNGSI IF TEXT/TUNGGAL
Pada contoh rumus if ini kita akan menguji apakah jumlah nilai lebih dari 140 atau
tidak. Jika lebih dari 140 maka dinyatakan Lulus dan sebaliknya jika kurang dari atau
sama dengan 140 maka dinyatakan gagal (tidak lulus).
Pada contoh di atas, rumus excel yang digunakan pada sel F2 adalah:
=IF(E2>140;"LULUS";"GAGAL")
Formula excel di atas melakukan uji logika pada sel E2 apakah nilainya lebih dari 140
atau tidak. Jika nilai E2 lebih dari 140 maka rumus if akan menghasilkan teks LULUS.
Sebaliknya jika nilai E2 tidak lebih dari 140 maka rumus IF akan menghasilkan nilai
teks GAGAL.
Hasil dari rumus if excel tersebut adalah "LULUS", sebab nilai E2 adalah 150 yang
berarti bahwa nilai angka pada sel E2 lebih dari 140.
Berikunya perhatikan contoh rumus IF pada nomor 2. Pada contoh nomor 2, rumus
excel if yang digunakan pada sel F3 adalah:
=IF(E3>140;"LULUS";"GAGAL")
Rumus excel if di atas menghasilkan nilai teks "GAGAL", sebab uji logika pada sel E3
(125) tidak lebih dari 140.
B. FUNGSI IF GANDA
Rumus IF Ganda Pada Kondisi Terpenuhi
Rumus Umum fungsi IF ganda pada kondisi terpenuhi adalah sebagai berikut:
Advertisements
IF(TesLogika1;
IF(TesLogika2; KondisiTerpenuhi2; [KondisiTidakTerpenuhi2]);
[KondisiTidakTerpenuhi1])
Silahkan perhatikan contoh Rumus IF ganda di bawah ini:
Pada contoh tersebut rumus if ganda yang digunakan pada sel F2 adalah:
=IF(C2>60;IF(D2>60;"LULUS";"GAGAL");"GAGAL")
Rumus IF diatas melakukan uji logika ganda pada dua sel sekaligus secara bertahap:
1. Jika C2 lebih dari 60 maka lakukan uji logika lanjutan dengan rumus IF ke-2. Jika C2
tidak lebih dari 60 maka "GAGAL"
2. Pada rumus IF ke-2 jika D2 lebih dari 60 maka "LULUS", jika tidak maka "GAGAL".
Hasil akhir dari rumus if diatas adalah LULUS, sebab nilai cell C2 dan D2 sama-sama
lebih dari 60.
Selanjutnya silahkan perhatikan contoh nomor 4. Pada contoh nomor 4 rumus if excel
yg dipakai pada sel F5 adalah:
=IF(C5>60;IF(D5>60;"LULUS";"GAGAL");"GAGAL")
Rumus excel diatas menghasilkan nilai GAGAL sebab pada rumus if kedua, nilai dari
D4 (60) tidak lebih dari 60.
Rumus IF Ganda Pada Kondisi Tidak Terpenuhi
Rumus Umum fungsi IF ganda pada kondisi tidak terpenuhi adalah sebagai berikut:
IF(TesLogika1;
KondisiTerpenuhi1;
IF(TesLogika2; KondisiTerpenuhi2; [KondisiTidakTerpenuhi2]))
Contoh rumus IF yang menggunakan sintaksis ini adalah sebagai berikut:
Pada sel F2 contoh rumus excel if ganda ini, rumusnya:
=IF(C2<=60;"GAGAL";IF(D2<=60;"GAGAL";"LULUS"))
Rumus IF diatas melakukan uji logika ganda pada dua sel sekaligus secara bertahap:
1. Jika C2 kurang dari atau sama dengan 60 maka hasilnya "GAGAL", sebaliknya jika nilai
C2 Lebih dari 60 maka lakukan uji logika lanjutan dengan rumus IF ke-2.
2. Pada rumus IF ke-2 jika nilai cell D2 kurang dari atau sama dengan 60 maka
"GAGAL", jika tidak maka "LULUS".
Hasil akhir dari rumus if diatas adalah LULUS, sebab nilai cell C2 maupun D2
TIDAK kurang dari atau sama dengan 60.
Advertisements
Rumus IF Ganda Pada Kondisi Terpenuhi dan Tidak Terpenuhi
Rumus Umum fungsi IF ganda pada kondisi tidak terpenuhi adalah sebagai berikut:
IF(TesLogika1;
IF(TesLogika2; KondisiTerpenuhi2; [KondisiTidakTerpenuhi2]);
IF(TesLogika3; KondisiTerpenuhi3; [KondisiTidakTerpenuhi3]))
Contoh rumus IF yang menggunakan sintaksis ini adalah sebagai berikut:
Pada sel F2 contoh rumus excel if ganda ini, rumusnya:
=IF(C2="L";
IF(F2>150;"LULUS";"GAGAL");
IF(F2>130;"LULUS";"GAGAL"))
Rumus IF diatas melakukan uji logika ganda dimana pada masing-masing Argumen
NilaiTerpenuhi dan NilaiTidakTerpenuhi pada IF pertama diisi dengan rumus IF
lainnya.
1. Pada contoh ini fungsi IF pertama melakukan uji perbandingan dengan menilai apakah
Nilai C2 adalah teks "L".
2. Jika benar (TRUE) maka dilanjutkan dengan uji logika dengan IF ke-2
(IF(F2>150;"LULUS";"GAGAL"))
3. Jika salah (FALSE) atau bukan "L", maka dilakukan uji logika dengan IF ke-3
(IF(F2>130;"LULUS";"GAGAL"))
C. RUMUS IF BERTINGKAT
Rumus IF bertingkat adalah menggunakan fungsi IF excel sebagai argument dari rumus
if lainnya. Pada bagian "NilaiJikaBenar" atau "NilaiJikaSalah" dan juga bisa pada kedua
bagian atau argumen fungsi IF.
Penggunaan rumus if bertingkat semacam ini bisa bertingkat 2, bertingkat 3 dan
seterusnya.
Hal ini berarti bahwa Anda bisa memasukkan fungsi if ke dalam sebuah rumus if excel.
Kemudian memasukkan fungsi IF pada rumus if yang telah dimasukkan ke dalam
rumus if lain.
Sintaksisnya seperti ini:
1. Rumus IF Bercabang pada NilaiJikaBenar:
=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; NilaiJikaSalah2); NilaiJikaSalah1)
2. Rumus IF Bercabang pada NilaiJikaSalah:
=IF(TesLogika1; NilaiJikaBenar1; IF(TesLogika2; NilaiJikaBenar2; NilaiJikaSalah2))
3. Rumus IF Bercabang pada NilaiJikaBenar dan NilaiJikaSalah:
=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; NilaiJikaSalah2); IF(TesLogika3;
NilaiJikaBenar3; NilaiJikaSalah3))
Rumus IF bertingkat atau IF bercabang yang dipakai Pada contoh di atas adalah sebagai
berikut:
Advertisements
=IF(D2>=0;IF(D2<=59;"E";IF(D2<=69;"D";IF(D2<=79;"C";IF(D2<=89;"B";IF(D2<=100;"
A";"Nilai diatas 100")))));"Nilai Minus")
Dari sintaksis dasar rumus IF, kita masukkan masing-masing argumennya:
IF(TesLogika; NilaiJikaBenar; NilaiJikaSalah)
Argument TesLogika yang digunakan pada bagian pertama rumus tersebut adalah
"D2>=0".
Argument NilaiJikaBenar diisi dengan rumus if lain "IF(...)".
Argument NilaiJikaSalah diisi dengan sebuah teks "Nilai Minus".
=IF(D2>=0;IF(...);"Nilai Minus")
Dari rumus excel diatas fungsi IF pertama bertingkat pada bagian
TRUE(NilaiJikaBenar).
=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; NilaiJikaSalah2); NilaiJikaSalah1)
Maksud dari rumus diatas jika D2 Lebih dari atau Sama dengan 0 maka hasilkan nilai
rumus IF ke-2. Jika tidak lebih dari atau sama dengan 0 (nol) maka hasilkan teks "Nilai
Minus".
Misal nilai angka pada cell D2 adalah -60 maka rumus tersebut akan menghasilkan teks
"Nilai Minus". Sebab -60 tidak lebih dari atau sama dengan 0.
Apabila Nilai cell D2 adalah 95 maka rumus excel tersebut akan mengerjakan fungsi IF
tingkat ke-2, karena 95 lebih dari 0.
Rumus If tingkat ke-2 adalah sebagai berikut:
IF(D2<=59;"E";IF(...))
Rumus IF tingkat ke-2 pada contoh di atas bertingkat pada bagian FALSE
(NilaiJikaSalah).
Arti rumus if diatas jika D2 Kurang dari atau sama dengan 59 maka tulis "E". Jika tidak
kerjakan Rumus IF ke-3.
Jika digabungkan dengan IF sebelumnya penulisannya sebagai berikut:
=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; IF(TesLogika3; NilaiJikaBenar3;
NilaiJikaSalah3)); NilaiJikaSalah1)
Jika nilai cell D2 tidak kurang dari atau sama dengan 59 maka rumus excel akan
mengerjakan fungsi IF ke-3 sebagai berikut :
IF(D2<=69;"D";IF(...))
Rumus IF ke-3 ini bertingkat pada bagian "NilaiJikaSalah" seperti sebelumnya.
Jika digabungkan dengan fungsi IF sebelumnya penulisannya sebagai berikut:
=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; IF(TesLogika3; NilaiJikaBenar3;
IF(TesLogika4; NilaiJikaBenar4; NilaiJikaSalah4))); NilaiJikaSalah1)
Dan seterusnya. Sampai disini saya yakin anda sudah bisa memahami bagaimana cara
kerja fungsi IF berjenjang ini.
Selain dengan rumus diatas fungsi IF bertingkat/bercabang dalam kasus ini bisa juga
anda tulis seperti berikut :
=IF(D2>=0;IF(D2<60;"E";IF(D2<70;"D";IF(D2<80;"C";IF(D2<90;"B";IF(D2<=100;"A";"
Nilai diatas 100")))));"Nilai Minus")
Yang membedakan dengan fungsi sebelumnya hanyalah operator perbandingannya
saja. Jadi suka-suka anda lebih memilih yang mana. Tinggal bagaimana kreatifitas kita
saja dalam menyusun rumus excel yang lebih efisien.
