Wikidata:WikiProject Invasion biology

invasion biology (Q42985020): branch of biology that deals with the spread of alien species, with its building blocks theory, case studies and application, embedded in societal context

Lantana camara (Q332469): species of plant is native to Latin America and has spread to tropical and subtropical habitats around the globe.

Pterois volitans (Q824672): species of lionfish is native to the Pacific and invasive in the Western Atlantic

Six approaches for the analysis of living systems

Global air and sea traffic contributes to biological invasions by providing introduction pathways

Invasions can occur in any ecosystem

About

This WikiProject is about invasion biology (Q42985020): branch of biology that deals with the spread of alien species as well as about biological, ecological, conservational and other aspects of invasive species (Q183368): non-native organism causing damage to an established environment.

Properties

These properties should be tagged with maintained by WikiProject (P6104): WikiProject Invasion Biology (Q56241615). Note that usage of on focus list of Wikimedia project (P5008) for this is deprecated.

Existing

• invasive to (P5588): region which a taxon is not endemic to where the taxon has a tendency to spread to a degree believed to cause damage to the environment, human economy or human health
• Global Invasive Species Database ID (P5626): identifier for a taxon in the IUCN's Global Invasive Species Database
• Invasive Species Compendium Datasheet ID (P5698): identifier for a taxon datasheet in the Invasive Species Compendium, produced by the Centre for Agriculture and Bioscience International
• Espèces Envahissantes Outre-mer ID (P6043): identifier for a species on the Espèces Envahissantes Outre-mer website
• GT IBMA ID (P6054): identifier for a species on the Groupe de travail Invasions biologiques en milieux aquatiques website
• Invasive Plant Atlas of the United States ID (P6161): identifier for a species on the Invasive Plant Atlas of the United States website
• NAS ID (P6163): identifier for a species in the Nonindigenous Aquatic Species database, on the U.S. Geological Survey website
• Cal-IPC ID (P6176): identifier for a species on the California Invasive Plant Council website
• Invasive.org species ID (P10711): identifier for a species on Invasive.org
• Applied Ecology Resources document ID (P10877): identifier for a document in the Applied Ecology Resources database
• ORKG ID (P10897): Open Research Knowledge Graph (ORKG) ID
• Nebraska Invasive Species Program species ID (P11092): identifier for an invasive species in Nebraska on the Nebraska Invasive Species Program website

Possibly relevant

• statement is subject of (P805): (qualifying) item that describes the relation identified in this statement

To be proposed

• Natural enemy/ predator
  • besides main food source (P1034)
  • e.g. terms from biotic interaction ontology
• Further properties relating to
  • food chain
  • habitat
  • distribution
  • mechanisms of spread
  • spatial scale
  • temporal scale
  • etc.
• CABI publication identifier
  • e.g. 20067203670 for Limited evidence for increased cold-tolerance of invasive versus native Caulerpa taxifolia (Q60535985)   
• variables
• something to describe the relationship between a title (or other string value) and the lexemes contained therein

Schemas

Existing

• E392 for invasive taxa

To be considered

• invasion biologist
• biological invasion
• invaded habitat
• native taxon in an invasion context
• invasion biology publication
• invasion biology journal
• invasion biology hypothesis
• invasion biology event

Items

General concepts

• biological invasion (Q446911)   : process in which organisms become established in a region where they previously did not exist and then rapidly expand their range
• invasive species (Q183368)   : non-native organism causing damage to an established environment
  • introduced species (Q1065449)   : species introduced either deliberately or accidentally through human activity
  • 100 of the World's Worst Invasive Alien Species (Q311688)   : Wikimedia list article
• invasion biology (Q42985020)   : branch of biology that deals with the spread of alien species
• glossary of invasion biology terms (Q6059580)   : no description
• invasion ecology (Q105094378)   : branch of ecology
• habitat (Q52105)   : ecological or environmental area inhabited by a particular species; natural environment in which an organism lives, or the physical environment that surrounds a species population
• invasion success (Q109467185)   : concept in invasion biology
• invasion pathway (Q111525751)   : route taken by a species to a new habitat it invades

Invasive taxa by higher-level taxon group

This is still very drafty. The emphasis here is on ecological relevance of the groupings, less on taxonomic precision.

• invasive plant (Q3391537)   : plant species that is not native to a specific location that has a tendency to spread to a degree that causes damage
  • invasive tree (Q111114675)   : tree that is spreading outside its original habitat
    • invasive pine (Q116921353)   : pine species spreading outside its native habitat
  • invasive shrub (Q111114776)   : shrub that is spreading outside its original habitat
  • invasive weed (Q111118578)   : weed that is spreading outside its original habitat
  • invasive macrophyte (Q113105522)   : plant visible to the naked human eye that spreads in new habitats
• invasive microbe (Q111471755)   : microbe that is spreading outside its original habitat
  • See also microbial invasion into a new geographic area (Q111288898)   : expansion of microbes into new habitats
• invasive fungus (Q111551093)   : fungus that is spreading outside its original habitat
• invasive vertebrate (Q111535331)   : vertebrate that is spreading outside its original habitat
  • invasive fish (Q111475351)   : fish that is spreading outside its original habitat
  • invasive amphibian (Q111535327)   : amphibian that is spreading outside its original habitat
  • invasive reptile (Q111535328)   : reptile that is spreading outside its original habitat
    • invasive snake (Q111535373)   : snake that is spreading outside its original habitat
    • invasive lizard (Q111535374)   : lizard that is spreading outside its original habitat
  • invasive bird (Q111535329)   : bird that is spreading outside its original habitat
  • invasive mammal (Q111535330)   : mammal that is spreading outside its original habitat
    • invasive rodent (Q111535375)   : rodent that is spreading outside its original habitat
• invasive invertebrate (Q111535332)   : invertebrate that is spreading outside its original habitat
  • invasive macroinvertebrate (Q111541794)   : macroinvertebrate that is spreading outside its original habitat
  • invasive insect (Q111535560)   : insect that is spreading outside its original habitat
    • invasive beetle (Q111535564)   : beetle that is spreading outside its original habitat
    • invasive mosquito species (Q111541628)   : mosquito that is spreading outside its original habitat
    • invasive ant (Q111541702)   : ant that is spreading outside its original habitat
    • invasive wasp (Q111803613)   : wasp that is spreading outside its original habitat
    • invasive bee (Q112846115)   : bee that is spreading outside its original habitat
  • invasive snail (Q111541604)   : snail that is spreading outside its original habitat
  • invasive crayfish (Q111795828)   : crayfish that is spreading outside its original habitat

Invasion biology hypotheses

For the moment, we include rules.

• enemy release hypothesis (Q85759287)   
• biotic resistance hypothesis (Q108374968)   
• Foster's rule (Q2296350)   
• Intermediate Disturbance Hypothesis (Q9003976)   
• novel weapons hypothesis (Q109996900)   
• propagule pressure hypothesis (Q110620464)   
• habitat amount hypothesis (Q110808826)   

Textbook examples

• Introduction of Brown tree snake (Q900781)    in Guam (Q16635)   
• pyrrolizidine alkaloid (Q75005794)   
• Senecio inaequidens (Q939756)   
• Diversity of pyrrolizidine alkaloids in native and invasive Senecio pterophorus (Asteraceae): implications for toxicity (Q46831900)   
• Fallopia japonica (Q899672)   
• Impatiens glandulifera (Q158035)   
• Bias and error in understanding plant invasion impacts (Q34478639)   
• The lionfish Pterois sp. invasion: Has the worst-case scenario come to pass? (Q51147482)   
• The profile of a ‘perfect’ invader – the case of killer shrimp, Dikerogammarus villosus (Q56448004)   
• An ideal weed: plasticity and invasiveness in Polygonum cespitosum. (Q35803290)   
• Hemimysis anomala (Q1758554)   

Items with confusion potential

• Selective Production of Exotic Species (Q111303462)   
  • exotic meson (Q2629256)   
  • exotic resonance (Q112903729)   
  • See also
    • SPES: EXOTIC BEAMS FOR NUCLEAR PHYSICS STUDIES (Q60515283)   
    • Search for an exotic decay of the Higgs boson to a pair of light pseudoscalars in the final state of two muons and two τ leptons in proton-proton collisions at s=13$$ \sqrt{s}=13 $$ TeV (Q58790175)   
    • Search for decays of stopped exotic long-lived particles produced in proton-proton collisions at s = 13 $$ \sqrt{s}=13 $$ TeV (Q56895051)   
• invasive disease (Q111796726)   
  • invasive mycosis (Q112040879)    — see also systemic mycosis (Q18553214)    and invasive fungal infections (Q55022218)   
    • invasive candidiasis (Q29887808)   
      • candidemia (Q54946225)   
  • placenta accreta (Q517856)    (abnormally invasive placenta)
• trophoblast invasion (Q121778533)   
• neoplastic invasiveness (Q112498967)   
• reactive oxygen species (Q424361)   
• colonization
• invasion front (Q112158018)   
• invasion pattern
• invasive weed optimization (Q115923980)   
  • see also A modified Marine Predator Algorithm based on opposition based learning for tracking the global MPP of shaded PV system (Q115575300)   
• strand invasion (Q21112603)   
• invader assay (Q121867283)   
• T-cell invasion (Q121885022)   
• tissue invasion (Q121891607)   
• Invasion percolation (Q24902133)   
• volcanology:
  • magmatic invasion: Geochemical evidence for invasion of Kilauea's plumbing system by Mauna Loa magma (Q59083344)   
  • lava invasion: Mitigation of lava flow invasion hazard through optimized barrier configuration aided by numerical simulation: The case of the 2001 Etna eruption (Q57570010)   
• CO2 invasion: CO2 invasion
• glacial invasion: Discrimination of glacial accumulation and invasion (Q60677273)   
• landscape invasion: Tracking Invasive Land Covers in India, or Why Our Landscapes Have Never Been Modern (Q58137884)   
• Insights into the invasion biology of Plasmodium vivax (Q36655327)   
  • Similar: New approaches to studying Plasmodium falciparum merozoite invasion and insights into invasion biology (Q38065630)   
• The Oman Exotics: a key to the understanding of the Neotethyan geodynamic evolution (Q57698992)   
• Postglacial Invasion Routes of Canadian Arctic Butterflies (Q110862044)   
• Toxoplasma gondii: The best terrestrial biological weapon against extraterrestrial invaders? (Q80381423)   

Test items

• Molecular Phylogenetics of Physa acuta (Pulmonata: Basommatophora): an Invasive species in Central Punjab Pakistan (Q112116359)    — detailed annotations of main subject (P921) and describes a project that uses (P4510) statements
• Phytotoxic effects of invasive Ageratina adenophora on two native subtropical shrubs in Nepal (Q110862381)    — detailed annotations of main subject (P921) and describes a project that uses (P4510) statements
• Valorization of Invasive Plant Extracts against the Bispecies Biofilm Staphylococcus aureus–Candida albicans by a Bioguided Molecular Networking Screening (Q115582787)    — detailed annotations of main subject (P921) and describes a project that uses (P4510) statements
• Ecology and Management of Alien Plant invasions (Q112229050)    — conference series
• SInAS database of alien species occurrences (Q112339024)    — dataset
• Ecological Solutions and Evidence (Q96695849)    — journal
• Invaded Invaders: Infection of Invasive Brown Treesnakes on Guam by an Exotic Larval Cestode with a Life Cycle Comprised of Non-Native Hosts (Q28603606)    — second-degree invasion

Themes

• invasion management (Q113019190)   
  • Some more candidates
• invasion success (Q109467185)   
• invasion impact (Q112148709)   
• invasion pathway (Q111525751)   
  • Some more candidates
• meta-invasion science (Q124428132)   

Caveats

• Seven Shortfalls that Beset Large-Scale Knowledge of Biodiversity (Q60300062)   

Data sources

• A workflow for standardising and integrating alien species distribution data (Q107461651)   
• Country Compendium of the Global Register of Introduced and Invasive Species (Q113052006)   

Lexemes

Lexemes associated with items about entities studied by invasion biology and/or ecology

The following query uses these:

• Items: invasion biology (Q42985020)   , ecology (Q7150)   

• Properties: studied in (P2579)   , item for this sense (P5137)   

  #title: Lexemes associated with items about entities studied by invasion biology and/or ecology
  SELECT 
  DISTINCT ?qid
  (GROUP_CONCAT(DISTINCT ?lemma; separator=" // ") AS ?lexemes)
  (CONCAT("https://ordia.toolforge.org/Q", STR(?qid ) ) AS ?ordia)
  
  WHERE {
    { ?item wdt:P2579 wd:Q42985020 .}
    UNION
    { ?item wdt:P2579 wd:Q7150 .}
    ?item ^wdt:P5137 ?sense .
    ?sense ^ontolex:sense ?lexeme .
    ?lexeme wikibase:lemma ?lemma .
    BIND(xsd:integer(STRAFTER(STR(?item), 'Q')) as ?qid)
  }
  GROUP BY ?qid ?lexemes ?ordia
  ORDER BY ASC(?qid)
  

Lexemes associated with items about entities studied by invasion biology and/or ecology

Lexemes associated with topics that occur in the invasion biology literature

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , item for this sense (P5137)   

  #title: Lexemes associated with topics that occur in the invasion biology literature
  SELECT 
  DISTINCT ?qid
  (GROUP_CONCAT(DISTINCT ?lemma; separator=" // ") AS ?lexemes)
  (CONCAT("https://ordia.toolforge.org/Q", STR(?qid ) ) AS ?ordia)
  
  WHERE {
    { ?invasion_biology_item wdt:P6104 wd:Q56241615 ;
                             wdt:P921 ?item . }
    ?item ^wdt:P5137 ?sense .
    ?sense ^ontolex:sense ?lexeme .
    ?lexeme wikibase:lemma ?lemma .
    BIND(xsd:integer(STRAFTER(STR(?item), 'Q')) as ?qid)
  }
  GROUP BY ?qid ?lexemes ?ordia
  ORDER BY ASC(?qid)
  

Lexemes associated with topics that occur in the invasion biology literature

Queries

🪣 Content queries

🪣 Generic

🪣 Number of entities within scope of the WikiProject

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   

  SELECT DISTINCT (COUNT(?item_) AS ?count) 
  WHERE { ?item_ wdt:P6104 wd:Q56241615. }
  

Try it!

🪣 Entity types within scope of the WikiProject

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: instance of (P31)   , subclass of (P279)   , maintained by WikiProject (P6104)   

  SELECT 
    DISTINCT 
    ?type ?typeLabel 
    ?count ?sample ?sampleLabel
  WITH {
    SELECT DISTINCT ?type (COUNT(?item_) AS ?count) (SAMPLE(?item_) AS ?sample)  
    WHERE {
      ?item_ wdt:P31|wdt:P279 ?type .    
      ?item_ wdt:P6104 wd:Q56241615 .  
    }
    GROUP BY ?type ?count ?sample
  } AS %items
  WHERE {
    INCLUDE %items 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
  }
  GROUP BY ?type ?typeLabel ?count ?sample ?sampleLabel 
  ORDER BY DESC(?count)
  LIMIT 200
  

