CodeSnip Old Code (SVN)

{
 * This Source Code Form is subject to the terms of the Mozilla Public License,
 * v. 2.0. If a copy of the MPL was not distributed with this file, You can
 * obtain one at http://mozilla.org/MPL/2.0/
 *
 * Copyright (C) 2008-2012, Peter Johnson (www.delphidabbler.com).
 *
 * $Rev$
 * $Date$
 *
 * Pascal script for use in [Code] Section of CodeSnip's Install.iss.
 *
 * Copies existing CodeSnip main databases from an original location to location
 * required by current version of CodeSnip.
}


// Copies all files from one directory to another. Does nothing if SourceDir
// doesn't exist or if both directories are the same. If DestDir does not exist
// it is created.
procedure CopyDirectory(SourceDir, DestDir: string);
var
  SourcePath: string;
  DestPath: string;
  FindRec: TFindRec;
begin
  if CompareText(SourceDir, DestDir) = 0 then
    Exit;
  if not DirExists(SourceDir) then
    Exit;
  if not DirExists(DestDir) then
    ForceDirectories(DestDir);
  SourcePath := AddBackslash(SourceDir);
  DestPath := AddBackslash(DestDir);
  if FindFirst(SourcePath + '*', FindRec) then
  begin
    repeat
      if (FindRec.Attributes and FILE_ATTRIBUTE_DIRECTORY) = 0 then
        FileCopy(SourcePath + FindRec.Name, DestPath + FindRec.Name, False);
    until not FindNext(FindRec);
    FindClose(FindRec);
  end;
end;

// Copies main database from it's location on the installation identified by
// PrevInstallID to correct location for program being installed.
procedure CopyMainDatabase(PrevInstallID: Integer);
var
  OldMainDatabase: string;
begin
  OldMainDatabase := gMainDatabaseDirs[PrevInstallID];
  if OldMainDatabase <> '' then
    CopyDirectory(OldMainDatabase, gMainDatabaseDirs[piCurrent]);
end;

// Checks if main database is installed in correct install directory for
// current version of program.
function MainDatabaseExists: Boolean;
begin
  Result := FileExists(gMainDatabaseDirs[piCurrent] + '\categories.ini');
end;