x-net-upnp-browser

#!/usr/bin/env perl
#
# Scan the Network for UPnP devices
#
# Pedro Melo <melo@simplicidade.org>
#

use strict;
use warnings;
use Net::UPnP::ControlPoint;

# $Net::UPnP::DEBUG++;

my $obj = Net::UPnP::ControlPoint->new();
my @dev_list = $obj->search(st =>'upnp:rootdevice', mx => 3);
my $devNum= 0;

foreach my $dev (@dev_list) {
  my $device_type = $dev->getdevicetype();
  my $name = $dev->getfriendlyname();
  if ($device_type ne 'urn:schemas-upnp-org:device:MediaServer:1') {
    $name ||= '<unamed>';
    print "Device type '$device_type' named '$name', ignored\n";
    next;
  }
  
  print "[$devNum]: $name\n";
  next unless $dev->getservicebyname('urn:schemas-upnp-org:service:ContentDirectory:1');

  my $condir_service = $dev->getservicebyname('urn:schemas-upnp-org:service:ContentDirectory:1');
  next unless defined($condir_service);

  my %action_in_arg = (
    'ObjectID'       => 0,
    'BrowseFlag'     => 'BrowseDirectChildren',
    'Filter'         => '*',
    'StartingIndex'  => 0,
    'RequestedCount' => 0,
    'SortCriteria'   => '',
  );
  my $action_res = $condir_service->postcontrol('Browse', \%action_in_arg);
  next unless $action_res->getstatuscode() == 200;

  my $actrion_out_arg = $action_res->getargumentlist();
  next unless $actrion_out_arg->{'Result'};

  my $result = $actrion_out_arg->{'Result'};
  while ($result =~ m/<dc:title>(.*?)<\/dc:title>/sgi) {
    print "\t$1\n";
  }
  $devNum++;
}