Try it!

🪣 Entities within scope of the WikiProject

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   

  SELECT 
    DISTINCT 
    ?item ?itemLabel ?sitelinks
  WITH {
    SELECT DISTINCT ?item ?sitelinks
    WHERE {
      ?item wdt:P6104 wd:Q56241615 .  
      ?item wikibase:sitelinks ?sitelinks.
    }
    GROUP BY ?item ?sitelinks
  } AS %items
  WHERE {
    INCLUDE %items 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
  }
  GROUP BY ?item ?itemLabel ?sitelinks
  ORDER BY DESC(?sitelinks)
  LIMIT 200
  

Try it!

🪣 Property use within scope of the WikiProject

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   

  SELECT DISTINCT ?property ?propertyLabel ?count
  WITH {
    SELECT DISTINCT ?item WHERE {
      ?item wdt:P6104 wd:Q56241615 .
    }
    LIMIT 200000
    } AS %items 
  WITH {
    SELECT DISTINCT ?property (COUNT(*) AS ?count) WHERE {
    INCLUDE %items.
      ?item ?p [ ] .
      ?property a wikibase:Property;
                  wikibase:claim ?p.
    }
    GROUP BY ?property 
  #   LIMIT 100
    } AS %results 
  WHERE {
    INCLUDE %results.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  ORDER BY DESC(?count)
  # LIMIT 100
  

Try it!

🪣 Pictorial overview of WikiProject Invasive species

The following query uses these:

• Items: human (Q5)   

• Properties: image (P18)   , different from (P1889)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
PREFIX target: <http://www.wikidata.org/entity/Q56241615>

SELECT DISTINCT ?item (SAMPLE(?image_) AS ?image) WHERE {
  {
    # Images of the target
    target: wdt:P18 ?image_ .
  }
  UNION {
    # Images from whatever property value is linked.
    
    # Excluded "different from" property and take all other properties
    target: !wdt:P1889 ?item .

    ?item wdt:P18 ?image_ . 
    
    # All people are humans, so these images are excluded.
    FILTER (?item != wd:Q5)
  }
  UNION {
    # Images from whatever property value is linked.
    
    # Excluded "different from" property and take all other properties
    ?item !wdt:P1889 target: .

    ?item wdt:P18 ?image_ .     
  }
  ?item wikibase:sitelinks ?sitelinks .
}   
GROUP BY ?item ?image
ORDER BY DESC(?sitelinks)
LIMIT 200

Try it!

🪣 Entitites studied by invasion biology

The following query uses these:

• Items: invasion biology (Q42985020)   

• Properties: studied in (P2579)   

  #title: Entitites studied by invasion biology
  SELECT DISTINCT ?item ?itemLabel
  WHERE {
    ?item wdt:P2579 wd:Q42985020 .
    BIND(xsd:integer(STRAFTER(STR(?item), 'Q')) as ?qid)
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" .}
  }
  ORDER BY ASC(?qid )
  

Entitites studied by invasion biology

🪣 Invasion biology in a broader context that includes restoration ecology, urban ecology and freshwater ecology

The following query uses these:

• Properties: main subject (P921)   , instance of (P31)   , subclass of (P279)   , part of (P361)   , facet of (P1269)   

Features: Graph (Q24515287)   

#defaultView:Graph
#title: Invasion biology in a broader context that includes restoration ecology, urban ecology and freshwater ecology

PREFIX target1: <http://www.wikidata.org/entity/Q183368> # invasive species
PREFIX target2: <http://www.wikidata.org/entity/Q2428433>  # restoration ecology
PREFIX target3: <http://www.wikidata.org/entity/Q60566657> # freshwater ecology
PREFIX target4: <http://www.wikidata.org/entity/Q1430301> # urban ecology
PREFIX target5: <http://www.wikidata.org/entity/Q42985020> # invasion biology

SELECT
  ?topic1 ?topic1Label ?rgb ?topic2 ?topic2Label 
WITH {
  SELECT
    (COUNT(DISTINCT ?work) AS ?count) ?topic1 ?topic2 ?rgb
  WHERE {
    # Find works that are marked with main subject of the topic.
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target1: .}
    UNION
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target2: .}
    UNION
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target3: .}
    UNION
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target4: .}
    UNION
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target5: .}
    
    # Identify co-occuring topics. 
    ?work wdt:P921 ?topic1, ?topic2 . 

    # Exclude the topic it self
    FILTER (target1: != ?topic1 && target1: != ?topic2 && ?topic1 != ?topic2)
      BIND(IF(?topic1 = target5:,"7FFF00",
              IF( ?topic1 = target4:, "3080BB",
                IF( ?topic1 = target3:, "3080BB",
                  IF( ?topic1 = target2:, "3080BB",
                "FFA500"
                     )
                  )
                )
              )
           AS ?rgb).
  }
  GROUP BY ?topic1 ?topic2 ?rgb
  ORDER BY DESC(?count)

  # There a performance problems in the browser: We cannot show large graphs,
  # so we put a limit on the number of links displayed.
  LIMIT 200

} AS %results
WHERE {
  INCLUDE %results
  
  # Label the results
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh".
  }
}

Invasion biology in a broader context that includes restoration ecology, urban ecology and freshwater ecology

🪣 Most recently created entities within scope of the WikiProject

The following query uses these:

SELECT ?item ?itemLabel {
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:endpoint "www.wikidata.org";
                    wikibase:api "Generator" ;
                    wikibase:limit "once" ;
                    mwapi:generator "search";
                    mwapi:gsrsearch "haswbstatement:P6104=Q56241615" ;
                    mwapi:gsrsort "create_timestamp_desc" ;
                    mwapi:gsrlimit "100".
    ?item wikibase:apiOutputItem mwapi:title.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(xsd:integer(SUBSTR(STR(?item), 33)))

Try it!

🪣 Taxa

🪣 Taxon names sorted by association with invasion biology in the literature

🪣 Overall

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   , class (Q37517)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , taxon name (P225)   , taxon rank (P105)   , parent taxon (P171)   

  SELECT 
    DISTINCT 
    ?topic ?speciesname ?classname 
    ?count
    (CONCAT('https://scholia.toolforge.org/taxon/', ENCODE_FOR_URI(REPLACE(STR(?topic), ".*Q", "Q")), '/curation') AS ?taxon_curation) 
  
  WITH {
    SELECT DISTINCT ?topic 
    (COUNT(?paper) AS ?count)
    WHERE {
    ?paper wdt:P6104 wd:Q56241615 ;
           wdt:P921 ?topic .
    }  
    GROUP BY ?topic ?count
  } AS %papers
  WITH {
    SELECT DISTINCT ?topic ?speciesname ?count WHERE {
      INCLUDE %papers
    ?topic wdt:P225 ?speciesname ;
           wdt:P105 wd:Q7432 .
  
    }
    GROUP BY ?topic ?speciesname ?count
    
  } AS %species
  
  WHERE {
    INCLUDE %species
    ?topic wdt:P171* ?class .
    ?class wdt:P105 wd:Q37517;
           wdt:P225 ?classname .
  }
  GROUP BY ?topic ?speciesname ?classname ?count ?taxon_curation
  ORDER BY DESC(?count)
  

Try it!

🪣 By taxonomic kingdom

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   , kingdom (Q36732)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , taxon name (P225)   , taxon rank (P105)   , parent taxon (P171)   

  SELECT 
    DISTINCT 
    ?topic ?kingdomname ?speciesname
    ?count
    (CONCAT('https://scholia.toolforge.org/taxon/', ENCODE_FOR_URI(REPLACE(STR(?topic), ".*Q", "Q")), '/curation') AS ?taxon_curation) 
  
  WITH {
    SELECT DISTINCT ?topic 
    (COUNT(?paper) AS ?count)
    WHERE {
    ?paper wdt:P6104 wd:Q56241615 ;
           wdt:P921 ?topic .
    }  
    GROUP BY ?topic ?count
  } AS %papers
  WITH {
    SELECT DISTINCT ?topic ?speciesname ?count WHERE {
      INCLUDE %papers
    ?topic wdt:P225 ?speciesname ;
           wdt:P105 wd:Q7432 .
  
    }
    GROUP BY ?topic ?speciesname ?count
  #  HAVING (?count > 25)
    
  } AS %species
  
  WHERE {
    INCLUDE %species
    ?topic wdt:P171* ?kingdom .
    ?kingdom wdt:P105 wd:Q36732;
           wdt:P225 ?kingdomname .
  }
  GROUP BY ?topic ?kingdomname ?speciesname ?count ?taxon_curation
  ORDER BY ASC(?kingdomname) DESC(?count)
  

Try it!

🪣 By taxonomic class

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   , class (Q37517)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , taxon name (P225)   , taxon rank (P105)   , parent taxon (P171)   

  SELECT 
    DISTINCT 
    ?topic ?classname ?speciesname
    ?count
    (CONCAT('https://scholia.toolforge.org/taxon/', ENCODE_FOR_URI(REPLACE(STR(?topic), ".*Q", "Q")), '/curation') AS ?taxon_curation) 
  
  WITH {
    SELECT DISTINCT ?topic 
    (COUNT(?paper) AS ?count)
    WHERE {
    ?paper wdt:P6104 wd:Q56241615 ;
           wdt:P921 ?topic .
    }  
    GROUP BY ?topic ?count
  } AS %papers
  WITH {
    SELECT DISTINCT ?topic ?speciesname ?count WHERE {
      INCLUDE %papers
    ?topic wdt:P225 ?speciesname ;
           wdt:P105 wd:Q7432 .
  
    }
    GROUP BY ?topic ?speciesname ?count
  #  HAVING (?count > 25)
    
  } AS %species
  
  WHERE {
    INCLUDE %species
    ?topic wdt:P171* ?class .
    ?class wdt:P105 wd:Q37517;
           wdt:P225 ?classname .
  }
  GROUP BY ?topic ?classname ?speciesname ?count ?taxon_curation
  ORDER BY ASC(?classname) DESC(?count)
  

Try it!

🪣 Most common fish in the invasion biology literature

The following query uses these:

• Items: species (Q7432)   , WikiProject Invasion Biology (Q56241615)   

• Properties: taxon rank (P105)   , maintained by WikiProject (P6104)   , FishBase species ID (P938)   , taxon name (P225)   

Features: BubbleChart (Q24515280)   

#title: Most common fish in the invasion biology literature
#defaultView:BubbleChart

PREFIX target: <http://www.wikidata.org/prop/direct/P921>

SELECT ?count ?o ?taxonname 
WITH {
  SELECT (COUNT(?s) AS ?count) ?o WHERE {
    ?s target: ?o .
    ?o wdt:P105 wd:Q7432 .
    ?o wdt:P6104 wd:Q56241615 .
    ?o wdt:P938 ?fishbase .
  }
  GROUP BY ?o
  ORDER BY DESC(?count)
  LIMIT 100
} AS %result
WHERE {
  INCLUDE %result
  ?o wdt:P225 ?taxonname .
}
ORDER BY DESC(?count)

Most common fish in the invasion biology literature

🪣 Within-scope papers about Rosaceae

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , Rosaceae (Q46299)   

• Properties: main subject (P921)   , maintained by WikiProject (P6104)   , title (P1476)   , parent taxon (P171)   

  #title: Within-scope papers about Rosaceae
  SELECT ?paper ?title ?topic ?topicLabel
  
  WHERE {
    ?paper wdt:P921 ?topic ;
           wdt:P6104 wd:Q56241615 ;
           wdt:P1476 ?title .
    ?topic wdt:P171* wd:Q46299 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
  }
  

Within-scope papers about Rosaceae

🪣 Taxa within scope of the project

See also #Invasive species without an image on Wikidata.

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , taxon name (P225)   , taxon rank (P105)   , image (P18)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
SELECT 
  DISTINCT 
  ?topic ?taxonname (SAMPLE(?image_) AS ?image)
  (COUNT(?paper) AS ?count)
WHERE {
  ?paper wdt:P6104 wd:Q56241615 ;
         wdt:P921 ?topic .
  ?topic wdt:P225 ?taxonname ;
         wdt:P105 wd:Q7432 .
  ?topic wdt:P18 ?image_.
}
GROUP BY ?topic ?taxonname ?image ?count
ORDER BY DESC(?count)
LIMIT 200

Try it!

🪣 In-scope taxa as depicted in art

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   , Homo sapiens (Q15978631)   , lion (Q140)   

• Properties: maintained by WikiProject (P6104)   , taxon name (P225)   , taxon rank (P105)   , depicts (P180)   , image (P18)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
SELECT 
  DISTINCT 
?taxon ?taxonname ?pic ?image
WHERE {
  ?taxon wdt:P6104 wd:Q56241615 ;
         wdt:P225 ?taxonname ;
         wdt:P105 wd:Q7432 .
  FILTER (?taxon != wd:Q15978631 )
  FILTER (?taxon != wd:Q140 )
  ?pic wdt:P180 ?taxon ;
       wdt:P18 ?image .
}

Try it!

🪣 Taxa with a Global Invasive Species Database ID (P5626) or an Invasive Species Compendium Datasheet ID (P5698), ranked by number of Wikimedia sitelinks

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: Invasive Species Compendium Datasheet ID (P5698)   , Global Invasive Species Database ID (P5626)   , maintained by WikiProject (P6104)   , image (P18)   , taxon name (P225)   , main subject (P921)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
SELECT DISTINCT ?item ?taxonname (SAMPLE(?image_) AS ?image) ?linkcount WHERE {

  {?item wdt:P5698 [].} UNION {?item wdt:P5626 [].}
#   ?item wdt:P6104 wd:Q56241615 . 
  ?item wdt:P18 ?image_ ;
        wdt:P225 ?taxonname.
  ?work wdt:P921 ?item .
  ?item wikibase:sitelinks ?linkcount .
}
GROUP BY ?item ?taxonname ?image ?linkcount
ORDER BY DESC(?linkcount)

Try it!

🪣 Publications

🪣 Works within scope of WikiProject Invasion Biology

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , DOI (P356)   

  #title: Publications within scope of WikiProject Invasion biology
  
  SELECT DISTINCT ?item ?itemLabel 
  WHERE {
    ?item wdt:P6104 wd:Q56241615;
          wdt:P356 ?doi .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel
  

Publications within scope of WikiProject Invasion biology

🪣 Topics of works within scope of WikiProject Invasion Biology

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   

  #title: Topics of works within scope of WikiProject Invasion Biology
  SELECT ?count ?topic ?topicLabel ?example_work ?example_workLabel
  WITH {
    SELECT DISTINCT ?topic (SAMPLE(?work) AS ?example_work) (COUNT(?work) AS ?count) WHERE {
      # Find works for the specific queried topic
      ?work wdt:P6104 wd:Q56241615 .
  
      # Find co-occuring topics
      ?work wdt:P921 ?topic .
  
    }
    GROUP BY ?topic
  } AS %result
  WHERE {
    # Label the results
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  ORDER BY DESC(?count)
  LIMIT 200
  

Topics of works within scope of WikiProject Invasion Biology

🪣 Items about invasion biology hypothesis papers

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , hypothesis (Q41719)   

• Properties: maintained by WikiProject (P6104)   , DOI (P356)   , main subject (P921)   , instance of (P31)   

  #title: Items about invasion biology hypothesis papers
  SELECT DISTINCT ?item ?itemLabel ?topic ?topicLabel ?doi
  WHERE { 
    ?item wdt:P6104 wd:Q56241615 ;
          wdt:P356 ?doi ;
          wdt:P921 ?topic .
    ?topic wdt:P31 wd:Q41719 .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?topic ?topicLabel ?doi
  ORDER BY DESC(?doi)
  

Items about invasion biology hypothesis papers

🪣 Openly licensed invasion biology publications about hypotheses known to Wikidata

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , hypothesis (Q41719)   , open license (Q30939938)   

• Properties: maintained by WikiProject (P6104)   , DOI (P356)   , main subject (P921)   , instance of (P31)   , copyright license (P275)   , subclass of (P279)   

  #title: Openly licensed invasion biology publications about hypotheses known to Wikidata
  SELECT DISTINCT ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
  WHERE { 
    ?item wdt:P6104 wd:Q56241615;
          wdt:P356 ?doi ;
          wdt:P921 ?topic .
    ?topic wdt:P31 wd:Q41719 .        
    ?item wdt:P275 ?license .
    ?license wdt:P31*/wdt:P279* wd:Q30939938 .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
  

Openly licensed invasion biology publications about hypotheses known to Wikidata

🪣 Items about invasion biology theme papers

The following query uses these:

• Items: invasion impact (Q112148709)   , invasion success (Q109467185)   , invasion pathway (Q111525751)   , invasion management (Q113019190)   , WikiProject Invasion Biology (Q56241615)   

• Properties: main subject (P921)   , maintained by WikiProject (P6104)   , DOI (P356)   

  #title: Items about invasion biology theme papers
  SELECT DISTINCT ?item ?itemLabel ?theme ?themeLabel ?doi
  WHERE {
    VALUES ?theme { wd:Q112148709 wd:Q109467185 wd:Q111525751 wd:Q113019190 }
    ?item wdt:P921 ?theme ;
          wdt:P6104 wd:Q56241615 ;
          wdt:P356 ?doi .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?theme ?themeLabel ?doi
  ORDER BY DESC(?doi)
  

Items about invasion biology theme papers

🪣 Invasion biology publications for inclusion in the OAI-PMH endpoint

The results of this query are exposed (about weekly) via the OAI-PMH endpoint for WikiProject Invasion biology.

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , hypothesis (Q41719)   , invasion success (Q109467185)   , invasion impact (Q112148709)   , invasion pathway (Q111525751)   , invasion management (Q113019190)   , open license (Q30939938)   

• Properties: maintained by WikiProject (P6104)   , DOI (P356)   , main subject (P921)   , instance of (P31)   , copyright license (P275)   , subclass of (P279)   

  #title: Invasion biology publications for inclusion in the OAI-PMH endpoint
  
  SELECT DISTINCT ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
  WHERE {
    ?item wdt:P6104 wd:Q56241615;
          wdt:P356 ?doi ;
          wdt:P921 ?topic .
   
    {?topic wdt:P31 wd:Q41719 .}
    UNION
    {VALUES ?topic { wd:Q109467185 wd:Q112148709 wd:Q111525751 wd:Q113019190} }
    UNION
    {?item wdt:P275 ?license .
    ?license wdt:P31*/wdt:P279* wd:Q30939938 .}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
  

Invasion biology publications for inclusion in the OAI-PMH endpoint

🪣 Language distribution of works within scope of the project

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   

  PREFIX target: <http://www.wikidata.org/prop/direct/P407>
  
  SELECT ?count ?Language ?LanguageLabel 
  WITH {
    SELECT (COUNT(?s) AS ?count) ?Language WHERE {
      ?s target: ?Language .
      ?s wdt:P6104 wd:Q56241615 .
    }
    GROUP BY ?Language
    ORDER BY DESC(?count)
    LIMIT 100
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language  "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . }
  }
  ORDER BY DESC(?count)
  

Try it!

🪣 Works that are (i) used as references and (b) have a topic that is a species with either a Global Invasive Species Database ID (P5626) or an Invasive Species Compendium Datasheet ID (P5698)

The following query uses these:

• Items: taxon (Q16521)   , female (Q6581072)   

• Properties: Invasive Species Compendium Datasheet ID (P5698)   , Global Invasive Species Database ID (P5626)   , instance of (P31)   , author (P50)   , title (P1476)   , main subject (P921)   , sex or gender (P21)   , ORCID iD (P496)   , cites work (P2860)   , stated in (P248)   

  SELECT DISTINCT ?item ?title (COUNT(DISTINCT ?statement) AS ?count)
  WHERE { 
      {?topic wdt:P5698 [].} UNION {?topic wdt:P5626 [].}
      ?topic wdt:P31 wd:Q16521 .
      ?item wdt:P50 ?author;
            wdt:P1476 ?title ;
            wdt:P921 ?topic .
      ?statement prov:wasDerivedFrom/pr:P248 ?item .
      ?author wdt:P21 wd:Q6581072 ;
              wdt:P496 ?orcid .
      [] wdt:P2860 ?item .
      
  }
  GROUP BY ?item ?title
  ORDER BY DESC(?count)
  LIMIT 200
  

Try it!

🪣 Works in scope by publication venue and its main subjects

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , published in (P1433)   , part of the series (P179)   , short name (P1813)   , main subject (P921)   

  #defaultView:Table
  SELECT ?count ?short_name ?venue ?venueLabel ?topic ?topicLabel
  WITH {
    SELECT (count(?work) as ?count) ?venue (SAMPLE(?short_name_) AS ?short_name) WHERE {
      ?work wdt:P6104 wd:Q56241615 .
      ?work wdt:P1433/wdt:P179* ?venue .
      OPTIONAL { ?venue wdt:P1813 ?short_name_ . }
    }
    GROUP BY ?venue
  } AS %result
  WHERE {
    INCLUDE %result
    OPTIONAL  { ?venue wdt:P921 ?topic }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  ORDER BY DESC(?count)
  

Try it!

🪣 Works in scope available under an Open Definition-compliant license

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , open license (Q30939938)   

• Properties: maintained by WikiProject (P6104)   , copyright license (P275)   , instance of (P31)   , subclass of (P279)   

  SELECT DISTINCT ?item ?itemLabel ?license ?licenseLabel
  WHERE { 
    ?item wdt:P6104 wd:Q56241615 . 
    ?item wdt:P275 ?license .
    ?license wdt:P31*/wdt:P279* wd:Q30939938 .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?license ?licenseLabel
  LIMIT 200
  

Try it!

🪣 In-scope articles with no license statement, by their identifiers (DOI, PubMed ID, PubMed Central ID)

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , scholarly article (Q13442814)   

• Properties: maintained by WikiProject (P6104)   , instance of (P31)   , title (P1476)   , copyright license (P275)   , DOI (P356)   , PubMed publication ID (P698)   , PMC publication ID (P932)   

  #title: In-scope articles with no license statement, by their identifiers (DOI, PubMed ID, PubMed Central ID)
  SELECT DISTINCT ?item ?title ?doi ?pmid ?pmcid
  WHERE { 
    ?item wdt:P6104 wd:Q56241615 ;
          wdt:P31 wd:Q13442814 ;
          wdt:P1476 ?title .
    MINUS {  ?item wdt:P275 ?license .}
    OPTIONAL { ?item wdt:P356 ?doi .}
    OPTIONAL { ?item wdt:P698 ?pmid .}
    OPTIONAL { ?item wdt:P932 ?pmcid .}
  }
  LIMIT 200
  

In-scope articles with no license statement, by their identifiers (DOI, PubMed ID, PubMed Central ID)

🪣 In-scope articles by authors related to Canada

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , Canada (Q16)   

• Properties: maintained by WikiProject (P6104)   , author (P50)   , title (P1476)   , zbMATH author ID (P1556)   

  #title: In-scope articles by authors related to Canada
  SELECT * WHERE {
    ?item wdt:P6104 wd:Q56241615 ;
          wdt:P50 ?author ;
          wdt:P1476 ?title .
    ?author wdt:P1556 [] .
    {?author ?p1 wd:Q16 .}
    UNION
    {?author ?p2 [?p3 wd:Q16 ] .}
  }
  

In-scope articles by authors related to Canada

🪣 Hypotheses

🪣 List of hypotheses studied by invasion biology

The following query uses these:

• Items: hypothesis (Q41719)   , invasion biology (Q42985020)   

• Properties: instance of (P31)   , studied in (P2579)   

  SELECT ?hypothesis ?hypothesisLabel WHERE {
    ?hypothesis wdt:P31 wd:Q41719 ;
          wdt:P2579 wd:Q42985020 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
  }
  

Try it!

🪣 List of hypotheses within scope of this Wikiproject

Some hypotheses may be studied by fields broader than invasion biology, so they would not be listed in the results of the above query for "List of hypotheses studied by invasion biology".

The following query uses these:

• Items: hypothesis (Q41719)   , WikiProject Invasion Biology (Q56241615)   

• Properties: instance of (P31)   , maintained by WikiProject (P6104)   , main subject (P921)   

  SELECT DISTINCT ?hypothesis ?hypothesisLabel WHERE {
    ?hypothesis wdt:P31 wd:Q41719 .
    {?hypothesis wdt:P6104 wd:Q56241615 .}
    UNION
    {?paper wdt:P6104 wd:Q56241615 ;
            wdt:P921 ?hypothesis .  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
  }
  

Try it!

🪣 People

🪣 Authors publishing about invasion biology

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , author (P50)   

  #defaultView:Table
  SELECT ?count ?author ?authorLabel ?sample_pub ?sample_pubLabel
  WITH {
    SELECT (count(DISTINCT ?work) as ?count) ?author (SAMPLE(?work) AS ?sample_pub) WHERE {
      ?work wdt:P6104 wd:Q56241615 .
      ?work wdt:P921 ?topic . 
      ?work wdt:P50 ?author .
    }
    GROUP BY ?author
    ORDER BY DESC(?count)
    LIMIT 200
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . } 
  }
  ORDER BY DESC(?count)
  

Try it!

🪣 Authors publishing about invasion biology who are not tagged as within scope of this WikiProject

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , author (P50)   

  SELECT 
  DISTINCT
    (REPLACE(STR(?author), ".*Q", "Q") AS ?qid) 
    ("P6104" AS ?property)
    ("Q56241615" AS ?ReplaceWithYourTargetID)
  
  WITH {
    SELECT (count(DISTINCT ?work) as ?count) ?author 
    WHERE {
      ?work wdt:P6104 wd:Q56241615 .
      ?work wdt:P921 ?topic . 
      ?work wdt:P50 ?author .
      MINUS { ?author wdt:P6104 wd:Q56241615 }
    }
    GROUP BY ?author
    HAVING(?count > 9)
    LIMIT 200
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . } 
  }
  

Try it!

🪣 Authors tagged as within scope of this WikiProject who have less than three in-scope papers

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , author (P50)   

  SELECT
  
  DISTINCT
    (REPLACE(STR(?author), ".*Q", "-Q") AS ?qid)
    ("P6104" AS ?property)
    ("Q56241615" AS ?ReplaceWithYourTargetID)
  
  WITH {
    SELECT (count(DISTINCT ?work) as ?count) ?author
    WHERE {
      ?work wdt:P6104 wd:Q56241615 .
      ?work wdt:P921 ?topic .
      ?work wdt:P50 ?author .
      ?author wdt:P6104 wd:Q56241615
    }
    GROUP BY ?author
    HAVING(?count < 3)
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . }
  }
  

Try it!

🪣 Authors tagged as within scope of this WikiProject who have no in-scope papers

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , human (Q5)   

• Properties: maintained by WikiProject (P6104)   , instance of (P31)   , author (P50)   

  SELECT
  DISTINCT
    (REPLACE(STR(?author), ".*Q", "-Q") AS ?qid)
    ("P6104" AS ?property)
    ("Q56241615" AS ?ReplaceWithYourTargetID)
  
  WITH {
    SELECT DISTINCT ?author
    WHERE {
      ?author wdt:P6104 wd:Q56241615 ;
              wdt:P31 wd:Q5 .
      FILTER NOT EXISTS {    ?work wdt:P50 ?author ; wdt:P6104 wd:Q56241615 .}
    }
    GROUP BY ?author
    LIMIT 100
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . }
  }
  

Try it!

🪣 Awards received by people studying invasion biology

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , human (Q5)   

• Properties: maintained by WikiProject (P6104)   , instance of (P31)   , award received (P166)   

  SELECT ?count ?award ?awardLabel ?recipients ?recipientsUrl
  WITH {
    SELECT (COUNT(?researcher) AS ?count) ?award 
    (GROUP_CONCAT(DISTINCT ?researcher_label; separator=", ") AS ?recipients) 
    (CONCAT("https://scholia.toolforge.org/authors/", GROUP_CONCAT(DISTINCT SUBSTR(STR(?researcher), 32); separator=",")) AS ?recipientsUrl)
    WHERE {
      { 
        SELECT DISTINCT ?researcher ?award WHERE {
          hint:Query hint:optimizer "None" .
          ?researcher wdt:P6104 wd:Q56241615 ; 
                      wdt:P31 wd:Q5 ;
                      wdt:P166 ?award .
        } 
        LIMIT 100000
      }
      ?researcher rdfs:label ?researcher_label . FILTER (LANG(?researcher_label) = 'en')
    }
    GROUP BY ?award 
  } AS %result
  WHERE {
    INCLUDE %result
      ?award rdfs:label ?awardLabel . FILTER (LANG(?awardLabel) = 'en')
  }
  GROUP BY ?count ?award ?awardLabel ?recipients ?recipientsUrl
  ORDER BY DESC(?count)
  

Try it!

🪣 Organizations

🪣 Institutions associated with authors publishing about invasion biology

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , author (P50)   , employer (P108)   , member of (P463)   , affiliation (P1416)   , part of (P361)   

  #defaultView:Table
  SELECT ?count ?organization ?organizationLabel ?sample_author ?sample_authorLabel
  WITH {
    SELECT (count(DISTINCT ?work) as ?count) ?organization (SAMPLE(?author) AS ?sample_author) WHERE {
      ?work wdt:P6104 wd:Q56241615 .
      ?work wdt:P921 ?topic . 
      ?work wdt:P50 ?author .
      ?author ( wdt:P108 | wdt:P463 | wdt:P1416 ) / wdt:P361* ?organization . 
    }
    GROUP BY ?organization ?sample_author
    ORDER BY DESC(?count)
    LIMIT 200
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . } 
  }
  GROUP BY ?count ?organization ?organizationLabel ?sample_author ?sample_authorLabel
  ORDER BY DESC(?count)
  

Try it!

🪣 Chemicals

🪣 Chemicals within scope of the project

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , InChIKey (P235)   , ChEBI ID (P683)   

  #title: Chemicals associated with the invasion biology literature
  
  SELECT 
    DISTINCT 
      ?topic ?topicLabel 
      ?count 
      ?SamplePaper ?SamplePaperLabel
      (CONCAT('https://scholia.toolforge.org/topics/Q42985020,Q183368,', ENCODE_FOR_URI(REPLACE(STR(?topic), ".*Q", "Q"))) AS ?curation_url ) 
  WITH {
    SELECT 
    ?topic
    (COUNT(?paper_) AS ?count)
    (SAMPLE(?paper_) AS ?SamplePaper)
    {
      ?paper_ wdt:P6104 wd:Q56241615 ;
              wdt:P921 ?topic .
    }
    GROUP BY ?topic ?count ?SamplePaper
  }
  AS %topics
  WHERE {
    INCLUDE %topics
    { ?topic wdt:P235 ?InChIKey .}
    UNION
    { ?topic wdt:P683 ?ChEBI .}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?topic ?topicLabel ?count ?SamplePaper ?SamplePaperLabel ?curation_url 
  ORDER BY DESC(?count)
  

Chemicals associated with the invasion biology literature

🪣 Habitats

🪣 Map of geolocated entities co-occurring with invasive species in the literature

The following query uses these:

• Properties: main subject (P921)   , instance of (P31)   , subclass of (P279)   , part of (P361)   , facet of (P1269)   , coordinate location (P625)   

Features: map (Q24515275)   

#defaultView:Map

PREFIX target: <http://www.wikidata.org/entity/Q183368>

SELECT
  ?location ?locationLabel
  ?geo
  ?example_work ?example_workLabel
WITH {
  SELECT
    ?location ?geo
    (SAMPLE(?work) AS ?example_work)
  WHERE {
    # Find works that are marked with main subject of the topic.
    ?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target: .
    
    # Identify co-occuring topic that is geo-locatable. 
    ?work wdt:P921 ?location .
    ?location wdt:P625 ?geo .
  }
  GROUP BY ?location ?geo
} AS %results
WHERE {
  INCLUDE %results
  
  # Label the results
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh".
  }
}

Try it!

🪣 Journals

🪣 Journals publishing about invasive species

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , published in (P1433)   , part of the series (P179)   , short name (P1813)   , main subject (P921)   

  #defaultView:Table
  SELECT ?count ?short_name ?venue ?venueLabel ?topic ?topicLabel
  WITH {
    SELECT (count(?work) as ?count) ?venue (SAMPLE(?short_name_) AS ?short_name) WHERE {
      ?work wdt:P6104 wd:Q56241615 .
      ?work wdt:P1433/wdt:P179* ?venue .
      OPTIONAL { ?venue wdt:P1813 ?short_name_ . }
    }
    GROUP BY ?venue
  } AS %result
  WHERE {
    INCLUDE %result
    OPTIONAL  { ?venue wdt:P921 ?topic }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  ORDER BY DESC(?count)
  

Try it!

🪣 Methods

🪣 Methods used for research described in in-scope publications

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , describes a project that uses (P4510)   

  SELECT
    ?count
    ?use ?useLabel 
    ?useDescription
    ?example_work ?example_workLabel
  WITH {
    SELECT
      (COUNT(?work) AS ?count)
      ?use
      (SAMPLE(?work) AS ?example_work)
    {
      ?work wdt:P6104 wd:Q56241615 ;
            wdt:P4510 ?use .
    }
    GROUP BY ?use
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  ORDER BY DESC(?count)
  

Try it!

🪣 Lexemes

🪣 Overview

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: item for this sense (P5137)   , maintained by WikiProject (P6104)   

  #title: Items within scope of WikiProject Invasion biology, sorted by number of languages with associated lexemes
  # adapted from https://w.wiki/5H28
  SELECT ?item ?itemLabel ?count ?langExample ?langExampleLabel (SAMPLE(?lexeme) AS ?lexemeExample) (SAMPLE(?lemma) AS ?lemmaExample) (SAMPLE(?sens) AS ?sense) {
    {
      SELECT ?item (COUNT(DISTINCT ?lang) AS ?count) (SAMPLE(?lang) AS ?langExample) {
        ?sens wdt:P5137 ?item .
        ?lexeme ontolex:sense ?sens ;
                dct:language ?lang .
        ?item wdt:P6104 wd:Q56241615 .
    
      } 
      GROUP BY ?item
    }
    
    ?lexeme ontolex:sense ?sens ;
            dct:language ?langExample ;
            wikibase:lemma ?lemma .
    ?sens wdt:P5137 ?item .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?count ?langExample ?langExampleLabel ?lemmaExample
  ORDER BY DESC(?count)
  

Items within scope of WikiProject Invasion biology, sorted by number of languages with associated lexemes

🪣 Lexemes related to in-scope concepts

The following query uses these:

• Items: ecology (Q7150)   , invasion biology (Q42985020)   

• Properties: item for this sense (P5137)   , studied in (P2579)   

  #title: Concepts studied by ecology or invasion biology, sorted by number of languages with associated lexemes
  # adapted from https://w.wiki/5H28
  SELECT ?item ?itemLabel ?count ?langExample ?langExampleLabel (SAMPLE(?lexeme) AS ?lexemeExample) (SAMPLE(?lemma) AS ?lemmaExample) (SAMPLE(?sens) AS ?sense) {
    {
      SELECT ?item (COUNT(DISTINCT ?lang) AS ?count) (SAMPLE(?lang) AS ?langExample) {
        ?sens wdt:P5137 ?item .
        ?lexeme ontolex:sense ?sens ;
                dct:language ?lang .
        { ?item wdt:P2579 wd:Q7150 . }
        UNION
        { ?item wdt:P2579 wd:Q42985020 . }
      } 
      GROUP BY ?item
    }
    
    ?lexeme ontolex:sense ?sens ;
            dct:language ?langExample ;
            wikibase:lemma ?lemma .
    ?sens wdt:P5137 ?item .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?count ?langExample ?langExampleLabel ?lemmaExample
  ORDER BY DESC(?count)
  

Concepts studied by ecology or invasion biology, sorted by number of languages with associated lexemes

🪣 Lexemes related to in-scope taxa

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: item for this sense (P5137)   , maintained by WikiProject (P6104)   , taxon name (P225)   

  #title: Taxa within scope of WikiProject Invasion biology, sorted by number of languages with associated lexemes
  # adapted from https://w.wiki/5H28
  SELECT ?item ?itemLabel ?taxonname ?count ?langExample ?langExampleLabel (SAMPLE(?lexeme) AS ?lexemeExample) (SAMPLE(?lemma) AS ?lemmaExample) (SAMPLE(?sens) AS ?sense) {
    {
      SELECT ?item ?taxonname (COUNT(DISTINCT ?lang) AS ?count) (SAMPLE(?lang) AS ?langExample) {
        ?sens wdt:P5137 ?item .
        ?lexeme ontolex:sense ?sens ;
                dct:language ?lang .
        ?item wdt:P6104 wd:Q56241615 ;
              wdt:P225 ?taxonname .
      } 
      GROUP BY ?item ?taxonname
    }
    
    ?lexeme ontolex:sense ?sens ;
            dct:language ?langExample ;
            wikibase:lemma ?lemma .
    ?sens wdt:P5137 ?item .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?taxonname ?count ?langExample ?langExampleLabel ?lemmaExample
  ORDER BY DESC(?count)
  

Taxa within scope of WikiProject Invasion biology, sorted by number of languages with associated lexemes

⚽ Community queries

⚽ Recent changes

Scholia's curation pages (example) now point to a set of recent changes pages in a way that is generic for a given Scholia page. The links below point to pages that list recent changes to pages that are

• about items within scope of this WikiProject
  • 100 random items edited over the last 7 days
    • variant
  • 100 random items edited over the last 70 days
  • 100 random items edited over the last 700 days
  • 100 random items edited over the last 7000 days (Wikidata is not to reach that age before December 2031, but as long as the tool is operational until then, the query gives the entire history of the respective items)
  • 1000 random items edited over the last day
• linking to the Wikidata item for this WikiProject
• linked from the Wikidata item for this WikiProject
• linked from this page
• linking to this page.
• about items with an Invasive Species Compendium Datasheet ID (P5698)

⚽ Overlap with other WikiProjects

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

Features: BubbleChart (Q24515280)   

#defaultView:BubbleChart

PREFIX target: <http://www.wikidata.org/prop/direct/P6104>

SELECT ?count ?o ?oLabel 
WITH {
  SELECT (COUNT(?s) AS ?count) ?o WHERE {
    ?s target: wd:Q56241615 .
    ?s target: ?o .
    FILTER (?o != wd:Q56241615)
  }
  GROUP BY ?o
  ORDER BY DESC(?count)
  LIMIT 100
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language  "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . }
}
ORDER BY DESC(?count)

Try it!

🌿 Property queries

🌿 Properties used on items about invasive species

More precisely, the query asks about properties used on items that have a Global Invasive Species Database ID (P5626): identifier for a taxon in the IUCN's Global Invasive Species Database.

The following query uses these:

• Properties: Global Invasive Species Database ID (P5626)   

  SELECT DISTINCT ?property ?propertyLabel ?count
  WITH {
    SELECT DISTINCT ?property (COUNT(*) AS ?count) WHERE {
      ?item wdt:P5626 [];
      ?p [ ] .
      ?property a wikibase:Property;
                  wikibase:claim ?p.
    }
    GROUP BY ?property 
    } AS %results WHERE {
    INCLUDE %results.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  ORDER BY DESC(?count)
  LIMIT 100
  

Try it!

🌿 External identifier properties used on items about works within scope of the project

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , title (P1476)   

  SELECT ?ExternalIdentifierProperty ?ExternalIdentifierPropertyLabel ?count WHERE {
      {
          SELECT ?ExternalIdentifierProperty (COUNT(DISTINCT ?item) AS ?count) WHERE {
             
             hint:Query hint:optimizer "None" .
             ?item wdt:P6104 wd:Q56241615 ;
                   wdt:P1476 ?title .
             ?item ?p ?id .
             ?ExternalIdentifierProperty wikibase:directClaim ?p; wikibase:propertyType wikibase:ExternalId.     
          }  GROUP BY ?ExternalIdentifierProperty
      }
      SERVICE wikibase:label {
          bd:serviceParam wikibase:language "en" .
      }
  }
  ORDER BY DESC(?count)
  

Try it!

🌿 Properties maintained by the WikiProject

🌿 List of properties maintained by the WikiProject

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   

  #:title: List of properties maintained by the WikiProject
  SELECT DISTINCT ?property ?propertyLabel (COUNT(DISTINCT ?entity) AS ?count) WHERE {
    ?entity wdt:P6104 wd:Q56241615 .
    ?entity ?p [ ] .
    ?property a wikibase:Property;
                wikibase:claim ?p.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  GROUP BY ?property ?propertyLabel
  ORDER BY DESC(?count)
  

Try it!

🌿 Properties used on properties maintained by the WikiProject

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   

  #:title: Properties used on properties maintained by the WikiProject
  SELECT DISTINCT ?property ?propertyLabel ?count
  WITH {
    SELECT DISTINCT ?entity WHERE {
      ?entity wdt:P6104 wd:Q56241615 .
    }
    LIMIT 200000
    } AS %items 
  WITH {
    SELECT DISTINCT ?property (COUNT(*) AS ?count) WHERE {
    INCLUDE %items.
      ?entity ?p [ ] .
      ?property a wikibase:Property;
                  wikibase:claim ?p.
    }
    GROUP BY ?property 
    LIMIT 100
    } AS %results 
  WHERE {
    INCLUDE %results.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  ORDER BY DESC(?count)
  LIMIT 100
  

Try it!

🚧 Maintenance queries

In the following queries, the expected outcome is that there are no results. If there are, this means that some curation is necessary, and to facilitate that, the query variables are arranged such that commenting out the line after the (first or only) DISTINCT line will yield output that can be pasted into QuickStatements to make corresponding edits. Before running such QuickStatements batches, please check those planned edits.

🚧 Works with X in their title but no statement about X being their main subject

🚧 X = 'invasive species'

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q183368" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "invasive species haswbstatement:P31=Q13442814 -haswbstatement:P921=Q183368".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "invasive(.)species").
  
  }
  

Try it!

🚧 X = 'invasion biology'

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q42985020" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "invasion biology haswbstatement:P31=Q13442814 -haswbstatement:P921=Q42985020".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "invasion(.)biology").
  
  }
  

Try it!

🚧 X = 'invasion ecology'

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q105094378" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "invasion ecology haswbstatement:P31=Q13442814 -haswbstatement:P921=Q105094378".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "invasion(.)ecology").
  
  }
  

Try it!

🚧 X = 'invasion science'

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q113050263" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "invasion science haswbstatement:P31=Q13442814 -haswbstatement:P921=Q113050263".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "invasion(.)science").
  
  }
  

Try it!

🚧 X = 'invasion success'

See also https://w.wiki/65fC.

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q109467185" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "invasion success haswbstatement:P31=Q13442814 -haswbstatement:P921=Q109467185".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "invasion(.)success").
  
  }
  

Try it!

🚧 X = 'biological invasion'

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q446911" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "biological invasion haswbstatement:P31=Q13442814 -haswbstatement:P921=Q446911".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "biological(.)invasion").
  
  }
  

Try it!

🚧 X = 'biotic invasion'

'Biotic invasion' is an alias to biological invasion (Q446911).

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q446911" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "biotic invasion haswbstatement:P31=Q13442814 -haswbstatement:P921=Q446911".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "biotic(.)invasion").
  
  }
  

Try it!

🚧 X = 'propagule pressure'

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q7250076" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "propagule pressure haswbstatement:P31=Q13442814 -haswbstatement:P921=Q7250076".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "propagule(.)pressure").
  
  }
  

Try it!

🚧 X = 'aquatic invasion'

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q110758984" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "aquatic invasion haswbstatement:P31=Q13442814 -haswbstatement:P921=Q110758984".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "aquatic(.)invasion").
  
  }
  

Try it!

🚧 X = 'enemy release hypothesis'

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q85759287" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "enemy release hypothesis haswbstatement:P31=Q13442814 -haswbstatement:P921=Q85759287".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "enemy(.)release(.)hypothesis").
  
  }
  

Try it!

🚧 Works with hypotheses-related titles but no statement about any specific hypotheses being their main subject

The following query uses these:

• Items: species (Q7432)   

• Properties: title (P1476)   , main subject (P921)   , taxon rank (P105)   , taxon name (P225)   

  SELECT DISTINCT ?Taxon ?TaxonName ?SampleWork ?SampleTitle ?WorkCount
  WITH {
    SELECT ?work WHERE {
      hint:Query hint:optimizer "None".
  
      {  SERVICE wikibase:mwapi {
        bd:serviceParam wikibase:api "Search";
                        wikibase:endpoint "www.wikidata.org";
                        mwapi:srsearch "\"hypothesis\" haswbstatement:P31=Q13442814 haswbstatement:P6104=Q56241615".
        ?page_title wikibase:apiOutput mwapi:title.
      }
      }
      UNION
      {  SERVICE wikibase:mwapi {
        bd:serviceParam wikibase:api "Search";
                        wikibase:endpoint "www.wikidata.org";
                        mwapi:srsearch "impact haswbstatement:P31=Q13442814 haswbstatement:P6104=Q56241615".
        ?page_title wikibase:apiOutput mwapi:title.
      }
      }    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?work)
    ?work wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "(\\bhypothesis\\b|\\bimpact)").
    }
  }
  AS %works
  WITH {
    SELECT ?Taxon ?TaxonName (SAMPLE(?work) AS ?SampleWork) (COUNT(?work) AS ?WorkCount) WHERE {
      INCLUDE %works
      ?work wdt:P921 ?Taxon .
      ?Taxon wdt:P105 wd:Q7432 .
      ?Taxon wdt:P225 ?TaxonName .
    }
    GROUP BY ?Taxon ?TaxonName ?SampleWork ?WorkCount
  }
  AS %taxa
  WHERE {
    INCLUDE %works
    INCLUDE %taxa
    ?SampleWork wdt:P1476 ?SampleTitle .
  }
  GROUP BY ?Taxon ?TaxonName ?SampleWork ?SampleTitle ?WorkCount
  ORDER BY DESC(?WorkCount)
  

Try it!

🚧 Hypotheses-related n-grams in titles of papers within scope of this WikiProject

The following query uses these:

• Properties: maintained by WikiProject (P6104)   , title (P1476)   , KIT Linked Open Numbers ID (P5176)   , numeric value (P1181)   

  PREFIX target: <http://www.wikidata.org/entity/Q56241615>
  SELECT DISTINCT ?Ngram ?N ?Count ?Length ?Dashes ?Score ?ExamplePub ?ExamplePubTitle
  
  WITH
  { # Generating a list of entities to be analyzed
    SELECT ?Publication
     { 
        SERVICE bd:sample { ?Publication wdt:P6104 target: . bd:serviceParam bd:sample.limit 100000 }   
     }
  } AS %items 
  WITH
  { # Preprocessing the titles
    SELECT ?Title ?Publication ?Seeds ?ClearTitleLength
     { 
        INCLUDE %items
        ?Publication wdt:P1476 ?Title.
        BIND (REPLACE(STR(?Title),"[\\.:,;\\[\\]\\?()$]","") AS ?ClearTitle) # remove some frequent special characters, including colons and semicolons
        BIND(STRLEN(?ClearTitle) AS ?ClearTitleLength) 
        FILTER(LANG(?Title)="en") 
        FILTER REGEX(LCASE(?Title), "\\bhypothes(i|e)(s|z)").
        # Basic processing of the titles
        BIND ("::: ::: ::: ::: ::: ::: ::: ::: " AS ?StartCodon)
        BIND (" ;;; ;;; ;;; ;;; ;;; ;;; ;;; ;;;" AS ?StopCodon)
        BIND (LCASE(CONCAT(?StartCodon , # add start codon of colons to assist with processing of n-grams at beginning of title
                              ?ClearTitle, 
                              ?StopCodon)) # add stop codon of semicolons to assist with processing of n-grams at end of title
                       AS ?Seeds )
     }
  } AS %titles 
  WITH
  { # Generating a list of regexes to look for the NumericValue-th word in a string     
    # Based on https://w.wiki/KG$ by Jura1
    SELECT ?Regex1 ?Regex2 ?Regex3 ?Regex4 ?NumericValue 
      { 
        ?NumberItem wdt:P5176 []; wdt:P1181 ?NumericValue . 
        FILTER( ?NumericValue > 0 ) 
        FILTER( ?NumericValue < 151)
        BIND("^([^ ]+ ){" AS ?RegexStart)
        BIND("}([^ ]+) .*" AS ?RegexEnd)
        BIND( CONCAT( ?RegexStart , STR( ?NumericValue - 1 ), ?RegexEnd ) AS ?Regex1)
        BIND( CONCAT( ?RegexStart , STR( ?NumericValue + 1 ), ?RegexEnd ) AS ?Regex2) 
        BIND( CONCAT( ?RegexStart , STR( ?NumericValue + 3 ), ?RegexEnd ) AS ?Regex3) 
        BIND( CONCAT( ?RegexStart , STR( ?NumericValue + 5 ), ?RegexEnd ) AS ?Regex4) 
      }
  } AS %regexes 
  WITH
  { # Applying the regexes to the titles to extract ngrams, and counting occurrences of the ngrams across titles
    SELECT 
      DISTINCT ?Ngram 
      ?N
      (COUNT(DISTINCT ?Title) AS ?Count)
      ?Length
      ?Dashes
      (( ?Count * ?Length * ( (?Dashes +1) / ?N) 
       ) AS ?Score)
      (SAMPLE(DISTINCT ?Publication) AS ?ExamplePub)
        { 
          INCLUDE %regexes
          INCLUDE %titles
          BIND( 
            (CONCAT(
              REPLACE(?Seeds, ?Regex1, "$1"), " ", 
              REPLACE(?Seeds, ?Regex1, "$2"), " ", 
              REPLACE(?Seeds, ?Regex2, "$1"), " ", 
              REPLACE(?Seeds, ?Regex2, "$2"), " ", 
              REPLACE(?Seeds, ?Regex3, "$1"), " ", 
              REPLACE(?Seeds, ?Regex3, "$2"), " ", 
              REPLACE(?Seeds, ?Regex4, "$1"), " ", 
              REPLACE(?Seeds, ?Regex4, "$2")
            )
          ) AS ?NgramCandidate) 
                              
          BIND( 
            (REPLACE
             (REPLACE
              (REPLACE
               (REPLACE
                (STR(?NgramCandidate),"([;:])",""),
                "(^\\s+)",""),
               "(\\s+$)",""),
              "([ ]{2,})"," ")
            ) AS ?Ngram) 
  
          BIND(STRLEN(?Ngram) AS ?Length) 
          FILTER (?Length > 3 )  
          FILTER (?Length <= ?ClearTitleLength )  
  
          BIND(STRLEN(REPLACE(?Ngram, "\\S", "")) + 1 as ?N)
          BIND((STRLEN(?Ngram) - STRLEN(REPLACE(?Ngram, "-", "")))  as ?Dashes)
        }
    GROUP BY ?Ngram ?N ?Count ?Length ?Dashes ?Score ?ExamplePub
  #   HAVING(?Count > 1)
  } AS %ngrams 
  WHERE {
    INCLUDE %ngrams 
    # Exclude Ngrams starting or ending with any of a set of blacklisted words
    BIND("(a|and|between|during|for|from|in|of|on|or|the|to|with)" AS ?blacklist)
    BIND( CONCAT( "(^", ?blacklist ,")+( )+") AS ?RegexBlackStart)
    BIND( CONCAT( "( )+(", ?blacklist ,")+$") AS ?RegexBlackEnd)
    FILTER (!REGEX(?Ngram, ?RegexBlackStart))
    FILTER (!REGEX(?Ngram, ?RegexBlackEnd))
  
    ?ExamplePub wdt:P1476 ?ExamplePubTitle.
    FILTER(LANG(?ExamplePubTitle)="en") 
  }
  GROUP BY ?Ngram ?N ?Count ?Length ?Dashes ?Score ?ExamplePub ?ExamplePubTitle
  ORDER BY DESC(?Score) DESC(?Count) DESC(?Length)
  LIMIT 200
  

Try it!

🚧 Taxa ranked by number of in-scope works that have their name in the title, along with either or both of the strings "hypothesis" and "impact"

The following query uses these:

• Items: species (Q7432)   

• Properties: main subject (P921)   , taxon rank (P105)   , taxon name (P225)   , title (P1476)   

  SELECT DISTINCT ?Taxon ?TaxonName ?SampleWork ?SampleTitle ?WorkCount
  WITH {
    SELECT ?work WHERE {
      hint:Query hint:optimizer "None".
  
      {  SERVICE wikibase:mwapi {
        bd:serviceParam wikibase:api "Search";
                        wikibase:endpoint "www.wikidata.org";
                        mwapi:srsearch "\"hypothesis\" haswbstatement:P31=Q13442814 haswbstatement:P6104=Q56241615".
        ?page_title wikibase:apiOutput mwapi:title.
      }
      }
      UNION
      {  SERVICE wikibase:mwapi {
        bd:serviceParam wikibase:api "Search";
                        wikibase:endpoint "www.wikidata.org";
                        mwapi:srsearch "impact haswbstatement:P31=Q13442814 haswbstatement:P6104=Q56241615".
        ?page_title wikibase:apiOutput mwapi:title.
      }
      }    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?work)
    }
  }
  AS %works
  WITH {
    SELECT ?Taxon ?TaxonName (SAMPLE(?work) AS ?SampleWork) (COUNT(?work) AS ?WorkCount) WHERE {
      INCLUDE %works
      ?work wdt:P921 ?Taxon .
      ?Taxon wdt:P105 wd:Q7432 .
      ?Taxon wdt:P225 ?TaxonName .
    }
    GROUP BY ?Taxon ?TaxonName ?SampleWork ?WorkCount
  }
  AS %taxa
  WHERE {
    INCLUDE %works
    INCLUDE %taxa
    ?SampleWork wdt:P1476 ?SampleTitle .
  }
  GROUP BY ?Taxon ?TaxonName ?SampleWork ?SampleTitle ?WorkCount
  ORDER BY DESC(?WorkCount)
  

Try it!

🚧 Habitat-related n-grams in titles of papers within scope of this WikiProject

See also IUCN's Habitat Classification Scheme.

The following query uses these:

• Properties: maintained by WikiProject (P6104)   , title (P1476)   , KIT Linked Open Numbers ID (P5176)   , numeric value (P1181)   

  PREFIX target: <http://www.wikidata.org/entity/Q56241615>
  SELECT DISTINCT ?Ngram ?N ?Count ?Length ?Dashes ?Score ?ExamplePub ?ExamplePubTitle
  
  WITH
  { # Generating a list of entities to be analyzed
    SELECT ?Publication
     { 
        SERVICE bd:sample { ?Publication wdt:P6104 target: . bd:serviceParam bd:sample.limit 100000 }   
     }
  } AS %items 
  WITH
  { # Preprocessing the titles
    SELECT ?Title ?Publication ?Seeds ?ClearTitleLength
     { 
        INCLUDE %items
        ?Publication wdt:P1476 ?Title.
        BIND (REPLACE(STR(?Title),"[\\.:,;\\[\\]\\?()$]","") AS ?ClearTitle) # remove some frequent special characters, including colons and semicolons
        BIND(STRLEN(?ClearTitle) AS ?ClearTitleLength) 
        FILTER(LANG(?Title)="en") 
        FILTER REGEX(LCASE(?Title), "\\bhabitat(s?)\\b").
        # Basic processing of the titles
        BIND ("::: ::: ::: ::: ::: ::: ::: ::: " AS ?StartCodon)
        BIND (" ;;; ;;; ;;; ;;; ;;; ;;; ;;; ;;;" AS ?StopCodon)
        BIND (LCASE(CONCAT(?StartCodon , # add start codon of colons to assist with processing of n-grams at beginning of title
                              ?ClearTitle, 
                              ?StopCodon)) # add stop codon of semicolons to assist with processing of n-grams at end of title
                       AS ?Seeds )
     }
  } AS %titles 
  WITH
  { # Generating a list of regexes to look for the NumericValue-th word in a string     
    # Based on https://w.wiki/KG$ by Jura1
    SELECT ?Regex1 ?Regex2 ?Regex3 ?Regex4 ?NumericValue 
      { 
        ?NumberItem wdt:P5176 []; wdt:P1181 ?NumericValue . 
        FILTER( ?NumericValue > 0 ) 
        FILTER( ?NumericValue < 151)
        BIND("^([^ ]+ ){" AS ?RegexStart)
        BIND("}([^ ]+) .*" AS ?RegexEnd)
        BIND( CONCAT( ?RegexStart , STR( ?NumericValue - 1 ), ?RegexEnd ) AS ?Regex1)
        BIND( CONCAT( ?RegexStart , STR( ?NumericValue + 1 ), ?RegexEnd ) AS ?Regex2) 
        BIND( CONCAT( ?RegexStart , STR( ?NumericValue + 3 ), ?RegexEnd ) AS ?Regex3) 
        BIND( CONCAT( ?RegexStart , STR( ?NumericValue + 5 ), ?RegexEnd ) AS ?Regex4) 
      }
  } AS %regexes 
  WITH
  { # Applying the regexes to the titles to extract ngrams, and counting occurrences of the ngrams across titles
    SELECT 
      DISTINCT ?Ngram 
      ?N
      (COUNT(DISTINCT ?Title) AS ?Count)
      ?Length
      ?Dashes
      (( ?Count * ?Length * ( (?Dashes +1) / ?N) 
       ) AS ?Score)
      (SAMPLE(DISTINCT ?Publication) AS ?ExamplePub)
        { 
          INCLUDE %regexes
          INCLUDE %titles
          BIND( 
            (CONCAT(
              REPLACE(?Seeds, ?Regex1, "$1"), " ", 
              REPLACE(?Seeds, ?Regex1, "$2"), " ", 
              REPLACE(?Seeds, ?Regex2, "$1"), " ", 
              REPLACE(?Seeds, ?Regex2, "$2"), " ", 
              REPLACE(?Seeds, ?Regex3, "$1"), " ", 
              REPLACE(?Seeds, ?Regex3, "$2"), " ", 
              REPLACE(?Seeds, ?Regex4, "$1"), " ", 
              REPLACE(?Seeds, ?Regex4, "$2")
            )
          ) AS ?NgramCandidate) 
                              
          BIND( 
            (REPLACE
             (REPLACE
              (REPLACE
               (REPLACE
                (STR(?NgramCandidate),"([;:])",""),
                "(^\\s+)",""),
               "(\\s+$)",""),
              "([ ]{2,})"," ")
            ) AS ?Ngram) 
  
          BIND(STRLEN(?Ngram) AS ?Length) 
          FILTER (?Length > 3 )  
          FILTER (?Length <= ?ClearTitleLength )  
  
          BIND(STRLEN(REPLACE(?Ngram, "\\S", "")) + 1 as ?N)
          BIND((STRLEN(?Ngram) - STRLEN(REPLACE(?Ngram, "-", "")))  as ?Dashes)
        }
    GROUP BY ?Ngram ?N ?Count ?Length ?Dashes ?Score ?ExamplePub
  #   HAVING(?Count > 1)
  } AS %ngrams 
  WHERE {
    INCLUDE %ngrams 
    # Exclude Ngrams starting or ending with any of a set of blacklisted words
    BIND("(a|and|between|during|for|from|in|of|on|or|the|to|with)" AS ?blacklist)
    BIND( CONCAT( "(^", ?blacklist ,")+( )+") AS ?RegexBlackStart)
    BIND( CONCAT( "( )+(", ?blacklist ,")+$") AS ?RegexBlackEnd)
    FILTER (!REGEX(?Ngram, ?RegexBlackStart))
    FILTER (!REGEX(?Ngram, ?RegexBlackEnd))
  
    ?ExamplePub wdt:P1476 ?ExamplePubTitle.
    FILTER(LANG(?ExamplePubTitle)="en") 
  }
  GROUP BY ?Ngram ?N ?Count ?Length ?Dashes ?Score ?ExamplePub ?ExamplePubTitle
  ORDER BY DESC(?Score) DESC(?Count) DESC(?Length)
  LIMIT 200
  

Try it!

🚧 Invasion biology papers not tagged as being within scope of this WikiProject (whitelist)

The following query uses these:

• Items: invasion biology (Q42985020)   , invasion ecology (Q105094378)   , invasion science (Q113050263)   , biological invasion (Q446911)   , invasive species (Q183368)   , invasion success (Q109467185)   , propagule pressure (Q7250076)   , aquatic invasion (Q110758984)   , enemy release hypothesis (Q85759287)   , predation on invasive species (Q124217921)   , predation by invasive species (Q124217952)   , WikiProject Invasion Biology (Q56241615)   , parasitic egress (Q122674206)   , immunological parasite invasion (Q122208643)   

• Properties: main subject (P921)   , studied in (P2579)   , subclass of (P279)   , maintained by WikiProject (P6104)   , title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P6104" AS ?property)
    ("Q56241615" AS ?WikiProjectQID)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
    { ?item wdt:P921 wd:Q42985020 .}
    UNION
    { ?item wdt:P921 wd:Q105094378 .}
    UNION
    { ?item wdt:P921 wd:Q113050263 .}
  #   UNION
  #   { ?item wdt:P921 [ wdt:P2579  wd:Q42985020 ].} # this is about things studied by invasion biology - use with caution
    UNION
    { ?item wdt:P921 wd:Q446911 .}
    UNION
    { ?item wdt:P921 [ wdt:P279*  wd:Q446911 ].}
    UNION
    { ?item wdt:P921 wd:Q446911 .}
    UNION
    { ?item wdt:P921 wd:Q183368 .}
    UNION
    { ?item wdt:P921 [ wdt:P279*  wd:Q183368 ].}
    UNION
    { ?item wdt:P921 wd:Q109467185 .}
    UNION
    { ?item wdt:P921 wd:Q7250076 .}
    UNION
    { ?item wdt:P921 wd:Q110758984 .}
    UNION
    { ?item wdt:P921 wd:Q85759287 .}
    UNION
    { ?item wdt:P921 wd:Q124217921 .}
    UNION
    { ?item wdt:P921 wd:Q124217952 .}
  
    MINUS {?item wdt:P6104 wd:Q56241615 }
    
    MINUS {?item wdt:P921 wd:Q122674206 }  
    MINUS {?item wdt:P921 wd:Q122208643 }
  
    ?item wdt:P1476 ?title .
    FILTER (!REGEX(LCASE(?title), "(minimally|strand(.)invasion)|immun|tissue"))
  }
  

Try it!

🚧 Out-of scope papers that should not be tagged as being within scope of this WikiProject (blacklist)

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , parasitic egress (Q122674206)   , immunological parasite invasion (Q122208643)   , Invasion percolation (Q24902133)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , subclass of (P279)   , title (P1476)   

  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "-Q") AS ?qid) 
    ("P6104" AS ?property)
    ("Q56241615" AS ?WikiProjectQID)
  
  WHERE {
    ?item wdt:P6104 wd:Q56241615 .
    
    { ?item wdt:P921 wd:Q122674206 .}
    UNION
    { ?item wdt:P921 [ wdt:P279*  wd:Q122208643 ].}
    UNION
    { ?item wdt:P921 wd:Q24902133 .}
    
    ?item wdt:P1476 ?title .
  }
  

Try it!

🚧 Taxa not tagged as being within scope of this WikiProject but that co-occur with invasion biology in papers

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , taxon name (P225)   , taxon rank (P105)   

  #title: Taxa not tagged as being within scope of this WikiProject but that co-occur with invasion biology in papers
  
  SELECT 
    DISTINCT 
    ?topic ?taxonname (COUNT(?paper) AS ?count)
  
    (REPLACE(STR(?topic), ".*Q", "Q") AS ?qid) 
    ("P6104" AS ?property)
    ("Q56241615" AS ?ReplaceWithYourTargetID)
  
  WHERE {
    ?paper wdt:P6104 wd:Q56241615 ;
           wdt:P921 ?topic .
    ?topic wdt:P225 ?taxonname ;
           wdt:P105 wd:Q7432 .
    
    MINUS {?topic wdt:P6104 wd:Q56241615 .}
    
  }
  GROUP BY ?topic ?taxonname ?count ?qid ?property ?ReplaceWithYourTargetID
  ORDER BY DESC(?count)
  

Taxa not tagged as being within scope of this WikiProject but that co-occur with invasion biology in papers

🚧 Species with a Global Invasive Species Database ID (P5626) or an Invasive Species Compendium Datasheet ID (P5698) but not tagged as being within scope of this WikiProject

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   

• Properties: Invasive Species Compendium Datasheet ID (P5698)   , Global Invasive Species Database ID (P5626)   , maintained by WikiProject (P6104)   , image (P18)   , taxon rank (P105)   , taxon name (P225)   , main subject (P921)   

Features: ImageGrid (Q24515278)   

#title: Species with a Global Invasive Species Database ID (P5626) or an Invasive Species Compendium Datasheet ID (P5698) but not tagged as being within scope of this WikiProject
#defaultView:ImageGrid
SELECT DISTINCT ?item ?taxonname ?taxonrank (SAMPLE(?image_) AS ?image) ?linkcount WHERE {

  {?item wdt:P5698 [].} UNION {?item wdt:P5626 [].}
  FILTER NOT EXISTS {   ?item wdt:P6104 wd:Q56241615 . }
  ?item wdt:P18 ?image_ ;
        wdt:P105 wd:Q7432 ;
        wdt:P225 ?taxonname.
  ?work wdt:P921 ?item .
  ?item wikibase:sitelinks ?linkcount .
}
GROUP BY ?item ?taxonname ?taxonrank ?image ?linkcount

ORDER BY DESC(?linkcount)

Species with a Global Invasive Species Database ID (P5626) or an Invasive Species Compendium Datasheet ID (P5698) but not tagged as being within scope of this WikiProject

🚧 Works not tagged as being within scope of this WikiProject but that are tagged as being about in-scope taxa

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   

• Properties: maintained by WikiProject (P6104)   , taxon rank (P105)   , taxon name (P225)   , main subject (P921)   , title (P1476)   

  SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P6104" AS ?property)
  ("Q56241615" AS ?WikiProjectQID)
  WITH {
    SELECT DISTINCT ?taxon {
      SERVICE bd:sample { ?taxon wdt:P6104 wd:Q56241615 . bd:serviceParam bd:sample.limit 2000 }
      ?taxon wdt:P105 wd:Q7432 .
    }
  } AS %taxa
  WITH {
    SELECT DISTINCT ?item ?title {
      INCLUDE %taxa
      ?taxon wdt:P225 ?taxonname .
      ?item wdt:P921 ?taxon ;
            wdt:P1476 ?title .
      MINUS {?item wdt:P6104 wd:Q56241615 }
      FILTER REGEX(LCASE(?title), LCASE(?taxonname)).
    }
  } AS %papers
  WHERE {
    INCLUDE %papers
    FILTER REGEX(LCASE(?title), "\\b(invasive|non-native|invasion|exotic\\b|introduced)").
    FILTER (!REGEX(LCASE(?title), "\\b(disease|cancer|patho|escherichia|coli|medic|clinic|epidem|infectio|virus|protein|cell|non-invasive)")).
  }
  

Try it!

🚧 Works not tagged as being within scope of this WikiProject but with in-scope titles and written by authors of in-scope works

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   

• Properties: maintained by WikiProject (P6104)   , taxon rank (P105)   , taxon name (P225)   , main subject (P921)   , title (P1476)   

  SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P6104" AS ?property)
  ("Q56241615" AS ?WikiProjectQID)
  WITH {
    SELECT DISTINCT ?taxon {
      SERVICE bd:sample { ?taxon wdt:P6104 wd:Q56241615 . bd:serviceParam bd:sample.limit 20000 }
      ?taxon wdt:P105 wd:Q7432 .
    }
  } AS %taxa
  WITH {
    SELECT DISTINCT ?item ?title {
      INCLUDE %taxa
      ?taxon wdt:P225 ?taxonname .
      ?item wdt:P921 ?taxon ;
            wdt:P1476 ?title .
      MINUS {?item wdt:P6104 wd:Q56241615 }
      FILTER REGEX(LCASE(?title), LCASE(?taxonname)).
    }
  } AS %papers
  WHERE {
    INCLUDE %papers
    FILTER REGEX(LCASE(?title), "\\b(invasive|non(.?)native|invasion|exotic\\b|introduced)").
    FILTER REGEX(LCASE(?title), "(idae|ceae)\\b").
    FILTER (!REGEX(LCASE(?title), "(\\b(minimally|disease|cancer|patho|escherichia|coli|medic|clinic|epidem|infectio|virus|protein|cell|non-invasive|mutant)|cell)")).
  }
  

Try it!

🚧 Works tagged as being within scope of this WikiProject and as being about taxa but not as being about invasive species

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , invasive species (Q183368)   

• Properties: maintained by WikiProject (P6104)   , title (P1476)   , main subject (P921)   , taxon name (P225)   

  SELECT DISTINCT 
  ?item ?title ?taxon ?taxon_name
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    ("Q183368" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  WHERE { 
    ?item wdt:P6104 wd:Q56241615 ;
          wdt:P1476 ?title ;
          wdt:P921 ?taxon . 
    FILTER NOT EXISTS { ?item wdt:P921 wd:Q183368 }
    ?taxon wdt:P225 ?taxon_name .
    FILTER REGEX(LCASE(?title), "\\b(invasive|non-native|invasion|exotic|alien\\b|introduced)").
  }
  GROUP BY ?item ?title ?taxon ?taxon_name
  LIMIT 200
  

Try it!

🚧 In-scope works whose titles contain strings that correspond to names of taxa for which they have not been topic tagged

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , taxon name (P225)   , taxon rank (P105)   , title (P1476)   , parent taxon (P171)   

  SELECT DISTINCT
  (CONCAT(
  ENCODE_FOR_URI(REPLACE(STR(?i), ".*Q", "Q")), "|P921|", ENCODE_FOR_URI(REPLACE(STR(?ta), ".*Q", "Q")), "|P1932|", (CONCAT("\"", ?a, "\"")), "|S887|Q69652283") AS ?QuickStatements)
  WITH {
  SELECT DISTINCT ?ta WHERE {
  SERVICE bd:sample { ?p wdt:P6104 wd:Q56241615 . bd:serviceParam bd:sample.limit 100000 }
  ?p wdt:P921 ?ta .
  }
  } AS %topics
  WITH {
  SELECT DISTINCT ?ta ?n WHERE {
  INCLUDE %topics .
  ?ta wdt:P225 ?n .
  ?ta wdt:P105 wd:Q7432 .
  }
  LIMIT 25
  } AS %taxa
  WITH
  { SELECT ?i ?n ?ta ?ti WHERE {
  INCLUDE %taxa
  ?ta wdt:P225 ?n .
  SERVICE wikibase:mwapi
  {
  bd:serviceParam wikibase:endpoint "www.wikidata.org";
  wikibase:api "Generator";
  mwapi:generator "search";
  mwapi:gsrsearch ?n ;
  mwapi:gsrlimit "max".
  ?i wikibase:apiOutputItem mwapi:title.
  }
  ?i wdt:P1476 ?ti .
  MINUS {?i wdt:P921 ?ta }
  MINUS {?i wdt:P921 [wdt:P171* ?ta ] } 
  FILTER (REGEX(LCASE(?ti), LCASE(CONCAT( "\\", "b", ?n ,"\\", "b"))))
  FILTER (!REGEX(LCASE(?ti), LCASE(CONCAT( ?n ,"-"))))
  FILTER (!REGEX(LCASE(?ti), LCASE(CONCAT( ?n ,"(.)virus"))))
  FILTER (!REGEX(LCASE(?ti), LCASE(CONCAT( "pseudo(.?)", ?n))))
  }
  }
  AS %items
  WHERE {
  INCLUDE %items
  INCLUDE %taxa
  BIND (SUBSTR(?ti, STRLEN(STRBEFORE(REPLACE(?ti, ?n, "===HELP_STRING===", "i"), "===HELP_STRING===")) +1, STRLEN(?n)) AS ?a)
  }
  

Try it!

🚧 Works not tagged as being about the target topic but citing AND cited from works that are

The following query uses these:

• Properties: main subject (P921)   , instance of (P31)   , subclass of (P279)   , part of (P361)   , facet of (P1269)   , cites work (P2860)   , title (P1476)   

  #title: Works not tagged as being about the target topic but citing AND cited from works that are
  PREFIX target: <http://www.wikidata.org/entity/Q85759287>
  
  SELECT DISTINCT
    ?cited_work ?title ?count
    (REPLACE(STR(?cited_work), ".*Q", "Q") AS ?qid) 
    ("P921" AS ?property)
    (REPLACE(STR(target:), ".*Q", "Q") AS ?target) 
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WITH {
    SELECT (count(?work) as ?count) ?cited_work WHERE {
      { ?work wdt:P921/wdt:P31*/wdt:P279* target: . }
      union { ?work wdt:P921/wdt:P361+ target: . }
      union { ?work wdt:P921/wdt:P1269+ target: . }
      ?work wdt:P2860 ?cited_work .
    }
    GROUP BY ?cited_work
    ORDER BY DESC(?count)
    LIMIT 20000
  } AS %result
  WHERE {
    INCLUDE %result
    FILTER (?count > 20)
    FILTER NOT EXISTS {?cited_work wdt:P921 target: }
    ?cited_work wdt:P1476 ?title .
    ?cited_work wdt:P2860 [wdt:P921 target: ] .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  ORDER BY DESC(?count)
  LIMIT 200
  

Works not tagged as being about the target topic but citing AND cited from works that are

🚧 Works not tagged as being within scope of the WikiProject but citing AND cited from works that are

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , cites work (P2860)   , title (P1476)   

  #title: Works not tagged as being within scope of the WikiProject but citing AND cited from works that are
  PREFIX target: <http://www.wikidata.org/entity/Q56241615>
  
  SELECT DISTINCT
    ?cited_work ?title ?count
    (REPLACE(STR(?cited_work), ".*Q", "Q") AS ?qid) 
    ("P6104" AS ?property)
    (REPLACE(STR(target:), ".*Q", "Q") AS ?target) 
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WITH {
    SELECT (count(?work) as ?count) ?cited_work WHERE {
      ?work wdt:P6104 target: .
      ?work wdt:P2860 ?cited_work .
    }
    GROUP BY ?cited_work
    ORDER BY DESC(?count)
    LIMIT 20000
  } AS %result
  WHERE {
    INCLUDE %result
    FILTER (?count > 20)
    FILTER NOT EXISTS {?cited_work wdt:P6104 target: }
    ?cited_work wdt:P1476 ?title .
    ?cited_work wdt:P2860 [wdt:P6104 wd:Q56241615 ] .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  ORDER BY DESC(?count)
  LIMIT 200
  

Works not tagged as being within scope of the WikiProject but citing AND cited from works that are

🚧 Works that have (a) been published in in-scope venues but (b) not been tagged as being in scope themselves

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , ISSN (P236)   , published in (P1433)   , title (P1476)   

  #title: Works that have (a) been published in invasion biology venues but (b) not been tagged as being in scope of WikiProject Invasion Biology
  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P6104" AS ?property)
    ("Q56241615" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q124004081" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
    ?venue wdt:P6104 wd:Q56241615.
    ?venue wdt:P236 [].
    ?item wdt:P1433 ?venue.
    
    FILTER NOT EXISTS { ?item wdt:P6104 wd:Q56241615. }
  
    ?item wdt:P1476 ?title_.
    ?venue wdt:P1476 ?venue_title.
    ?venue wdt:P6104 wd:Q56241615.
    BIND(CONCAT(?title_ , " | " , ?venue_title)  AS ?title)
  
  }
  

Works that have (a) been published in invasion biology venues but (b) not been tagged as being in scope of WikiProject Invasion Biology

🚧 Common author name strings

The corresponding authors need to be identified and tagged via author (P50): main creator(s) of a written work (use on works, not humans); use P2093 (author name string) when Wikidata item is unknown or does not exist, with the author name string from author name string (P2093): stores unspecified author or editor name for publications; use if Wikidata item for author (P50) or editor (P98) does not exist or is not known. Do not use both. statement added via object named as (P1932): use as qualifier to indicate how the object's value was given in the source. This can be achieved using the Author Disambiguator based on this Wikidata list.

🚧 Common author name strings on publications about invasion biology

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , author name string (P2093)   

  #defaultView:Table
  SELECT ?count ?authornamestring ?sample_pub ?sample_pubLabel
    (CONCAT(
        'https://tools.wmflabs.org/author-disambiguator/names_oauth.php?name=',
        ENCODE_FOR_URI(?authornamestring)) AS ?generic_resolver_url)
    (CONCAT(
        'https://author-disambiguator.toolforge.org/names_oauth.php?doit=Look+for+author&limit=5000&filter=wdt%3AP6104+wd%3AQ56241615&name=',
        ENCODE_FOR_URI(?authornamestring)) AS ?specific_resolver_url)
  WITH {
    SELECT (count(DISTINCT ?work) as ?count) ?authornamestring (SAMPLE(?work) AS ?sample_pub) WHERE {
      ?work wdt:P6104 wd:Q56241615 .
      ?work wdt:P2093 ?authornamestring .
    }
    GROUP BY ?authornamestring
    ORDER BY DESC(?count)
    LIMIT 200
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . } 
  }
  ORDER BY DESC(?count)
  

Try it!

🚧 Random selection of common author name strings associated with authors known to have published about invasion biology

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , author (P50)   , author name string (P2093)   , object named as (P1932)   

  SELECT
    (COUNT(?work) AS ?count) 
    ?author_name 
    (CONCAT(
        'https://tools.wmflabs.org/author-disambiguator/names_oauth.php?limit=5000&name=',
        ENCODE_FOR_URI(?author_name)) AS ?generic_resolver_url)
    (CONCAT(
        'https://author-disambiguator.toolforge.org/names_oauth.php?precise=0&doit=Look+for+author&limit=1000&filter=wdt%3AP6104+wd%3AQ56241615&filter_authors=1&name=',
        ENCODE_FOR_URI(?author_name)) AS ?specific_resolver_url)
  WITH {
   
      SELECT DISTINCT ?author_name WHERE {
        { 
          SERVICE bd:sample { ?work wdt:P6104 wd:Q56241615 . bd:serviceParam bd:sample.limit 10000 }
          ?work wdt:P50 ?author .
          { ?author skos:altLabel ?author_name_. }
          UNION
          { ?author rdfs:label ?author_name_. }
          BIND(STR(?author_name_) AS ?author_name)
        }
        UNION
        {
          ?author_statement ps:P50 ?author;
            pq:P1932 ?author_name.
        }
      }
      LIMIT 2000 
  }
  AS %name_strings
  WHERE {
    INCLUDE %name_strings
    ?work wdt:P2093 ?author_name. 
  }
  
  GROUP BY ?author_name
  ORDER BY DESC (?count)
  

Try it!

🚧 Common author name strings associated with works by authors known to have published about invasion biology

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , author name string (P2093)   

  SELECT
    # Number of works on the topic with the author name string
    ?count
  
    # Number of works with the author name string
    ?count1
  
    # Author as a string
    ?authorstring
  
    # Build URL to the Author disambiguator tool
    (CONCAT(
        'https://tools.wmflabs.org/author-disambiguator/names_oauth.php?name=',
        ENCODE_FOR_URI(?authorstring)) AS ?resolver_url)
  WITH {
    SELECT DISTINCT ?work ?authorstring WHERE {
      SERVICE bd:sample { ?work wdt:P6104 wd:Q56241615 . bd:serviceParam bd:sample.limit 100000 }   
      ?work wdt:P2093 ?authorstring .
    }
    LIMIT 10000
  } AS %works
  WITH {
    SELECT
      (COUNT(DISTINCT ?work) AS ?count)
      (COUNT(DISTINCT ?work1) AS ?count1)
      ?authorstring
    WHERE {
      INCLUDE %works
      ?work1 wdt:P2093 ?authorstring .
    }
    GROUP BY ?authorstring
  } AS %result
  WHERE {
    INCLUDE %result
  }
  ORDER BY DESC(?count) DESC(?count1)
  LIMIT 200
  

Try it!

🚧 Common author name strings on publications tagged as being in scope of this WikiProject

The following query uses these:

• Properties: maintained by WikiProject (P6104)   , DOI (P356)   , author name string (P2093)   , cites work (P2860)   

  PREFIX target: <http://www.wikidata.org/entity/Q56241615>
  
  SELECT
    # Number of works with the author
    ?count
  
    # Author score - 3 points for authoring a work, 1 for being cited
    ?score
  
    # Author as a string
    ?author
  
    # Build URL to the Author disambiguator tool
    (URI(CONCAT(
        'https://author-disambiguator.toolforge.org/names_oauth.php?doit=Look+for+author&name=',
        ENCODE_FOR_URI(?author))) AS ?resolver_url)
  WITH {
    SELECT DISTINCT ?work WHERE {
      ?work wdt:P6104 target: ;
            wdt:P356 ?doi .
    }
    LIMIT 1000
  } AS %works
  WITH {
    SELECT
      (COUNT(?work) AS ?count)
      ?author
    WHERE {
      INCLUDE %works
      ?work wdt:P2093 ?author .
    }
    GROUP BY ?author
  } AS %result
  
  # Generate a score for each author
  WITH {
    SELECT (SUM(?score_) AS ?score) ?author
    WHERE {
      {
        # Assign them 3 points if they are an author of a work on the subject
        SELECT (3 AS ?score_) ?author ?work WHERE {
          ?work wdt:P2093 ?author .
          ?work wdt:P6104 target: .
        }
      }
      UNION
      {
        # Assign them 1 point if they are the author of a work that is cited by a work on the subject
        SELECT (1 AS ?score_) ?author ?work WHERE {
          ?work wdt:P2093 ?author .
          ?citing_work wdt:P2860 ?work .
          ?citing_work wdt:P6104 target: .
        }
      }
    }
    GROUP BY ?author
  } AS %scores
  
  WHERE {
    INCLUDE %result
    INCLUDE %scores
  
    # Label the result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . }
  }
  ORDER BY DESC(?count) DESC(?score)
  LIMIT 200
  

Try it!

🚧 Invasive species without an image on Wikidata

See also Tarsier (perhaps in combination with Jupyter) and Invasive species without image but with Commons category.''

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , species (Q7432)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   , taxon name (P225)   , taxon rank (P105)   , image (P18)   

  SELECT 
  DISTINCT 
  ?taxon ?taxonname 
  ?papercount
  ?linkcount
  ?score
  WITH {
    SELECT 
    ?taxon ?taxonname 
           (COUNT(?paper) AS ?papercount)
           {
             ?paper wdt:P6104 wd:Q56241615 ;
                    wdt:P921 ?taxon .
             ?taxon wdt:P225 ?taxonname ;
                    wdt:P105 wd:Q7432 .
             MINUS {?taxon wdt:P18 ?image}
  
           }
    GROUP BY ?taxon ?taxonname ?papercount 
  
  } AS %papers
  WHERE {
    INCLUDE %papers
            ?taxon wikibase:sitelinks ?linkcount .
    BIND ((?papercount +1) * (?linkcount +1 ) AS ?score)
  }
  GROUP BY ?taxon ?taxonname ?papercount ?linkcount ?score
  ORDER BY DESC(?score)
  LIMIT 200
  

Try it!

🚧 In-scope items with no image on Wikidata but with a category on Wikimedia Commons

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , Commons category (P373)   , image (P18)   

  SELECT 
  DISTINCT 
  ?item ?itemLabel ?commonscat
  WHERE {
    ?item wdt:P6104 wd:Q56241615 ;
          wdt:P373 ?commonscat .
    MINUS {?item wdt:P18 ?image}
    ?item wikibase:sitelinks ?sitelinks .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  ORDER BY DESC(?sitelinks)
  LIMIT 200
  

Try it!

🚧 In-scope works without language statements

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , DOI (P356)   , title (P1476)   , language of work or name (P407)   

  SELECT  
    DISTINCT
      ?item ?title
      (CONCAT(
        ENCODE_FOR_URI(REPLACE(STR(?item), ".*Q", "Q")), "|P407|Q1860|S887|Q69652283") AS ?QuickStatements)
  WITH {
    SELECT ?item ?title WHERE {
    ?item wdt:P6104 wd:Q56241615 ;
    wdt:P356 [] ;
          wdt:P1476 ?title .
    MINUS {?item wdt:P407 []. }
    }
    LIMIT 20000
  } AS %items
  WHERE {
    INCLUDE %items
    FILTER (REGEX(LCASE(?title), "\\b(the|and|which|with|why|where|what|from)\\b"))
    FILTER (!REGEX(LCASE(?title), "^\\[.*\\]$"))
  }
  ORDER BY DESC(?QuickStatements)
  LIMIT 10000
  

Try it!

🚧 Works without number of pages

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , number of pages (P1104)   , page(s) (P304)   

  SELECT 
  ?qs 
  # ?paper ?pages ?start_page ?end_page ?number_of_pages
  WHERE {
    { BIND("qid,P1104,S887" AS ?qs) }
    UNION
    {
      SERVICE bd:sample { ?paper wdt:P6104 wd:Q56241615 .bd:serviceParam bd:sample.limit 10000 }
      MINUS { ?paper wdt:P1104 [] }
      ?paper wdt:P304 ?pages . 
      FILTER REGEX(?pages, "^[1-9][0-9]*-[1-9][0-9]*$")
      BIND(xsd:integer(STRBEFORE(?pages, "-")) AS ?start_page)
      BIND(xsd:integer(STRAFTER(?pages, "-")) AS ?end_page)
      FILTER (STRLEN(?end_page) < STRLEN(?start_page))
      BIND(?end_page - ?start_page + 1 AS ?number_of_pages)
      FILTER (?number_of_pages > 0)
      BIND(CONCAT(SUBSTR(STR(?paper), 32), ",", STR(?number_of_pages), ",Q110768064") AS ?qs)
    }
  }
  

Try it!

🚧 Items about invasion biology hypothesis papers without license statement

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , hypothesis (Q41719)   , open license (Q30939938)   

• Properties: maintained by WikiProject (P6104)   , DOI (P356)   , main subject (P921)   , instance of (P31)   , copyright license (P275)   , subclass of (P279)   

  #title: Items about invasion biology hypothesis papers without license statement
  SELECT DISTINCT ?item ?itemLabel ?topic ?topicLabel ?doi
  WHERE { 
    ?item wdt:P6104 wd:Q56241615 ;
          wdt:P356 ?doi ;
          wdt:P921 ?topic .
    ?topic wdt:P31 wd:Q41719 .
    MINUS { ?item wdt:P275 ?license } .
  #   ?license wdt:P31*/wdt:P279* wd:Q30939938 .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?topic ?topicLabel ?doi
  ORDER BY DESC(?doi)
  

Items about invasion biology hypothesis papers without license statement

🚧 Works about predation and at least two species, at least one of which is in scope

The following query uses these:

• Items: species (Q7432)   , WikiProject Invasion Biology (Q56241615)   

• Properties: main subject (P921)   , taxon rank (P105)   , maintained by WikiProject (P6104)   

  #title: Works about predation and at least two species, at least one of which is in scope
  #defaultView:Table
  
  PREFIX target: <http://www.wikidata.org/entity/Q170430> 
  
  SELECT ?count # (CONCAT("/topics/Q202864,", SUBSTR(STR(?topic), 32)) AS ?countUrl)
         ?topic ?topicLabel # (CONCAT("/topic/", SUBSTR(STR(?topic), 32)) AS ?topicUrl)
         ?topic1 ?topic1Label # (CONCAT("/topic1/", SUBSTR(STR(?topic), 32)) AS ?topic1Url)
         ?example_work ?example_workLabel # (CONCAT("/work/", SUBSTR(STR(?example_work), 32)) AS ?example_workUrl)
  WITH {
    SELECT DISTINCT ?topic ?topic1 (COUNT(?work) AS ?count) (SAMPLE(?work) AS ?example_work) WHERE {
      # Find works for the specific queried topic
  	  ?work wdt:P921 target: .
      
      # Find co-occuring topics
      ?work wdt:P921 ?topic .
      ?work wdt:P921 ?topic1 .
  
      # Filter for species
      ?topic wdt:P105 wd:Q7432 .
      ?topic1 wdt:P105 wd:Q7432 .
  
      # Filter for topics within scope of WikiProject Invasion biology
      ?topic wdt:P6104 wd:Q56241615 .
  
      # Avoid listing the queried topic
        FILTER (target: != ?topic)
        FILTER (target: != ?topic1)
        FILTER (?topic != ?topic1)
  }
    GROUP BY ?topic ?topic1
  } AS %result
  WHERE {
    # Label the results
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  ORDER BY DESC(?count)
  

Works about predation and at least two species, at least one of which is in scope

🚧 Authors of at least three in-scope works who are not tagged as in scope

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , author (P50)   

  #title: Authors of at least three in-scope works who are not tagged as in scope
  #defaultView:Table
  
  SELECT 
    (REPLACE(STR(?author), ".*Q", "Q") AS ?qid) 
    ("P6104" AS ?property)
    ("Q56241615" AS ?ReplaceWithYourTargetID)
  
  WITH {
    SELECT (count(DISTINCT ?work) as ?count) ?author WHERE {
      ?work wdt:P6104 wd:Q56241615 .
      ?work wdt:P50 ?author .
    }
    GROUP BY ?author
    HAVING (?count > 2)
  } AS %result
  WHERE {
    INCLUDE %result
    FILTER NOT EXISTS {?author wdt:P6104 wd:Q56241615 .}
  }
  

Authors of at least three in-scope works who are not tagged as in scope

🚧 Works without topic tags

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , title (P1476)   , main subject (P921)   

  #title: Invasion biology papers without "main subject" (P921) statements
  SELECT DISTINCT ?work ?title
  WHERE {
    ?work wdt:P6104 wd:Q56241615 ;
          wdt:P1476 ?title .
    FILTER NOT EXISTS {?work wdt:P921 [] .}
  }
  

Invasion biology papers without "main subject" (P921) statements

🚧 In-scope species ranked by ambiguity of their taxon abbreviation

The following query uses these:

• Items: species (Q7432)   , WikiProject Invasion Biology (Q56241615)   

• Properties: taxon rank (P105)   , maintained by WikiProject (P6104)   

Features: BubbleChart (Q24515280)   

#title: Species ranked by ambiguity of their taxon abbreviation
#defaultView:BubbleChart

PREFIX target: <http://www.wikidata.org/prop/direct/P1813>

SELECT ?count ?o ?oLabel
WITH {
  SELECT (COUNT(?s) AS ?count) ?o WHERE {
    ?s target: ?o .
    ?s wdt:P105 wd:Q7432 .
    ?s wdt:P6104 wd:Q56241615 .
  }
  GROUP BY ?o
  ORDER BY DESC(?count)
  LIMIT 100
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language  "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . }
}
ORDER BY DESC(?count)

Species ranked by ambiguity of their taxon abbreviation

🚧 In-scope items with Scholia template on the English Wikipedia

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , main subject (P921)   

  #title: Invasion biology items with Scholia template on the English Wikipedia
  
  SELECT 
    DISTINCT ?item ?itemLabel
  WHERE {
    ?item wdt:P6104 wd:Q56241615.
      
    {   
     SELECT ?item ?pageid 
                  ?ns WHERE {
      SERVICE wikibase:mwapi {
        bd:serviceParam wikibase:endpoint "en.wikipedia.org" .
        bd:serviceParam wikibase:api "Generator" .
        bd:serviceParam mwapi:generator "search" .
        bd:serviceParam mwapi:gsrsearch "hastemplate:Scholia" .
        bd:serviceParam mwapi:gsrlimit "max" .
        ?item wikibase:apiOutputItem mwapi:item .
        ?pageid wikibase:apiOutput "@pageid" .
        ?ns wikibase:apiOutput "@ns" .
      }
    } LIMIT 10000
   }
    ?item ^wdt:P921 ?work .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Invasion biology items with Scholia template on the English Wikipedia

🚧 Invasive species items without Scholia template on the English Wikipedia

The following query uses these:

• Items: species (Q7432)   , WikiProject Invasion Biology (Q56241615)   

• Properties: taxon name (P225)   , taxon rank (P105)   , maintained by WikiProject (P6104)   , main subject (P921)   

  #title: Invasive species items without Scholia template on the English Wikipedia
  
  SELECT 
    DISTINCT ?item ?taxonname
  WHERE {
   ?item wdt:P225 ?taxonname ;
         wdt:P105 wd:Q7432 .
    ?item wdt:P6104 wd:Q56241615.
      
    {   
     SELECT ?item ?pageid 
                  ?ns WHERE {
      SERVICE wikibase:mwapi {
        bd:serviceParam wikibase:endpoint "en.wikipedia.org" .
        bd:serviceParam wikibase:api "Generator" .
        bd:serviceParam mwapi:generator "search" .
        bd:serviceParam mwapi:gsrsearch "-hastemplate:Scholia" .
        bd:serviceParam mwapi:gsrlimit "max" .
        ?item wikibase:apiOutputItem mwapi:item .
        ?pageid wikibase:apiOutput "@pageid" .
        ?ns wikibase:apiOutput "@ns" .
      }
    } LIMIT 10000
   }
    ?item ^wdt:P921 ?work .
  }
  

Invasive species items without Scholia template on the English Wikipedia

🚧 Items to be exposed via the OAI-PMH endpoint

The WikiProject maintains an OAI-PMH endpoint (Q116690832) at https://enkore.toolforge.org/oai_pmh/, through which bibliographic metadata for some of the items overseen by WikiProject Invasion biology is available. The query below is used to feed updates into that endpoint.

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   , hypothesis (Q41719)   , invasion success (Q109467185)   , invasion impact (Q112148709)   , invasion pathway (Q111525751)   , invasion management (Q113019190)   , meta-invasion science (Q124428132)   , open license (Q30939938)   

• Properties: maintained by WikiProject (P6104)   , DOI (P356)   , main subject (P921)   , instance of (P31)   , copyright license (P275)   , subclass of (P279)   

  #title: Items to be exposed via the OAI-PMH endpoint https://enkore.toolforge.org/oai_pmh/
  SELECT DISTINCT ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
  WHERE {
    ?item wdt:P6104 wd:Q56241615;
          wdt:P356 ?doi ;
          wdt:P921 ?topic .
   
    {?topic wdt:P31 wd:Q41719 .}
    UNION
    {VALUES ?topic { wd:Q109467185 wd:Q112148709 wd:Q111525751 wd:Q113019190 wd:Q124428132 } }
    UNION
    {?item wdt:P275 ?license .
    ?license wdt:P31*/wdt:P279* wd:Q30939938 .}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  GROUP BY ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
  

Items to be exposed via the OAI-PMH endpoint https://enkore.toolforge.org/oai_pmh/

🚧 ORCID Scraper pages for random in-scope Wikidata items with ORCID statement

The following query uses these:

• Items: WikiProject Invasion Biology (Q56241615)   

• Properties: maintained by WikiProject (P6104)   , ORCID iD (P496)   

  # ORCID Scraper pages for random in-scope Wikidata items with ORCID statement
  
  SELECT DISTINCT
  (URI(CONCAT("https://orcid-scraper.toolforge.org/results?qid=", ENCODE_FOR_URI(REPLACE(STR(?person), ".*Q", "Q")), "&orcid=", ENCODE_FOR_URI(?orcid))) AS ?qidorcidURI)
  WHERE {
    SERVICE bd:sample {
      ?person wdt:P6104 wd:Q56241615 .
      bd:serviceParam bd:sample.limit 2000 . 
    }
      ?person wdt:P496 ?orcid .
  }
  LIMIT 20
  

Try it!

🚧 Methods

🚧 QuickStatements for method tagging via describes a project that uses (P4510)

🚧 With lexemes typically preceding the mention of the method

The following query uses these:

• Properties: title (P1476)   , published in (P1433)   

  #title: QuickStatements for method tagging via P4510
  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P4510" AS ?property)
    ("Q4115189" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "\"using\" environmental dna haswbstatement:P31=Q13442814 -haswbstatement:P4510=Q4115189". 
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
  UNION
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "\"utilizing\" environmental dna haswbstatement:P31=Q13442814 -haswbstatement:P4510=Q4115189". 
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title_.
    ?item wdt:P1433 ?venue.
    ?venue wdt:P1476 ?venue_title.
    BIND(CONCAT(?title_ , " | " , ?venue_title)  AS ?title)
    FILTER REGEX(LCASE(?title), "\\b(using|utilizing|with|through|via|by|(us((ag)?)e|application(s?)) of\\b)(.)environmental(.)dna").
  
  }
  

QuickStatements for method tagging via P4510

🚧 With lexemes typically following the mention of the method

The following query uses these:

• Properties: title (P1476)   

  #title: QuickStatements for method tagging via P4510
  SELECT 
    DISTINCT
    ?item ?title
    (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
    ("P4510" AS ?property)
    ("Q4115189" AS ?ReplaceWithYourTargetID)
    ("S887" AS ?heuristic)
    ("Q69652283" AS ?deduced)
  
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "\"enables\" environmental dna haswbstatement:P31=Q13442814 -haswbstatement:P4510=Q4115189". 
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
  UNION
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "\"allows\" environmental dna haswbstatement:P31=Q13442814 -haswbstatement:P4510=Q4115189". 
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    FILTER REGEX(LCASE(?title), "environmental(.)dna(.)(demonstrates|shows|highlights|enables|allows|facilitates)(.)").
  
  }
  

QuickStatements for method tagging via P4510

🚧 Candidate methods for tagging via describes a project that uses (P4510)

🚧 Candidate methods from invasion biology

The following query uses these:

• Properties: title (P1476)   

  SELECT 
    DISTINCT
      ?method ?N (COUNT(?item) AS ?count)
  WHERE {
    hint:Query hint:optimizer "None".
    
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "\"using\" and haswbstatement:P31=Q13442814 -haswbstatement:P4510 haswbstatement:P6104=Q56241615". 
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
  UNION
  {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search";
                      wikibase:endpoint "www.wikidata.org";
                      mwapi:srsearch "\"using\" -and haswbstatement:P31=Q13442814 -haswbstatement:P4510 haswbstatement:P6104=Q56241615".
        ?page_title wikibase:apiOutput mwapi:title.
    }
   }
    BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
    
    ?item wdt:P1476 ?title.
    BIND(STRAFTER(LCASE(?title), "using ") AS ?method) 
    FILTER (STRLEN(?method) > 0 )
    BIND(STRLEN(REPLACE(?method, "\\S", "")) + 1 as ?N)
  }
  GROUP BY ?method ?N ?count
  ORDER BY DESC(?count)
  

Try it!

🚧 Candidate methods from ecology

The following query uses these:

• Properties: title (P1476)   

  #title: Candidate methods for tagging via P4510
  SELECT 
    DISTINCT
      ?method ?N (COUNT(?item) AS ?count)
  
  WHERE {
    hint:Query hint:optimizer "None".
  
    {  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
      wikibase:endpoint "www.wikidata.org";
      mwapi:srsearch "ecology and haswbstatement:P31=Q13442814 -haswbstatement:P4510=Q4115189".
      ?page_title wikibase:apiOutput mwapi:title.
    }
    }
  UNION
  
    {  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
      wikibase:endpoint "www.wikidata.org";
      mwapi:srsearch "ecology -and haswbstatement:P31=Q13442814 -haswbstatement:P4510=Q4115189". 
      ?page_title wikibase:apiOutput mwapi:title.
    }
    }  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
    ?item wdt:P1476 ?title.
    BIND(CONCAT(?title_ , " | " , ?venue_title)  AS ?title)
    FILTER REGEX(LCASE(?title), "\\b(using|utilizing|with|through|via|by|(us((ag)?)e|application(s?)) of\\b)(.)").
  
    BIND(STRAFTER(LCASE(?title), "using ") AS ?method) 
    FILTER (STRLEN(?method) > 0 )
    BIND(STRLEN(REPLACE(?method, "\\S", "")) + 1 as ?N)
  
  }
  GROUP BY ?method ?N ?count
  ORDER BY DESC(?count)
  

Candidate methods for tagging via P4510

🚧 Generic candidate methods

The following query uses these:

• Properties: title (P1476)   

  #title: Candidate methods for tagging via P4510
  SELECT 
    DISTINCT
      ?method ?N (COUNT(?item) AS ?count)
  
  WHERE {
    hint:Query hint:optimizer "None".
  
    {  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
      wikibase:endpoint "www.wikidata.org";
      mwapi:srsearch "using and haswbstatement:P31=Q13442814 -haswbstatement:P4510=Q4115189".
      ?page_title wikibase:apiOutput mwapi:title.
    }
    }
  UNION
  
    {  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
      wikibase:endpoint "www.wikidata.org";
      mwapi:srsearch "using -and haswbstatement:P31=Q13442814 -haswbstatement:P4510=Q4115189". 
      ?page_title wikibase:apiOutput mwapi:title.
    }
    }  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
    ?item wdt:P1476 ?title.
    BIND(CONCAT(?title_ , " | " , ?venue_title)  AS ?title)
    FILTER REGEX(LCASE(?title), "\\b(using|utilizing|with|through|via|by|(us((ag)?)e|application(s?)) of\\b)(.)").
  
    BIND(STRBEFORE(LCASE(?title), "using ") AS ?method) 
    FILTER (STRLEN(?method) > 0 )
    BIND(STRLEN(REPLACE(?method, "\\S", "")) + 1 as ?N)
  
  }
  GROUP BY ?method ?N ?count
  ORDER BY DESC(?count)
  

Candidate methods for tagging via P4510

Literature

Scholia

• invasion biology
• invasive species
• Comparison: native and non-native prey along with native and non-native predator

Topic tagging

• Wikidata:Tools/ItemSubjector
• TABernacle

Subpages

This WikiProject has the following subpages:

• Participants
• Statistics
• Statistics/Integraality
• Statistics/Integraality/human
• Statistics/Integraality/scholarly article
• Statistics/Integraality/taxon
• Task Force Hi Knowledge
• Wikidata lists
• Wikidata lists/Common author name strings on publications about invasion biology
• Wikidata lists/Habitats
• Wikidata lists/Invasive species without image but with Commons category
• Wikidata lists/Works about invasive species
• human
• scholarly article
• taxon

Participants

[+] Add yourself to the list

The participants listed below can be notified using the following template in discussions:
{{Ping project|Invasion biology}}

• Daniel Mietchen
• Peter Kraker
• JonathanJeschke
• Widowmaker12k
• Frank N. Havemann
• Dan Koehl
• Qgroom
• Tina Heger
• Vanessalozano
• Nicolas Noé
• Kees van Vliet
• Peter Murray-Rust
• Magnus Sälgö
• Ambrosia10

See also

• Wikidata:WikiProject Biology
• Wikidata:WikiProject Taxonomy
• Wikidata:WikiProject Ecology
• Wikidata:WikiProject Wikidata for research
• Wikidata:WikiProject Climate Change